added accelerometer examples

Author: tigoe

LIS3DHAccelerometer/LIS3DHAccelerometer.ino

@@ -0,0 +1,49 @@
+/*
+    Simplified example for the Adafruit LIS3DH accelerometer
+    breakout board (https://www.adafruit.com/products/2809)
+    based on Kevin Townsend's sample code.
+
+    Note: this code sets the accelerometer to 2G (aka 2x the acceleration
+    due to gravity). The accelerometer has a 14-bit range, or -8193 to 8192.
+    So at 1G, when the full force of gravity is on one of the axes,
+    the reading should be around 4095 for that axis (or -4096, depending on
+    the orientation).
+
+    modified 24 Nov 2015
+    by Tom Igoe
+*/
+
+#include <Wire.h>
+#include <Adafruit_LIS3DH.h>
+
+Adafruit_LIS3DH accelerometer = Adafruit_LIS3DH();
+
+void setup() {
+  Serial.begin(9600);
+  while (!Serial);
+  if (! accelerometer.begin(0x18)) {
+    Serial.println("Couldn't start. Check wiring.");
+    while (true);     // stop here and do nothing
+  }
+
+  accelerometer.setRange(LIS3DH_RANGE_2_G);   // 2, 4, 8 or 16 G!
+  Serial.print(accelerometer.getRange());
+}
+
+void loop() {
+  accelerometer.read();      // get X Y and Z data at once
+  // Then print out the raw data
+    Serial.print(convertReading(accelerometer.x));
+    Serial.print(",");
+    Serial.print(convertReading(accelerometer.y));
+    Serial.print(",");
+    Serial.println(convertReading(accelerometer.z));
+    
+}
+
+float convertReading(int reading) {
+  float divisor = 2 << (13 - accelerometer.getRange());
+  float acceleration = (float)reading / divisor;
+  return acceleration;
+}
+

LIS3DHAccelerometerADC/LIS3DHAccelerometerADC.ino

@@ -0,0 +1,52 @@
+/*
+    Simplified example for the Adafruit LIS3DH accelerometer
+    breakout board (https://www.adafruit.com/products/2809)
+    based on Kevin Townsend's sample code.
+
+    Note: this code sets the accelerometer to 2G (aka 2x the acceleration
+    due to gravity). The accelerometer has a 14-bit range, or -8193 to 8192.
+    So at 1G, when the full force of gravity is on one of the axes,
+    the reading should be around 4095 for that axis (or -4096, depending on
+    the orientation).
+
+    modified 24 Nov 2015
+    by Tom Igoe
+*/
+
+#include <Wire.h>
+#include <Adafruit_LIS3DH.h>
+
+Adafruit_LIS3DH accelerometer = Adafruit_LIS3DH();
+
+void setup() {
+  Serial.begin(9600);
+  if (! accelerometer.begin(0x18)) {
+    Serial.println("Couldn't start. Check wiring.");
+    while (true);     // stop here and do nothing
+  }
+
+  accelerometer.setRange(LIS3DH_RANGE_2_G);   // 2, 4, 8 or 16 G!
+
+}
+
+void loop() {
+  int adc;
+  float volt;
+  String output;
+  // read the ADCs
+  for (int channel = 1; channel < 4; channel++) {
+    adc = accelerometer.readADC(channel);
+    // LIS3DH ADCs are only sensitive in a range from 1.7V to 0.9V:
+    volt = map(adc, -32512, 32512, 1700, 900);
+    output = "ADC ";
+    output += channel;
+    output += ": ";
+    output += adc;
+    output += "  ";
+    output += volt;
+    output += " mV\t";
+    Serial.print(output);
+    delay(10);
+  }
+  Serial.println();
+}

LIS3DHAccelerometerTap/LIS3DHAccelerometerTap.ino

