Merge branch 'feature/oscript-port-30' into develop

Author: EvilBeaver

tests/v8files-extractor-test.os

@@ -0,0 +1,113 @@
+#Использовать tempfiles
+#Использовать asserts
+
+Перем юТест;
+
+Процедура Инициализация()
+		
+КонецПроцедуры
+
+Функция ПолучитьСписокТестов(Знач Контекст) Экспорт
+	
+	юТест = Контекст;
+	
+	ВсеТесты = Новый Массив;
+	
+	ВсеТесты.Добавить("Тест_ДолженРазложитьФайлОбработкиИзЗаданнойПапки");
+	ВсеТесты.Добавить("Тест_ДолженРазложитьКаталог");
+	
+	Возврат ВсеТесты;
+	
+КонецФункции
+
+Процедура ПослеЗапускаТеста() Экспорт
+	ВременныеФайлы.Удалить();
+КонецПроцедуры
+
+Функция ЗагрузитьИсполнителя()
+	
+	ИмяКаталога = ТекущийСценарий().Каталог;
+	Исполнитель = ЗагрузитьСценарий(ОбъединитьПути(ИмяКаталога,"../v8files-extractor.os"));
+	Лог = Логирование.ПолучитьЛог("oscript.app.v8files-extractor");
+	Лог.УстановитьУровень(УровниЛога.Отладка);
+	
+	Возврат Исполнитель;
+	
+КонецФункции
+
+Функция ПолучитьФайлТестовойОбработки()
+	
+	ИмяКаталога = ТекущийСценарий().Каталог;
+	ИмяФайла = "Fixture";
+	ИмяФайлаСРасширением = ИмяФайла+".epf";
+	
+	ПутьФайла = ОбъединитьПути(ИмяКаталога, ИмяФайлаСРасширением);
+	ФайлОбработки = Новый Файл(ПутьФайла);
+	Ожидаем.Что(ФайлОбработки.Существует(), "Исходный файл должен существовать").ЭтоИстина();
+	
+	Возврат ФайлОбработки;
+	
+КонецФункции
+
+Процедура Тест_ДолженРазложитьФайлОбработкиИзЗаданнойПапки() Экспорт
+
+	ФайлОбработки = ПолучитьФайлТестовойОбработки();
+	
+	КаталогВыгрузки = ВременныеФайлы.СоздатьКаталог();
+	
+	Исполнитель = ЗагрузитьИсполнителя();
+	Исполнитель.РазобратьФайл(ФайлОбработки.ПолноеИмя, КаталогВыгрузки);
+	
+	КаталогИсходников = Новый Файл(ОбъединитьПути(КаталогВыгрузки, ФайлОбработки.ИмяБезРасширения));
+	Ожидаем.Что(КаталогИсходников.Существует()).ЭтоИстина();
+	Ожидаем.Что(КаталогИсходников.ЭтоКаталог(), "Должны были найти каталог с именем обработки").ЭтоИстина();
+	Ожидаем.Что(КаталогСодержитИсходникиОбработки(КаталогИсходников.ПолноеИмя)).ЭтоИстина();
+КонецПроцедуры
+
+Процедура Тест_ДолженРазложитьКаталог() Экспорт
+
+	ФайлОбработки = ПолучитьФайлТестовойОбработки();
+	
+	ИмяВложенногоКаталога = "1";
+	
+	КаталогИсходников = ВременныеФайлы.СоздатьКаталог();
+	СоздатьКаталог(ОбъединитьПути(КаталогИсходников, ИмяВложенногоКаталога));
+	
+	КопироватьФайл(ФайлОбработки.ПолноеИмя, ОбъединитьПути(КаталогИсходников, ИмяВложенногоКаталога, ФайлОбработки.Имя));
+	
+	КаталогВыгрузки = ВременныеФайлы.СоздатьКаталог();
+	
+	Исполнитель = ЗагрузитьИсполнителя();
+	Исполнитель.РазобратьКаталог(КаталогИсходников, КаталогВыгрузки);
+	
+	ВложенныйКаталогВыгрузки = ОбъединитьПути(КаталогВыгрузки, ИмяВложенногоКаталога);
+	ФайлВложенныйКаталогИсходников = Новый Файл(ВложенныйКаталогВыгрузки);
+	Ожидаем.Что(ФайлВложенныйКаталогИсходников.Существует(), "Должны были найти имя вложенного каталога").ЭтоИстина();
+	Ожидаем.Что(ФайлВложенныйКаталогИсходников.ЭтоКаталог(), "Должны были найти вложенный каталог").ЭтоИстина();
+
+	ПутьКаталогаВыгрузкиДляОбработки = ОбъединитьПути(ВложенныйКаталогВыгрузки, ФайлОбработки.ИмяБезРасширения);
+	Ожидаем.Что(КаталогСодержитИсходникиОбработки(ПутьКаталогаВыгрузкиДляОбработки)).ЭтоИстина();
+
+КонецПроцедуры
+
+Функция КаталогСодержитИсходникиОбработки(Знач Каталог)
+	ВыгруженныеФайлы = НайтиФайлы(Каталог, ПолучитьМаскуВсеФайлы());
+	ИменаВыгруженныхФайлов = РазвернутьМассивФайловВИменаФайлов(ВыгруженныеФайлы);
+	Ожидаем.Что(ИменаВыгруженныхФайлов, "Должны были найти выгруженный файл").Содержит("renames.txt");
+	Ожидаем.Что(ИменаВыгруженныхФайлов, "Должны были найти выгруженный файл").Содержит("Form");
+	Ожидаем.Что(ИменаВыгруженныхФайлов, "Должны были найти выгруженный файл").Содержит("Макеты");
+	Ожидаем.Что(ИменаВыгруженныхФайлов, "Должны были найти выгруженный файл").Содержит("und");
+КонецФункции
+
+Функция РазвернутьМассивФайловВИменаФайлов(Знач МассивОбъектовФайл)
+	
+	ИменаФайлов = Новый Массив;
+	Для Каждого Файл Из МассивОбъектовФайл Цикл
+		ИменаФайлов.Добавить(Файл.Имя);
+	КонецЦикла;
+	
+	Возврат ИменаФайлов;
+	
+КонецФункции
+
+Инициализация();

