Customizeable crash fixes

patches/rom_map/Bank 82.txt

@@ -1,21 +1,21 @@
 C262 - C27D: disableable_etanks.asm
-C27D - C298:
-C2A6 - C2B7:
+C27D - C298: vanilla_bugfixes.asm
+C2A6 - C2B7: split_speed.asm
 C362 - C369:
 C37E - C385:
 C3B6 - C3BD: map_area.asm
 C3C4 - C3D9: map_area.asm
 C411 - C42D: map_area.asm
-C42D - C465: 
+C42D - C465: split_speed.asm
 F70F - F810: map_area.asm
-F810 - F830: vanilla_bugfixes.asm
+F810 - F830: crash_handle_springball.asm
 F830 - F9E0: disable_etanks.asm
 F9E0 - FA00: reserve_backward_fill.asm
 FA00 - FA80: alternate_door_colors.asm
 FA80 - FA90: fix_water_fx_bug.asm
 FA90 - FBB0: seed_hash_display.asm
 FBB0 - FBF0: fix_kraid_hud.asm
-FBF0 - FC30: vanilla_bugfixes.asm
+FBF0 - FC30: crash_handle_autoreserve.asm
 FC30 - FC50: fix_transition_bad_tiles.asm
 FC50 - FCD0: map_area.asm
 FCD0 - FD00: escape.asm

patches/rom_map/Bank 83.txt

@@ -3,8 +3,7 @@ AD66 - AD72: escape_autosave.asm
 B000 - B700: [FREE]
 B700 - B800: rng_fix.asm
 B800 - BA00: Mosaic (Area FX.asm)
-BA00 - BA15: vanilla_bugfixes.asm
-BA15 - BB00: [FREE]
+BA00 - BB00: [FREE]
 BB00 - BC40: disableable_etanks.asm
 BC40 - E000: [FREE]
 E000 - F000: item_dots_disappear.asm

patches/rom_map/Bank 84.txt

@@ -1,3 +1,4 @@
+$858C - $85B2: vanilla_bugfixes.asm (unused vanilla code, repurposed for main street save station plm check.)
 $EFD3 - $EFD7: load_plms_early.asm
 $EFD7 - $F000: vanilla_bugfixes.asm
 $F000 - $F0E2: walljump_plm.asm

patches/rom_map/Bank 85.txt

@@ -16,7 +16,11 @@ $AA00 - $AAA0: pause_menu_objectives.asm
 $AAA0 - $AB00: [FREE]
 $AB00 - $ACA0: map_area.asm
 $ACA0 - $AD00: load_flash_suit
-$AD00 - $AE20: [FREE]
+$AD00 - $AD02: crash_handle_base.asm (crash toggles referenced by patch.rs )
+$AD02 - $AD45: crash_handle_springball.asm
+$AD45 - $AE20: [FREE]
 $AE20 - $B000: reserve_backward_fill.asm
-$B000 - $B600: vanilla_bugfixes.asm
+$B000 - $B5B4: crash_handle_base.asm
+$B5B4 - $B5F1: crash_handle_yapping.asm
+$B5F1 - $B600: [free]
 $B600 - $BA00: map_area.asm

patches/rom_map/Bank 90.txt

@@ -7,6 +7,6 @@ $F900 - $F910: escape_timer.asm
 $F980 - $FA00: respin.asm
 $FA00 - $FC00: map_progress_maintain.asm (list of cross-area tiles to reveal)
 $FC00 - $FC10: Fake Lava.asm
-$FC10 - $FC20: vanilla_bugfixes.asm
+$FC10 - $FC20: crash_handle_yapping.asm
 $FC20 - $FC40: remove_spikesuit.asm
 $FC40 - $FD00: split_speed.asm

patches/rom_map/Bank 91.txt

@@ -1,4 +1,4 @@
+95bc - 965a: {unused vanilla code - demo instructions} - crash_handle_xmode.asm 
 F7F4 - F88C: {unused vanilla code} - split_speed.asm
 FC42 - FC66: {unsued vanilla code} - split_speed.asm