@@ -0,0 +1,73 @@
+/*
+    Simplified tap example for the Adafruit LIS3DH accelerometer
+    breakout board (https://www.adafruit.com/products/2809)
+    based on Kevin Townsend's sample code.
+
+    modified 22 Jan 2016
+    by Tom Igoe
+*/
+
+#include <Wire.h>
+#include <Adafruit_LIS3DH.h>
+
+Adafruit_LIS3DH accelerometer = Adafruit_LIS3DH();
+// Adjust this number for the sensitivity of the 'click' force
+// this strongly depend on the range! for 16G, try 5-10
+// for 8G, try 10-20. for 4G try 20-40. for 2G try 40-80
+#define CLICKTHRESHHOLD 40
+
+long steps = 0;
+
+void setup() {
+  Serial.begin(9600);
+  // 0x18 is the accelerometer's default I2C address:
+  if (! accelerometer.begin(0x18)) {
+    Serial.println("Couldn't start. Check wiring.");
+    while (true);     // stop here and do nothing
+  }
+  // accelerometer range can be 2, 4, 8, or 16G:
+  accelerometer.setRange(LIS3DH_RANGE_2_G);
+
+  // 0 = turn off click detection & interrupt
+  // 1 = single click only interrupt output
+  // 2 = double click only interrupt output, detect single click
+  // Adjust threshhold, higher numbers are less sensitive
+  accelerometer.setClick(1, CLICKTHRESHHOLD);
+  delay(100);
+}
+
+void loop() {
+
+  /*
+   * Each bit of the click byte value means something different: 
+   * bit 0: there's been a tap on the X axis
+   * bit 1: tap on the Y axis
+   * bit 2: tap on the Z axis
+   * bit 3: direction of the tap
+   * bit 4: enable single click detection
+   * bit 5: enable double click detection
+   * 
+   * The example below prints out the click value in binary,
+   * so you can see each bit in action. Try tapping on all three
+   * axes to see how it works:
+   */
+  byte click = accelerometer.getClick();
+  if (click > 0) {
+    // print the whole byte in binary:
+    Serial.println(click, BIN);
+    // print which axis was tapped:
+    if (bitRead(click, 0) == 1) {
+      Serial.println("tap on X axis");
+    }
+    if (bitRead(click, 1) == 1) {
+      Serial.println("tap on Y axis");
+    }
+    if (bitRead(click, 2) == 1) {
+      Serial.println("tap on Z axis");
+    }
+  }
+
+  // adjust the delay depending on how frequently you
+  // plan to detect clicks. For a step detector, 30 - 80 ms works:
+  delay(30);
+}

MMA8451Accelerometer/MMA8451Accelerometer.ino

@@ -0,0 +1,43 @@
+/* 
+    Simplified example for the Adafruit MMA8451 accelerometer
+    breakout board (https://www.adafruit.com/products/2019)
+    based on Kevin Townsend's sample code.
+
+    Note: this code sets the accelerometer to 2G (aka 2x the acceleration
+    due to gravity). The accelerometer has a 14-bit range, or -8193 to 8192.
+    So at 1G, when the full force of gravity is on one of the axes, 
+    the reading should be around 4095 for that axis (or -4096, depending on 
+    the orientation).
+
+    modified 23 Nov 2015
+    by Tom Igoe
+*/
+
+#include <Wire.h>
+#include <Adafruit_MMA8451.h>
+
+Adafruit_MMA8451 mma = Adafruit_MMA8451();
+
+void setup(void) {
+  Serial.begin(9600);
+// initialize communications with the accelerometer:
+  if (! mma.begin()) {
+    Serial.println("Couldnt start. Check wiring the to the sensor.");
+    while (true);   // stop here and do nothing else
+  }
+  // set accelerometer range to 2G max:
+  mma.setRange(MMA8451_RANGE_2_G);
+}
+
+void loop() {
+  // Read the accelerometer data
+  // (ranges from -8193 to 8192 at max acceleration):
+  mma.read();
+  Serial.print("X: ");
+  Serial.print(mma.x);
+  Serial.print("\tY: ");
+  Serial.print(mma.y);
+  Serial.print("\tZ: ");
+  Serial.println(mma.z);
+
+}