Dagger support

.envrc

@@ -0,0 +1,4 @@
+if ! has nix_direnv_version || ! nix_direnv_version 2.1.0; then
+  source_url "https://raw.githubusercontent.com/nix-community/nix-direnv/2.1.0/direnvrc" "sha256-FAT2R9yYvVg516v3LiogjIc8YfsbWbMM/itqWsm5xTA="
+fi
+use flake

.github/workflows/dagger.yaml

@@ -0,0 +1,41 @@
+name: Dagger
+
+on:
+  push:
+    branches:
+      - master
+  pull_request:
+
+jobs:
+  test:
+    name: Test
+    runs-on: ubuntu-latest
+    strategy:
+      matrix:
+        go: ['1.14', '1.15', '1.16', '1.17', '1.18']
+
+    steps:
+      - name: Checkout code
+        uses: actions/checkout@v3
+
+      - name: Dagger
+        uses: dagger/dagger-for-github@v3
+        with:
+          cmds: |
+            project update
+            do check test go ${{ matrix.go }}
+
+  lint:
+    name: Lint
+    runs-on: ubuntu-latest
+
+    steps:
+      - name: Checkout code
+        uses: actions/checkout@v3
+
+      - name: Dagger
+        uses: dagger/dagger-for-github@v3
+        with:
+          cmds: |
+            project update
+            do check lint

.gitignore

@@ -1,3 +1,4 @@
+/.direnv/
 /tmp/
 /vendor/
 

Taskfile.yaml

@@ -0,0 +1,14 @@
+version: '3'
+
+tasks:
+  check:
+    cmds:
+      - dagger do check
+
+  lint:
+    cmds:
+      - dagger do check lint
+
+  fmt:
+    cmds:
+      - golangci-lint run --fix

ci/codecov/image.cue

@@ -0,0 +1,74 @@
+package codecov
+
+import (
+	"universe.dagger.io/docker"
+	// "universe.dagger.io/alpine"
+	"universe.dagger.io/bash"
+)
+
+// Build a codecov base image
+#Image: {
+	_packages: [pkgName=string]: {
+		// NOTE(samalba, gh issue #1532):
+		//   it's not recommended to pin the version as it is already pinned by the major Alpine version
+		//   version pinning is for future use (as soon as we support custom repositories like `community`,
+		//   `testing` or `edge`)
+		version: string | *""
+	}
+	_packages: {
+		bash:         _
+		curl:         _
+		git:          _
+		gnupg:        _
+		coreutils:    _
+		"perl-utils": _
+	}
+	docker.#Build & {
+		steps: [
+			// alpine.#Build & {
+			//  packages: {
+			//   bash:         _
+			//   curl:         _
+			//   gnupg:        _
+			//   coreutils:    _
+			//   "perl-utils": _
+			//  }
+			// },
+			docker.#Pull & {
+				source: "index.docker.io/alpine:3.15.0@sha256:21a3deaa0d32a8057914f36584b5288d2e5ecc984380bc0118285c70fa8c9300"
+			},
+			for pkgName, pkg in _packages {
+				docker.#Run & {
+					command: {
+						name: "apk"
+						args: ["add", "\(pkgName)\(pkg.version)"]
+						flags: {
+							"-U":         true
+							"--no-cache": true
+						}
+					}
+				}
+			},
+			bash.#Run & {
+				script: contents: """
+					curl https://keybase.io/codecovsecurity/pgp_keys.asc | gpg --no-default-keyring --keyring trustedkeys.gpg --import
+
+					curl -Os https://uploader.codecov.io/latest/alpine/codecov
+
+					curl -Os https://uploader.codecov.io/latest/alpine/codecov.SHA256SUM
+
+					curl -Os https://uploader.codecov.io/latest/alpine/codecov.SHA256SUM.sig
+
+					gpgv codecov.SHA256SUM.sig codecov.SHA256SUM
+
+					shasum -a 256 -c codecov.SHA256SUM
+
+					chmod +x codecov
+
+					mv codecov /usr/local/bin
+					rm codecov.SHA256SUM codecov.SHA256SUM.sig
+					"""
+			},
+		]
+	}
+}

ci/codecov/test/image.cue

@@ -0,0 +1,11 @@
+package codecov
+
+import (
+	"dagger.io/dagger"
+
+	"emperror.dev/errors/ci/codecov"
+)
+
+dagger.#Plan & {
+	actions: test: codecov.#Image & {}
+}

ci/codecov/upload.cue

@@ -0,0 +1,52 @@
+package codecov
+
+import (
+	"dagger.io/dagger"
+
+	"universe.dagger.io/docker"
+)
+
+#Upload: {
+	// Source code
+	source: dagger.#FS
+
+	// Coverage files
+	file: string
+
+	// Codecov token (required for local runs and private repos)
+	token?: dagger.#Secret
+
+	// Don't upload files to Codecov
+	dryRun: bool | *false
+
+	_image: #Image
+
+	_sourcePath: "/src"
+
+	docker.#Run & {
+		input: *_image.output | docker.#Image
+		command: {
+			name: "codecov"
+			flags: {
+				"--file":    file
+				"--verbose": true
+
+				if dryRun {
+					"--dryRun": true
+				}
+			}
+		}
+		env: {
+			if token != _|_ {
+				CODECOV_TOKEN: token
+			}
+		}
+		workdir: _sourcePath
+		mounts: {
+			"source": {
+				dest:     _sourcePath
+				contents: source
+			}
+		}
+	}
+}