-
-FFEE - FFFE: mosaic\fake lava.asm
+FFEE - FFFE: mosaic\fake lava.asm

patches/rom_map/RAM.txt

@@ -1,5 +1,6 @@
 $95: temporary variable (unused debug location) - used by extended messageboxes, safe to use outside message boxes.
 $9B: decompression.asm
+$CF: vanilla_bugfixes.asm (used by crash dialogues to prevent unpause from resetting gamestate.)
 $09EC: number of disabled ETanks (saved to SRAM)
 $0A1A: previous reserve health (reserve_hud.asm)
 $1F5B: map area (like $079F)

patches/src/crash_handle_autoreserves.asm

@@ -0,0 +1,49 @@
+;;; Fix auto-reserve / pause bug
+;;;
+;;; This patch will initiate the death sequence if pause hit with auto-reserve enabled
+;;; on exact frame that leads to crash.
+;;;
+;;; (thanks to Benox50 for his initial patch, nn44/aquanight for the light pillar fix)
+;;; 
+
+
+;;; these variable are defined by the crash_handle_base.asm patch and patch.rs
+
+!crash_toggles = $85AD00 
+!kill_samus = $85b5a0
+!bug_dialog = $85b000
+
+!bank_82_free_space_start = $82fbf0 ; pause / reserve bug
+!bank_82_free_space_end = $82fc30
+
+
+;;; vanilla hooks
+
+org $828b3f
+    jsr pause_func : nop          ; gamestate 1Ch (unused) handler
+
+
+;;; custom code
+
+org !bank_82_free_space_start
+pause_func:
+    lda !crash_toggles
+    and #$00F0
+    beq .default
+    cmp #$0020
+    beq .fix
+.warn
+    lda #$0041                    ; "fix" leaves the screen black like any pause close to fadeout, warning will relight the screen due to showing the dialog
+    jsl !bug_dialog
+.fix
+    lda #$0008
+    sta $0998
+    rts
+.default
+    lda #$0041                    ; msg ID
+    jsl !bug_dialog
+    jsl !kill_samus
+    stz $9d6                      ; clear reserve health
+    rts
+
+assert pc() <= !bank_82_free_space_end

patches/src/crash_handle_base.asm