v8files-extractor.os

@@ -0,0 +1,188 @@
+#Использовать cmdline
+#Использовать logos
+#Использовать tempfiles
+#Использовать asserts
+#Использовать v8runner
+
+Перем Лог;
+Перем КодВозврата;
+
+Функция ЗапускВКоманднойСтроке()
+	
+	КодВозврата = 0;
+	
+	Если ТекущийСценарий().Источник <> СтартовыйСценарий().Источник Тогда
+		Возврат Ложь;
+	КонецЕсли;
+	
+	Попытка
+	
+		Парсер = Новый ПарсерАргументовКоманднойСтроки();
+		
+		ВозможныеКоманды = Новый Структура;
+		ВозможныеКоманды.Вставить("Декомпилировать", "--decompile");
+		ВозможныеКоманды.Вставить("Помощь", "--help");
+		
+		ОписаниеКоманды = Парсер.ОписаниеКоманды(ВозможныеКоманды.Декомпилировать);
+		Парсер.ДобавитьПозиционныйПараметрКоманды(ОписаниеКоманды, "ПутьВходящихДанных");
+		Парсер.ДобавитьПозиционныйПараметрКоманды(ОписаниеКоманды, "ВыходнойКаталог");
+		Парсер.ДобавитьКоманду(ОписаниеКоманды);
+
+		ОписаниеКоманды = Парсер.ОписаниеКоманды(ВозможныеКоманды.Помощь);
+		Парсер.ДобавитьКоманду(ОписаниеКоманды);
+		
+		Аргументы = Парсер.РазобратьКоманду(АргументыКоманднойСтроки);
+		
+		Команда = Аргументы.Команда;
+		Лог.Отладка("Передана команда: "+Команда);
+		Для Каждого Параметр Из Аргументы.ЗначенияПараметров Цикл
+			Лог.Отладка(Параметр.Ключ + " = " + Параметр.Значение);
+		КонецЦикла;
+		
+		Если Команда = ВозможныеКоманды.Декомпилировать Тогда
+			Декомпилировать(Аргументы.ЗначенияПараметров["ПутьВходящихДанных"], Аргументы.ЗначенияПараметров["ВыходнойКаталог"]);
+		ИначеЕсли Команда = ВозможныеКоманды.Помощь Тогда
+			ВывестиСправку();
+		КонецЕсли;
+		
+	Исключение
+		Лог.Ошибка(ОписаниеОшибки());
+		КодВозврата = 1;
+	КонецПопытки;
+	
+	Возврат Истина;
+	
+КонецФункции
+
+Процедура Инициализация()
+	Лог = Логирование.ПолучитьЛог("oscript.app.v8files-extractor");
+	Лог.УстановитьУровень(УровниЛога.Отладка);
+КонецПроцедуры
+
+Процедура Декомпилировать(Знач Путь, Знач КаталогВыгрузки) Экспорт
+	Файл = Новый Файл(Путь);
+	Если Файл.ЭтоКаталог() Тогда
+		РазобратьКаталог(Файл.ПолноеИмя, КаталогВыгрузки);
+	Иначе
+		РазобратьФайл(Файл.ПолноеИмя, КаталогВыгрузки);
+	КонецЕсли;
+КонецПроцедуры
+
+Процедура ВывестиСправку()
+	Сообщить("Утилита сборки/разборки внешних файлов 1С");
+	Сообщить(" ");
+	Сообщить("Параметры командной строки:");
+	Сообщить("	--decompile inputPath outputPath");
+	Сообщить("		Разбор файлов на исходники");
+	
+	Сообщить("	--help");
+	Сообщить("		Показ этого экрана");
+КонецПроцедуры
+
+Процедура РазобратьКаталог(Знач ПутьКаталога, Знач КаталогВыгрузки) Экспорт
+	Лог.Информация("Подготовка выгрузки каталога "+ПутьКаталога+" в каталог " + КаталогВыгрузки);
+	РазобратьКаталогВнутр(ПутьКаталога, КаталогВыгрузки);
+	Лог.Информация("Завершена выгрузки каталога "+ПутьКаталога+" в каталог " + КаталогВыгрузки);
+КонецПроцедуры
+
+Процедура РазобратьФайл(Знач ПутьФайла, Знач КаталогВыгрузки) Экспорт
+	Лог.Информация("Подготовка выгрузки файла "+ПутьФайла+" в каталог " + КаталогВыгрузки);
+	
+	РазобратьФайлВнутр(ПутьФайла, КаталогВыгрузки);
+	
+	Лог.Информация("Завершена выгрузка файла "+ПутьФайла+" в каталог " + КаталогВыгрузки);
+КонецПроцедуры
+
+Процедура РазобратьКаталогВнутр(Знач ПутьКаталога, Знач КаталогВыгрузки)
+	ОбъектКаталога = Новый Файл(ПутьКаталога);
+	ИмяКаталогаВыгрузки = Новый Файл(КаталогВыгрузки).Имя;
+	Лог.Информация("Вошел в каталог "+ОбъектКаталога.Имя);
+	
+	Файлы = НайтиФайлы(ПутьКаталога, ПолучитьМаскуВсеФайлы());
+	Для Каждого Файл из Файлы Цикл
+		Если Файл.ЭтоКаталог() Тогда
+			РазобратьКаталогВнутр(Файл.ПолноеИмя, ОбъединитьПути(КаталогВыгрузки, Файл.Имя));
+		ИначеЕсли ТипФайлаПоддерживается(Файл) Тогда
+			Лог.Информация("Подготовка выгрузки файла "+Файл.Имя+" в каталог " + ИмяКаталогаВыгрузки);
+			РазобратьФайлВнутр(Файл.ПолноеИмя, КаталогВыгрузки);
+			Лог.Информация("Завершена выгрузка файла "+Файл.Имя+" в каталог " + ИмяКаталогаВыгрузки);
+		КонецЕсли;
+	КонецЦикла;
+	
+	Лог.Информация("Вышел из каталога "+ОбъектКаталога.Имя);
+КонецПроцедуры
+
+Функция ТипФайлаПоддерживается(Файл)
+	Возврат Найти(".epf,.erf,", Файл.Расширение+",") > 0;
+КонецФункции
+
+Процедура РазобратьФайлВнутр(Знач ПутьФайла, Знач КаталогВыгрузки)
+	
+	Файл = Новый Файл(ПутьФайла);
+	Если Не ТипФайлаПоддерживается(Файл) Тогда
+		ВызватьИсключение "Тип файла """+Файл.Расширение+""" не поддерживается";
+	КонецЕсли;
+	
+	Ожидаем.Что(Файл.Существует(), "Файл " + ПутьФайла + " должен существовать").ЭтоИстина();
+	
+	ПапкаИсходников = Новый Файл(ОбъединитьПути(КаталогВыгрузки, Файл.ИмяБезРасширения));
+	ОбеспечитьПустойКаталог(ПапкаИсходников);
+	ЗапуститьРаспаковку(Файл, ПапкаИсходников);
+	
+КонецПроцедуры
+
+Процедура ЗапуститьРаспаковку(Знач Файл, Знач ПапкаИсходников)
+	
+	Лог.Отладка("Запускаем распаковку файла");
+	
+	Конфигуратор = Новый УправлениеКонфигуратором();
+	КаталогВременнойИБ = ВременныеФайлы.СоздатьКаталог();
+	Конфигуратор.КаталогСборки(КаталогВременнойИБ);
+	
+	ЛогКонфигуратора = Логирование.ПолучитьЛог("oscript.lib.v8runner");
+	ЛогКонфигуратора.УстановитьУровень(Лог.Уровень());
+	
+	Параметры = Конфигуратор.ПолучитьПараметрыЗапуска();
+	Параметры[0] = "ENTERPRISE";
+	
+	ПутьV8Reader = ОбъединитьПути(ТекущийСценарий().Каталог, "v8Reader", "V8Reader.epf");
+	Лог.Отладка("Путь к V8Reader: " + ПутьV8Reader);
+	Ожидаем.Что(Новый Файл(ПутьV8Reader).Существует()).ЭтоИстина();
+	
+	КоманднаяСтрокаV8Reader = СтрЗаменить("/C""decompile;pathtocf;%1;pathout;%2;ЗавершитьРаботуПосле;""","%1", Файл.ПолноеИмя);
+	КоманднаяСтрокаV8Reader = СтрЗаменить(КоманднаяСтрокаV8Reader,"%2", ПапкаИсходников.ПолноеИмя);
+	
+	Лог.Отладка("Командная строка V8Reader: " + КоманднаяСтрокаV8Reader);
+
+	Параметры.Добавить("/RunModeOrdinaryApplication");
+	Параметры.Добавить("/Execute """ + ПутьV8Reader + """");
+	Параметры.Добавить(КоманднаяСтрокаV8Reader);
+	
+	Конфигуратор.ВыполнитьКоманду(Параметры);
+	Лог.Отладка("Вывод 1С:Предприятия - " + Конфигуратор.ВыводКоманды());
+	Лог.Отладка("Очищаем каталог временной ИБ");
+	ВременныеФайлы.УдалитьФайл(КаталогВременнойИБ);
+	
+КонецПроцедуры
+
+Процедура ОбеспечитьПустойКаталог(Знач ФайлОбъектКаталога)
+	
+	Если Не ФайлОбъектКаталога.Существует() Тогда
+		Лог.Отладка("Создаем новый каталог " + ФайлОбъектКаталога.ПолноеИмя);
+		СоздатьКаталог(ФайлОбъектКаталога.ПолноеИмя);
+	ИначеЕсли ФайлОбъектКаталога.ЭтоКаталог() Тогда
+		Лог.Отладка("Очищаем каталог " + ФайлОбъектКаталога.ПолноеИмя);
+		УдалитьФайлы(ФайлОбъектКаталога.ПолноеИмя, ПолучитьМаскуВсеФайлы());
+	Иначе
+		ВызватьИсключение "Путь " + ФайлОбъектКаталога.ПолноеИмя + " не является каталогом. Выгрузка невозможна";
+	КонецЕсли;
+	
+КонецПроцедуры
+
+Инициализация();
+
+Если ЗапускВКоманднойСтроке() Тогда
+	ЗавершитьРаботу(КодВозврата);
+КонецЕсли;
+
+