Merge branch 'feature/git-index-32' into develop

Author: EvilBeaver

tests/v8files-extractor-test.os

@@ -15,6 +15,7 @@
 
 	ВсеТесты.Добавить("Тест_ДолженРазложитьФайлОбработкиИзЗаданнойПапки");
 	ВсеТесты.Добавить("Тест_ДолженРазложитьКаталог");
+	ВсеТесты.Добавить("Тест_ДолженРазобратьФайлыПоЖурналуИзмененийГит");
 
 	Возврат ВсеТесты;
 
@@ -90,6 +91,20 @@
 
 КонецПроцедуры
 
+Процедура Тест_ДолженРазобратьФайлыПоЖурналуИзмененийГит() Экспорт
+	
+	ФайлОбработки = ПолучитьФайлТестовойОбработки();
+	
+	ЖурналИзмененийГит = "A	" + ФайлОбработки.Имя+"
+		| M	" + "pref-" + ФайлОбработки.Имя;
+	
+	Исполнитель = ЗагрузитьИсполнителя();
+	МассивИмен = Исполнитель.ПолучитьИменаИзЖурналаИзмененийГит(ЖурналИзмененийГит);
+	
+	Ожидаем.Что(МассивИмен, "Должны были найти измененный файл").Содержит(ФайлОбработки.Имя);
+	Ожидаем.Что(МассивИмен, "Должны были найти измененный файл").Содержит("pref-" + ФайлОбработки.Имя);
+КонецПроцедуры
+
 Функция КаталогСодержитИсходникиОбработки(Знач Каталог)
 	ВыгруженныеФайлы = НайтиФайлы(Каталог, ПолучитьМаскуВсеФайлы());
 	ИменаВыгруженныхФайлов = РазвернутьМассивФайловВИменаФайлов(ВыгруженныеФайлы);

v8files-extractor.os

@@ -3,9 +3,24 @@
 #Использовать tempfiles
 #Использовать asserts
 #Использовать v8runner
+#Использовать strings
 
 Перем Лог;
 Перем КодВозврата;
+Перем мВозможныеКоманды;
+
+Функция ВозможныеКоманды()
+	
+	Если мВозможныеКоманды = Неопределено Тогда
+		мВозможныеКоманды = Новый Структура;
+		мВозможныеКоманды.Вставить("Декомпилировать", "--decompile");
+		мВозможныеКоманды.Вставить("Помощь", "--help");
+		мВозможныеКоманды.Вставить("ОбработатьИзмененияИзГит", "--git-precommit");
+	КонецЕсли;
+	
+	Возврат мВозможныеКоманды;
+	
+КонецФункции
 
 Функция ЗапускВКоманднойСтроке()
 
@@ -19,17 +34,9 @@
 
 		Парсер = Новый ПарсерАргументовКоманднойСтроки();
 
-		ВозможныеКоманды = Новый Структура;
-		ВозможныеКоманды.Вставить("Декомпилировать", "--decompile");
-		ВозможныеКоманды.Вставить("Помощь", "--help");
-		
-		ОписаниеКоманды = Парсер.ОписаниеКоманды(ВозможныеКоманды.Декомпилировать);
-		Парсер.ДобавитьПозиционныйПараметрКоманды(ОписаниеКоманды, "ПутьВходящихДанных");
-		Парсер.ДобавитьПозиционныйПараметрКоманды(ОписаниеКоманды, "ВыходнойКаталог");
-		Парсер.ДобавитьКоманду(ОписаниеКоманды);
-
-		ОписаниеКоманды = Парсер.ОписаниеКоманды(ВозможныеКоманды.Помощь);
-		Парсер.ДобавитьКоманду(ОписаниеКоманды);
+		ДобавитьОписаниеКомандыДекомпилировать(Парсер);
+		ДобавитьОписаниеКомандыПомощь(Парсер);
+		ДобавитьОписаниеКомандыИзмененияПоЖурналуГит(Парсер);
 
 		Аргументы = Парсер.РазобратьКоманду(АргументыКоманднойСтроки);
 
@@ -39,10 +46,12 @@
 			Лог.Отладка(Параметр.Ключ + " = " + Параметр.Значение);
 		КонецЦикла;
 