@@ -0,0 +1,179 @@
+;;; crash handler (displays a custom message box explaining the crash)
+;;; StagShot, toggle modifications - nn_357
+;;;
+;;; Implementation of custom dialog boxes
+;;; Requires hooking multiple functions to support extended msg IDs (0x40+)
+;;; and additional lookup tables
+;;; 
+;;; This code is used by other patches that handle hardlocks caused by the unequip springball, frame perfect pause on autoreserve trigger, yappingmaw shinespark
+;;; X-mode solid tile collision.
+
+arch snes.cpu
+lorom
+
+!bank_85_free_space_start = $85b000 ; be careful if moving this, the subpatches that use this code assume this location (xmode/oob/yappingmaw/autoreserve/springball)
+!bank_85_free_space_end = $85b5a0
+
+!bank_85_free_space2_start = $85b5a0 ; kill samus routine, location called by sub patches, as above, be careful if ever moving this code and update subpatches.
+!bank_85_free_space2_end = $85b5b4
+
+!msg_crash_timer_override = $7EF596 ; temporary variable used for overriding messagebox close delay times during crash box.
+!crash_toggles = $85ad00  ; this location is looked at by the subpatches to decide if to call the handler etc.
+
+org !crash_toggles
+    dw $0000    ; overwritten by patch.rs if any values are changed, subpatches reference this. default is gameover / death (pre-toggleable setting)
+
+;;; hooks into vanilla code
+
+org $858493     ; override messagebox delay if crash dialog 
+    jsr hook_msgbox_delay
+
+org $858093
+    jsr hook_message_box
+
+org $8582e5
+    jsr hook_index_lookup
+
+org $8582ee
+    jsr hook_message_table
+
+org $85840c     ; hook unpause to prevent resetting gamestate to 8 if crash ID set
+    jsr hook_button_lookup
+
+;;; custom code
+
+org !bank_85_free_space_start
+bug_dialog:                 ; A = msg ID
+    and #$00ff
+    pha
+    sep #$20
+    lda #$0f                ; restore screen brightness to full
+    sta $51
+    sta !msg_crash_timer_override   ; messagebox timer will check if this is 0 (if its non zero load a longer time)
+    rep #$30
+    jsl $808338             ; wait for NMI
+
+    pla                     ; dlg box parameter
+    jsl $858080             ; dlg box
+    cmp #$0044
+    bne .skipkill           ; oob death (dlg 44) is removable via major glitches patch, if its thrown then the intent is to kill as it isn't toggleable.
+    jsl kill_samus
+.skipkill
+    rtl
+
+hook_message_box:
+    rep #$30
+    lda $1c1f
+    cmp #$0040              ; custom boxes >= 0x40
+    bcs .custom
+    jmp $8241               ; original func
+
+.custom
+    ldx #(new_message_boxes-$869b) ; ptr for extended lookup table
+    jmp $824f
+
+hook_index_lookup:
+    lda $1c1f
+    cmp #$0040
+    bcs .custom
+    rts
+
+.custom
+    sec
+    sbc #$0040
+    rts
+
+hook_message_table:
+    adc $34                         ; replaced code
+    tax                             ;
+    lda $1c1f
+    cmp #$0040
+    bcs .custom
+    rts
+
+.custom
+    txa
+    clc
+    adc #(new_message_boxes-$869b)  ; adjust ptr for extended table
+    tax
+    rts
+
+hook_button_lookup:
+    lda $1c1f
+    cmp #$0040
+    bcs .custom
+    rts
+
+.custom
+    lda #$0001                      ; blank button tilemap
+    ldy #(reserve_pause_msg-$8426)  ; blank button letter
+    rts
+
+hook_msgbox_delay: 
+    pha
+    lda !msg_crash_timer_override
+    beq .nochange
+    ldx #$005a ; (put 1.5 seconds on the clock) 
+    lda #$00
+    sta !msg_crash_timer_override ; clear our special variable so then next msgbox will have whatever timer was set on generation
+.nochange
+    pla
+    jsr $8136  ; hi-jacked instruction.
+    rts
+
+; custom messages start at 0x41
+new_message_boxes:
+    dw $83c5, $825a, reserve_pause_msg  ; 0x41
+    dw $83c5, $825a, springball_msg     ; 0x42
+    dw $83c5, $825a, yapping_maw_msg    ; 0x43
+    dw $83c5, $825a, oob_msg            ; 0x44
+    dw $83c5, $825a, xmode_msg          ; 0x45
+    dw $0000, $0000, msg_end
+
+table "tables/dialog_chars.tbl",RTL
+
+reserve_pause_msg:
+    dw $000e,$000e,$000e, "        GAME CRASH!       ", $000e,$000e,$000e
+    dw $000e,$000e,$000e, "                          ", $000e,$000e,$000e
+    dw $000e,$000e,$000e, "   PAUSED ON EXACT FRAME  ", $000e,$000e,$000e
+    dw $000e,$000e,$000e, "   AUTO-REFILL STARTED!   ", $000e,$000e,$000e
+
+springball_msg:
+    dw $000e,$000e,$000e, "        GAME CRASH!       ", $000e,$000e,$000e
+    dw $000e,$000e,$000e, "                          ", $000e,$000e,$000e
+    dw $000e,$000e,$000e, "  UNEQUIPPED SPRING BALL  ", $000e,$000e,$000e
+    dw $000e,$000e,$000e, "   IN NEUTRAL BOUNCE!     ", $000e,$000e,$000e
+
+yapping_maw_msg:
+    dw $000e,$000e,$000e, "        GAME CRASH!       ", $000e,$000e,$000e
+    dw $000e,$000e,$000e, "                          ", $000e,$000e,$000e
+    dw $000e,$000e,$000e, "  YAPPING MAW SHINESPARK  ", $000e,$000e,$000e
+    dw $000e,$000e,$000e, " END WITH NO INPUTS HELD! ", $000e,$000e,$000e
+
+oob_msg:
+    dw $000e,$000e,$000e, "                          ", $000e,$000e,$000e
+    dw $000e,$000e,$000e, "   SAMUS OUT-OF-BOUNDS!   ", $000e,$000e,$000e
+    dw $000e,$000e,$000e, "                          ", $000e,$000e,$000e
+    dw $000e,$000e,$000e, "                          ", $000e,$000e,$000e
+
+xmode_msg:
+    dw $000e,$000e,$000e, "        GAME CRASH!       ", $000e,$000e,$000e
+    dw $000e,$000e,$000e, "                          ", $000e,$000e,$000e
+    dw $000e,$000e,$000e, "   X-MODE TILE COLLISION  ", $000e,$000e,$000e
+    dw $000e,$000e,$000e, "COLLIDED WITH A SOLID TILE", $000e,$000e,$000e
+
+msg_end:
+
+assert pc() <= !bank_85_free_space_end
+
+org !bank_85_free_space2_start
+kill_samus:
+    lda #$8000            ; init death sequence (copied from $82db80)
+    sta $a78
+    lda #$0011
+    jsl $90f084
+    lda #$0013              ; set gamestate
+    sta $998
+    rtl
+
+assert pc() <= !bank_85_free_space2_end

