Introduce SuppressibleTrait, including common functions to suppress an error code

Author: Atry

src/Linters/HHClientLintError.hack

@@ -11,6 +11,10 @@ namespace Facebook\HHAST;
 
 final class HHClientLintError implements LintError {
 
+  protected function getErrorCode(): string {
+    return $this->getLintRule()->getErrorCode();
+  }
+
   const type TJSONError = shape(
     'descr' => string,
     'severity' => HHClientLintSeverity,

src/Linters/HHClientLintRule.hack

@@ -13,6 +13,8 @@ namespace Facebook\HHAST;
  * The lint rule of an error code reported by the hh_client
  */
 final class HHClientLintRule implements LintRule {
+  use SuppressibleTrait;
+
   public function getName(): string {
     return 'Linter: '.$this->code;
   }

src/Linters/HHClientLinter.hack

@@ -17,6 +17,7 @@ use namespace HH\Lib\{C, Str, Vec};
  */
 final class HHClientLinter implements Linter {
   use LinterTrait;
+  use SuppressibleTrait;
 
   const type TConfig = shape();
 

src/Linters/LinterTrait.hack

@@ -60,41 +60,14 @@ trait LinterTrait {
       |> Str\strip_suffix($$, 'Linter');
   }
 
-  /**
-   * A user can choose to ignore all errors reported by this linter for a
-   * whole file using this string as a marker
-   */
-  public function getIgnoreAllMarker(): string {
-    return LintMarkerName::HHAST_IGNORE_ALL.'['.$this->getLinterName().']';
+  public final function getErrorCode(): string {
+    return $this->getLinterName();
   }
 
-  /**
-   * A user can choose to ignore a specific error reported by this linter
-   * using this string as a marker
-   */
-  public function getIgnoreSingleErrorMarker(): string {
-    return LintMarkerName::HHAST_IGNORE_ERROR.'['.$this->getLinterName().']';
-  }
-
-  /**
-   * A user can choose to ignore a specific error reported by this linter
-   * using this string as a marker.
-   *
-   * The difference to HHAST_IGNORE_ERROR is that we expect this one to be
-   * fixed.
-   */
-  public function getFixmeMarker(): string {
-    return LintMarkerName::HHAST_FIXME.'['.$this->getLinterName().']';
-  }
+  abstract protected function isSuppressedForFile(File $file): bool;
 
-  /**
-   * Is this linter error disabled for the entire file?
-   * Memoized since this should not change per run.
-   */
   public function isLinterSuppressedForFile(): bool {
-    return C\contains_key(
-      $this->getFile()->lintMarkersForLineBasedSuppression(),
-      $this->getIgnoreAllMarker(),
-    );
+    return $this->isSuppressedForFile($this->getFile());
   }
+
 }

src/Linters/SingleRuleLinter.hack

@@ -14,15 +14,12 @@ namespace Facebook\HHAST;
  */
 abstract class SingleRuleLinter implements LintRule, Linter {
   use LinterTrait;
+  use SuppressibleTrait;
 
   final public function getName(): string {
     return $this->getLinterName();
   }
 
-  final public function getErrorCode(): string {
-    return $this->getLinterName();
-  }
-
   abstract public function getLintErrorsAsync(): Awaitable<vec<SingleRuleLintError>>;
 
 }

src/Linters/SuppressibleTrait.hack

@@ -0,0 +1,63 @@
+/*
+ *  Copyright (c) 2017-present, Facebook, Inc.
+ *  All rights reserved.
+ *
+ *  This source code is licensed under the MIT license found in the
+ *  LICENSE file in the root directory of this source tree.
+ *
+ */
+
+namespace Facebook\HHAST;
+
+use type Facebook\HHAST\File;
+use namespace HH\Lib\C;
+
+trait SuppressibleTrait {
+
+  abstract protected function getErrorCode(): string;
+
+  /**
+   * A user can choose to ignore all errors reported by this linter for a
+   * whole file using this string as a marker
+   */
+  public final function getIgnoreAllMarker(): string {
+    return LintMarkerName::HHAST_IGNORE_ALL.
+      '['.
+      $this->getErrorCode().
+      ']';
+  }
+
+  /**
+   * A user can choose to ignore a specific error reported by this linter
+   * using this string as a marker
+   */
+  public final function getIgnoreSingleErrorMarker(): string {
+    return LintMarkerName::HHAST_IGNORE_ERROR.
+      '['.
+      $this->getErrorCode().
+      ']';
+  }
+
+  /**
+   * A user can choose to ignore a specific error reported by this linter
+   * using this string as a marker.
+   *
+   * The difference to HHAST_IGNORE_ERROR is that we expect this one to be
+   * fixed.
+   */
+  public final function getFixmeMarker(): string {
+    return
+      LintMarkerName::HHAST_FIXME.'['.$this->getErrorCode().']';
+  }
+
+  /**
+   * Is this error disabled for the entire file?
+   */
+  public final function isSuppressedForFile(File $file): bool {
+    return C\contains_key(
+      $file->lintMarkersForLineBasedSuppression(),
+      $this->getIgnoreAllMarker(),
+    );
+  }
+
+}