-		Если Команда = ВозможныеКоманды.Декомпилировать Тогда
+		Если Команда = ВозможныеКоманды().Декомпилировать Тогда
 			Декомпилировать(Аргументы.ЗначенияПараметров["ПутьВходящихДанных"], Аргументы.ЗначенияПараметров["ВыходнойКаталог"]);
-		ИначеЕсли Команда = ВозможныеКоманды.Помощь Тогда
+		ИначеЕсли Команда = ВозможныеКоманды().Помощь Тогда
 			ВывестиСправку();
+		ИначеЕсли Команда = ВозможныеКоманды().ОбработатьИзмененияИзГит Тогда
+			ОбработатьИзмененияИзГит(Аргументы.ЗначенияПараметров["ВыходнойКаталог"]);
 		КонецЕсли;
 
 	Исключение
@@ -54,11 +63,35 @@
 
 КонецФункции
 
+Процедура ДобавитьОписаниеКомандыДекомпилировать(Знач Парсер)
+	ОписаниеКоманды = Парсер.ОписаниеКоманды(ВозможныеКоманды().Декомпилировать);
+	Парсер.ДобавитьПозиционныйПараметрКоманды(ОписаниеКоманды, "ПутьВходящихДанных");
+	Парсер.ДобавитьПозиционныйПараметрКоманды(ОписаниеКоманды, "ВыходнойКаталог");
+	Парсер.ДобавитьКоманду(ОписаниеКоманды);
+КонецПроцедуры
+
+Процедура ДобавитьОписаниеКомандыПомощь(Знач Парсер)
+	ОписаниеКоманды = Парсер.ОписаниеКоманды(ВозможныеКоманды().Помощь);
+	Парсер.ДобавитьКоманду(ОписаниеКоманды);
+КонецПроцедуры
+
+Процедура ДобавитьОписаниеКомандыИзмененияПоЖурналуГит(Знач Парсер)
+	
+	ОписаниеКоманды = Парсер.ОписаниеКоманды(ВозможныеКоманды().ОбработатьИзмененияИзГит);
+	Парсер.ДобавитьПозиционныйПараметрКоманды(ОписаниеКоманды, "ВыходнойКаталог");
+	Парсер.ДобавитьКоманду(ОписаниеКоманды);
+	
+КонецПроцедуры
+
 Процедура Инициализация()
 	Лог = Логирование.ПолучитьЛог("oscript.app.v8files-extractor");
 	Лог.УстановитьУровень(УровниЛога.Отладка);
 КонецПроцедуры
 
+
+/////////////////////////////////////////////////////////////////////////////
+// РЕАЛИЗАЦИЯ КОМАНД
+
 Процедура Декомпилировать(Знач Путь, Знач КаталогВыгрузки) Экспорт
 	Файл = Новый Файл(Путь);
 	Если Файл.ЭтоКаталог() Тогда
@@ -68,30 +101,22 @@
 	КонецЕсли;
 КонецПроцедуры
 
-Процедура ВывестиСправку()
-	Сообщить("Утилита сборки/разборки внешних файлов 1С");
-	Сообщить(" ");
-	Сообщить("Параметры командной строки:");
-	Сообщить("	--decompile inputPath outputPath");
-	Сообщить("		Разбор файлов на исходники");
-	
-	Сообщить("	--help");
-	Сообщить("		Показ этого экрана");
-КонецПроцедуры
-
 Процедура РазобратьКаталог(Знач ПутьКаталога, Знач КаталогВыгрузки) Экспорт
 	Лог.Информация("Подготовка выгрузки каталога "+ПутьКаталога+" в каталог " + КаталогВыгрузки);
 	РазобратьКаталогВнутр(ПутьКаталога, КаталогВыгрузки);
 	Лог.Информация("Завершена выгрузки каталога "+ПутьКаталога+" в каталог " + КаталогВыгрузки);
 КонецПроцедуры
 
