build.gradle

group 'nl.martijndwars'
version '1.0.0'

apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'signing'

sourceCompatibility = 1.8
targetCompatibility = 1.8

jar {
    baseName = 'web-push'
    version = '1.0.0'
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives jar

    archives javadocJar
    archives sourcesJar
}

signing {
    required { gradle.taskGraph.hasTask("uploadArchives") }
    sign configurations.archives
}

uploadArchives {
  repositories {
    mavenDeployer {
      beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

      repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
        authentication(userName: hasProperty('ossrhUsername')?ossrhUsername:'', password: hasProperty('ossrhPassword')?ossrhPassword:'')
      }

      snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
        authentication(userName: hasProperty('ossrhUsername')?ossrhUsername:'', password: hasProperty('ossrhPassword')?ossrhPassword:'')
      }

      pom.project {
        name 'web-push'
        packaging 'jar'
        description 'A Web Push library for Java.'
        url 'https://github.com/MartijnDwars/web-push'

        scm {
          connection 'scm:git:git@github.com:MartijnDwars/web-push.git'
          developerConnection 'scm:git:git@github.com:MartijnDwars/web-push.git'
          url 'git@github.com:MartijnDwars/web-push.git'
        }

        licenses {
          license {
            name 'MIT License'
            url 'https://opensource.org/licenses/MIT'
          }
        }

        developers {
          developer {
            id 'martijndwars'
            name 'Martijn Dwars'
            email 'ikben@martijndwars.nl'
          }
        }
      }
    }
  }
}

repositories {
    mavenCentral()
}

dependencies {
    compile group: 'org.apache.httpcomponents', name: 'fluent-hc', version: '4.5.2'
    compile group: 'com.google.guava', name: 'guava', version: '19.0'
    compile group: 'org.bouncycastle', name: 'bcprov-jdk15on', version: '1.54'
    compile group: 'org.json', name: 'json', version: '20160212'

    testCompile group: 'junit', name: 'junit', version: '4.11'
}