build.gradle

plugins {
    id 'java-library'
    id 'eclipse'
    id 'idea'
    id 'maven-publish'
    id 'net.neoforged.moddev' version '2.0.140'
}

version = mod_version
group = mod_group_id

base {
    archivesName = "${mod_id}-${minecraft_version}"
}

java.toolchain.languageVersion = JavaLanguageVersion.of(21)

println "Java: ${System.getProperty 'java.version'}, JVM: ${System.getProperty 'java.vm.version'} (${System.getProperty 'java.vendor'}), Arch: ${System.getProperty 'os.arch'}"

sourceSets.main.resources { srcDir 'src/generated/resources' exclude(".cache")}

repositories {
    maven {
        url "https://www.cursemaven.com"
        content {
            includeGroup "curse.maven"
        }
    }
    maven {
        url = "https://maven.theillusivec4.top/"
    }

    maven { url = "https://maven.bawnorton.com/releases" }

}

neoForge {
    version = project.neo_version

    parchment {
        mappingsVersion = project.parchment_mappings_version
        minecraftVersion = project.parchment_minecraft_version
    }

    runs {
        client {
            client()
            systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
        }

        server {
            server()
            programArgument '--nogui'
            systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
        }

        gameTestServer {
            type = "gameTestServer"
            systemProperty 'neoforge.enabledGameTestNamespaces', project.mod_id
        }

        data {
            data()
            programArguments.addAll '--mod', project.mod_id, '--all', '--output', file('src/generated/resources/').getAbsolutePath(), '--existing', file('src/main/resources/').getAbsolutePath()
        }

        configureEach {
            systemProperty 'forge.logging.markers', 'REGISTRIES'

            jvmArgument("-XX:+IgnoreUnrecognizedVMOptions")
            jvmArgument("-XX:+AllowEnhancedClassRedefinition")
            systemProperty("mixin.debug.export", "true")
            if (it.name.startsWith("client")) {
                programArguments.addAll("--width", "1920", "--height", "1080")
            }
            logLevel = org.slf4j.event.Level.DEBUG
        }
    }

    mods {
        "${mod_id}" {
            sourceSet(sourceSets.main)
        }
    }
}

configurations {
    runtimeClasspath.extendsFrom localRuntime
}
dependencies {
    // Jars in "libs" folder
    implementation fileTree('libs') { include '*.jar'}

    // MixinSquared
    compileOnly(annotationProcessor("com.github.bawnorton.mixinsquared:mixinsquared-common:0.3.7-beta.1"))
    jarJar(implementation("com.github.bawnorton.mixinsquared:mixinsquared-neoforge:0.3.7-beta.1")) {
        version {
            strictly "[0.3.7-beta.1,)"
            prefer "0.3.7-beta.1"
        }
    }

    compileOnly "curse.maven:no-chat-reports-634062:5441267"
    compileOnly "curse.maven:villages-and-pillages-915531:5615165"
    compileOnly "com.yungnickyoung.minecraft.yungsapi:YungsApi:1.21.1-NeoForge-5.1.3"

    runtimeOnly "curse.maven:sodium-394468:6382651"
    implementation "curse.maven:irisshaders-455508:6661598"

    implementation "curse.maven:better-compatibility-checker-551894:7170665"
    implementation "curse.maven:${pipez}"
    implementation "curse.maven:yacl-667299:6336630"
    compileOnly("curse.maven:xycraft-machines-653791:5601045")
    implementation "curse.maven:modernfix-790626:7200212"
    implementation "curse.maven:berry-pouch-1246510:7310810"
    implementation "curse.maven:applied-energistics-2-223794:7027323"
    implementation "curse.maven:just-dire-things-1002348:7463040"
}

var generateModMetadata = tasks.register("generateModMetadata", ProcessResources) {
    var replaceProperties = [
            minecraft_version      : minecraft_version,
            minecraft_version_range: minecraft_version_range,
            neo_version            : neo_version,
            neo_version_range      : neo_version_range,
            loader_version_range   : loader_version_range,
            mod_id                 : mod_id,
            mod_name               : mod_name,
            mod_license            : mod_license,
            mod_version            : mod_version,
            mod_authors            : mod_authors,
            mod_description        : mod_description
    ]
    inputs.properties replaceProperties
    expand replaceProperties
    from "src/main/templates"
    into "build/generated/sources/modMetadata"
}
sourceSets.main.resources.srcDir generateModMetadata
neoForge.ideSyncTask generateModMetadata

jar {
    manifest {
        attributes([
                "Specification-Title"     : mod_id,
                "Specification-Vendor"    : group,
                "Specification-Version"   : "1", // We are version 1 of ourselves
                "Implementation-Title"    : project.name,
                "Implementation-Version"  : project.jar.archiveVersion,
                "MixinConfigs": "${mod_id}.mixins.json"
        ])
    }

    preserveFileTimestamps = false
    reproducibleFileOrder = true
}

publishing {
    publications {
        register('mavenJava', MavenPublication) {
            artifactId = mod_id
            from components.java
        }
    }
    repositories {
        maven {
            url "file://${project.projectDir}/repo"
        }
    }
}

tasks.withType(JavaCompile).configureEach {
    options.encoding = 'UTF-8' // Use the UTF-8 charset for Java compilation
}

// IDEA no longer automatically downloads sources/javadoc jars for dependencies, so we need to explicitly enable the behavior.
idea {
    module {
        downloadSources = true
        downloadJavadoc = true
    }
}