-Процедура РазобратьФайл(Знач ПутьФайла, Знач КаталогВыгрузки) Экспорт
+Функция РазобратьФайл(Знач ПутьФайла, Знач КаталогВыгрузки) Экспорт
 	Лог.Информация("Подготовка выгрузки файла "+ПутьФайла+" в каталог " + КаталогВыгрузки);
 
-	РазобратьФайлВнутр(ПутьФайла, КаталогВыгрузки);
+	КаталогИсходников = РазобратьФайлВнутр(ПутьФайла, КаталогВыгрузки);
 
 	Лог.Информация("Завершена выгрузка файла "+ПутьФайла+" в каталог " + КаталогВыгрузки);
-КонецПроцедуры
+	
+	Возврат КаталогИсходников;
+	
+КонецФункции
 
 Процедура РазобратьКаталогВнутр(Знач ПутьКаталога, Знач КаталогВыгрузки)
 	ОбъектКаталога = Новый Файл(ПутьКаталога);
@@ -113,10 +138,16 @@
 КонецПроцедуры
 
 Функция ТипФайлаПоддерживается(Файл)
-	Возврат Найти(".epf,.erf,", Файл.Расширение+",") > 0;
+	Если ПустаяСтрока(Файл.Расширение) Тогда
+		Возврат Ложь;
+	КонецЕсли;
+	
+	Поз = Найти(".epf,.erf,", Файл.Расширение+",");
+	Возврат Поз > 0;
+	
 КонецФункции
 
-Процедура РазобратьФайлВнутр(Знач ПутьФайла, Знач КаталогВыгрузки)
+Функция РазобратьФайлВнутр(Знач ПутьФайла, Знач КаталогВыгрузки)
 
 	Файл = Новый Файл(ПутьФайла);
 	Если Не ТипФайлаПоддерживается(Файл) Тогда
@@ -129,7 +160,9 @@
 	ОбеспечитьПустойКаталог(ПапкаИсходников);
 	ЗапуститьРаспаковку(Файл, ПапкаИсходников);
 
-КонецПроцедуры
+	Возврат ПапкаИсходников.ПолноеИмя;
+	
+КонецФункции
 
 Процедура ЗапуститьРаспаковку(Знач Файл, Знач ПапкаИсходников)
 
@@ -179,6 +212,129 @@
 
 КонецПроцедуры
 