patches/src/crash_handle_springball.asm

@@ -0,0 +1,86 @@
+;;; Spring ball menu crash fix by strotlog.
+;;; Fix obscure vanilla bug where: turning off spring ball while bouncing, can crash in $91:EA07,
+;;; or exactly the same way as well in $91:F1FC.
+;;; Adapted for map rando by Stag Shot:
+;;; toggle-modifications nn_357.
+
+arch snes.cpu
+lorom
+
+;;; these variable are defined by the crash_handle_base.asm patch and patch.rs
+
+!crash_toggles = $85AD00 
+!kill_samus = $85b5a0
+!bug_dialog = $85b000
+
+!bank_82_free_space2_start = $82f810 ; hook unpause (springball crash)
+!bank_82_free_space2_end = $82f830
+
+!bank_85_free_space_start = $85ad04
+!bank_85_free_space_end = $85ad45
+
+;;; vanilla hooks
+
+org $8293bb
+    jmp check_unpause
+
+org $91ea07
+    jsl spring_ball_crash
+
+org $91f1fc
+    jsl spring_ball_crash
+
+;;; custom code
+
+
+org !bank_82_free_space2_start
+check_unpause:
+    php
+    sep #$20
+    lda $00cf               ; pending crash ID
+    stz $00cf
+    cmp #$42                ; springball?
+    bne .skip
+    plp
+    jmp $93c1               ; skip changing gamestate
+.skip
+    plp
+    lda #$0008              ; replaced code
+    jmp $93be
+
+assert pc() <= !bank_82_free_space2_end
+
+
+org !bank_85_free_space_start
+spring_ball_crash:
+    lda $0B20               ; morph bounce state
+    cmp #$0600              ; bugged?
+    bcc .skip
+    lda !crash_toggles
+    and #$000F
+    beq .default
+    cmp #$0002
+    beq .fix
+.warn
+    lda #$0042
+    jsl !bug_dialog
+.fix
+    lda #$0000
+    stz $0b20
+    rtl
+.default
+    sep #$20
+    lda #$42                ; bug ID
+    sta $00cf               ; set flag to prevent unpause from resetting gamestate to 8
+    rep #$30
+    jsl !bug_dialog
+    jsl !kill_samus
+    lda #$0000
+    stz $0B20
+    rtl
+.skip
+    lda $0B20               ; replaced code
+    asl                     ;
+    rtl
+
+assert pc() <= !bank_85_free_space_end