Windows - Task :pbandk:generateProto does not finish

[mcpiroman]

I've cloned the repo (commit bd1fe1a) and built locally. Then, in a project I use it as described in readme. When building the project the task :pbandk:generateProto runs endlessly (at least 10 minutes) while the processor is idle.

My build.gradle.kts:

import com.google.protobuf.gradle.*

plugins {
    kotlin("jvm")
    id("java")
    id("com.google.protobuf") version "0.8.17"
}

val protocVersion = "3.18.0"

dependencies {
    implementation("com.google.protobuf:protobuf-java:$protocVersion")
    implementation("pro.streem.pbandk:pbandk-runtime:0.11.0")
    protobuf(files("../proto"))
}

protobuf {
    protoc {
        path = "<local path>/pbandk/protoc-gen-pbandk/jvm/build/install/protoc-gen-pbandk/bin/protoc-gen-pbandk.bat"
    }
}

[garyp]

I think you're configuring the protobuf gradle plugin incorrectly. With this configuration:

protobuf {
    protoc {
        path = "<local path>/pbandk/protoc-gen-pbandk/jvm/build/install/protoc-gen-pbandk/bin/protoc-gen-pbandk.bat"
    }
}

the gradle plugin is trying to use protoc-gen-pbandk instead of protoc. protoc-gen-pbandk is not a replacement for protoc, it is a plugin that is called by protoc.

You can see an example of how to use pbandk with the protobuf gradle plugin at https://github.com/streem/pbandk/blob/master/examples/gradle-and-jvm/build.gradle.kts. For your project, you probably want something like this in your build.gradle.kts file:

protobuf {
    protoc {
        artifact = "com.google.protobuf:protoc:$protocVersion"
    }
    plugins {
        id("pbandk") {
            path = "<local path>/pbandk/protoc-gen-pbandk/jvm/build/install/protoc-gen-pbandk/bin/protoc-gen-pbandk.bat"
        }
    }
    generateProtoTasks {
        ofSourceSet("main").forEach { task ->
            task.builtins {
                remove("java")
            }
            task.plugins {
                id("pbandk") {}
            }
        }
    }
}

P.S. you don't need a dependency on implementation("com.google.protobuf:protobuf-java:$protocVersion") in your project unless you are generating both Java and Kotlin code from your proto files (and if you are generating both then you'll want to get rid of remove("java") in my example above.

[mcpiroman]

Many thanks!