+
+Процедура ВывестиСправку()
+	Сообщить("Утилита сборки/разборки внешних файлов 1С");
+	Сообщить(" ");
+	Сообщить("Параметры командной строки:");
+	Сообщить("	--decompile inputPath outputPath");
+	Сообщить("		Разбор файлов на исходники");
+	
+	Сообщить("	--help");
+	Сообщить("		Показ этого экрана");
+	Сообщить("	--git-precommit");
+	Сообщить("		Запустить чтение индекса из git и определить список файлов для разбора, разложить их и добавить исходники в индекс");
+КонецПроцедуры
+
+
+Процедура ОбработатьИзмененияИзГит(Знач ВыходнойКаталог)
+	
+	Если ПустаяСтрока(ВыходнойКаталог) Тогда
+		ВыходнойКаталог = "src";
+	КонецЕсли;
+	
+	ЖурналИзмененийГитСтрокой = ПолучитьЖурналИзмененийГит();
+	ИменаФайлов = ПолучитьИменаИзЖурналаИзмененийГит(ЖурналИзмененийГитСтрокой);
+	
+	КореньРепо = ТекущийКаталог();
+	КаталогИсходников = ОбъединитьПути(КореньРепо, ВыходнойКаталог);
+	СписокНовыхКаталогов = Новый Массив;
+	Для Каждого Файл Из ИменаФайлов Цикл
+		Если ТипФайлаПоддерживается(Новый Файл(Файл)) Тогда
+			Лог.Отладка("Получен из журнала git файл " + Файл);
+			ПолныйПуть = ОбъединитьПути(КореньРепо, Файл);
+			СписокНовыхКаталогов.Добавить(РазобратьФайл(ПолныйПуть, КаталогИсходников));
+		КонецЕсли;
+	КонецЦикла;
+	
+	ДобавитьИсходникиВГит(СписокНовыхКаталогов);
+	
+КонецПроцедуры
+
+Функция ПолучитьЖурналИзмененийГит()
+	
+	Перем КодВозврата;
+	
+	Лог.Отладка("Запускаю git diff-index");
+	Вывод = ПолучитьВыводПроцесса("git diff-index --name-status --cached HEAD", КодВозврата);
+	Лог.Отладка("Вывод git diff-index: " + Вывод);
+	Если КодВозврата <> 0 Тогда
+		Лог.Отладка("Запускаю git status");
+		Вывод = ПолучитьВыводПроцесса("git status --porcelain", КодВозврата);
+		Лог.Отладка("Вывод git status: " + Вывод);
+		
+		Если КодВозврата <> 0 Тогда
+			ВызватьИсключение "Не удалось собрать журнал изменений git";
+		КонецЕсли;
+		
+	КонецЕсли;
+	
+	Возврат Вывод;
+	
+КонецФункции
+
+Функция ПолучитьВыводПроцесса(Знач КоманднаяСтрока, КодВозврата)
+	
+	// Это для dev версии 1.0.11
+	//Процесс = СоздатьПроцесс(КоманднаяСтрока, , Истина,, КодировкаТекста.UTF8);
+	// Процесс.Запустить();
+	// Вывод = "";
+	
+	// Процесс.ОжидатьЗавершения();
+	
+	// Вывод = Вывод + Процесс.ПотокВывода.Прочитать();
+	// Вывод = Вывод + Процесс.ПотокОшибок.Прочитать();
+	
+	// КодВозврата = Процесс.КодВозврата;
+	
+	ЛогФайл = ВременныеФайлы.НовоеИмяФайла();
+	СтрокаЗапуска = "cmd /C """ + КоманднаяСтрока + " > """ + ЛогФайл + """ 2>&1""";
+	Лог.Отладка(СтрокаЗапуска);
+	ЗапуститьПриложение(СтрокаЗапуска,, Истина, КодВозврата);
+	Лог.Отладка("Код возврата: " + КодВозврата);
+	ЧтениеТекста = Новый ЧтениеТекста(ЛогФайл, "utf-8");
+	Вывод = ЧтениеТекста.Прочитать();
+	ЧтениеТекста.Закрыть();
+	ВременныеФайлы.УдалитьФайл(ЛогФайл);
+	
+	Возврат Вывод;
+	
+КонецФункции
+
+Функция ПолучитьИменаИзЖурналаИзмененийГит(Знач ЖурналИзмененийГит) Экспорт
+	МассивИмен = Новый Массив;
+	МассивСтрокЖурнала = СтроковыеФункции.РазложитьСтрокуВМассивПодстрок(ЖурналИзмененийГит, Символы.ПС);
+	Лог.Отладка("ЖурналИзмененийГит:");
+	Для Каждого СтрокаЖурнала Из МассивСтрокЖурнала Цикл
+		Лог.Отладка("	"+СтрокаЖурнала);
+		СтрокаЖурнала = СокрЛ(СтрокаЖурнала);
+		СимволИзменений = Лев(СтрокаЖурнала, 1);
+		Если СимволИзменений = "A" или СимволИзменений = "M" Тогда
+			ИмяФайла = СокрЛП(Сред(СтрокаЖурнала, 2));
+			МассивИмен.Добавить(ИмяФайла);
+		КонецЕсли;
+	КонецЦикла;
+	Возврат МассивИмен;
+КонецФункции
+
+Процедура ДобавитьИсходникиВГит(Знач СписокНовыхКаталогов)
+
+	Перем КодВозврата;
+	
+	Для Каждого Каталог Из СписокНовыхКаталогов Цикл
+		
+		Лог.Отладка("Запуск git add для каталога " + Каталог);
+		Вывод = ПолучитьВыводПроцесса("git add --all " + Каталог, КодВозврата);
+		Лог.Отладка("Вывод git add: " + Вывод);
+		Если КодВозврата <> 0 Тогда
+			Лог.Ошибка(Вывод);
+			ЗавершитьРаботу(КодВозврата);
+		КонецЕсли;
+		
+	КонецЦикла
+
+КонецПроцедуры
+
 Инициализация();
 
 Если ЗапускВКоманднойСтроке() Тогда