cue.mod/.gitignore

@@ -0,0 +1,3 @@
+/gen/
+/pkg/
+/tmp/

cue.mod/dagger.mod

@@ -0,0 +1 @@
+github.com/sagikazarmark/dagger main

cue.mod/dagger.sum

@@ -0,0 +1 @@
+github.com/sagikazarmark/dagger h1:ekTs7tQbia01P9hMcMFSmA5TMFybb5F15Nlx8vYwU2g=

cue.mod/module.cue

@@ -0,0 +1 @@
+module: "emperror.dev/errors"

dagger.cue

@@ -0,0 +1,124 @@
+package main
+
+import (
+	"dagger.io/dagger"
+	"dagger.io/dagger/core"
+
+	"universe.dagger.io/go"
+
+	"github.com/sagikazarmark/dagger/go/golangci"
+	"emperror.dev/errors/ci/codecov"
+)
+
+dagger.#Plan & {
+	client: filesystem: ".": read: exclude: [
+		".github",
+		"bin",
+		"build",
+		"tmp",
+	]
+	client: network: "unix:///var/run/docker.sock": connect: dagger.#Socket
+	client: env: {
+		CI:                string | *""
+		GITHUB_ACTIONS:    string | *""
+		GITHUB_ACTION:     string | *""
+		GITHUB_HEAD_REF:   string | *""
+		GITHUB_REF:        string | *""
+		GITHUB_REPOSITORY: string | *""
+		GITHUB_RUN_ID:     string | *""
+		GITHUB_SERVER_URL: string | *""
+		GITHUB_SHA:        string | *""
+		GITHUB_WORKFLOW:   string | *""
+		CODECOV_TOKEN?:    dagger.#Secret
+	}
+
+	actions: {
+		_source: client.filesystem["."].read.contents
+
+		check: {
+			test: {
+				"go": {
+					"1.14": _
+					"1.15": _
+					"1.16": _
+					"1.17": _
+					"1.18": _
+
+					[v=string]: {
+						_test: go.#Test & {
+							source:  _source
+							name:    "go_test_\(v)" // necessary to keep cache for different versions separate
+							package: "./..."
+
+							_image: go.#Image & {
+								version: v
+							}
+
+							input: _image.output
+							command: flags: {
+								"-race":         true
+								"-covermode":    "atomic"
+								"-coverprofile": "/coverage.out"
+							}
+
+							export: files: "/coverage.out": _
+						}
+
+						_coverage: codecov.#Upload & {
+							_write: core.#WriteFile & {
+								input:    _source
+								path:     "/coverage.out"
+								contents: _test.export.files."/coverage.out"
+							}
+
+							source: _write.output
+							file:   "/src/coverage.out"
+
+							// Fixes https://github.com/dagger/dagger/issues/2680
+							// _env: client.env
+
+							// if _env.CODECOV_TOKEN != _|_ {
+							//  token: _env.CODECOV_TOKEN
+							// }
+
+							// Fixes https://github.com/dagger/dagger/issues/2680
+							_token: client.env.CODECOV_TOKEN
+
+							if client.env.CODECOV_TOKEN != _|_ {
+								token: client.env.CODECOV_TOKEN
+							}
+
+							dryRun: client.env.CI != "true"
+
+							// token: client.env.CODECOV_TOKEN
+
+							env: {
+								// if client.env.CODECOV_TOKEN != _|_ {
+								//  CODECOV_TOKEN: client.env.CODECOV_TOKEN
+								// }
+								GITHUB_ACTIONS:    client.env.GITHUB_ACTIONS
+								GITHUB_ACTION:     client.env.GITHUB_ACTION
+								GITHUB_HEAD_REF:   client.env.GITHUB_HEAD_REF
+								GITHUB_REF:        client.env.GITHUB_REF
+								GITHUB_REPOSITORY: client.env.GITHUB_REPOSITORY
+								GITHUB_RUN_ID:     client.env.GITHUB_RUN_ID
+								GITHUB_SERVER_URL: client.env.GITHUB_SERVER_URL
+								GITHUB_SHA:        client.env.GITHUB_SHA
+								GITHUB_WORKFLOW:   client.env.GITHUB_WORKFLOW
+							}
+						}
+
+						export: files: "/coverage.out": _test.export.files."/coverage.out"
+					}
+				}
+			}
+
+			lint: {
+				"golangci": golangci.#Lint & {
+					source:  _source
+					version: "1.46"
+				}
+			}
+		}
+	}
+}