AnalyzerSDK/AnalyzerSDKConfig.cmake at master · saleae/AnalyzerSDK · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
add_library(Saleae::AnalyzerSDK SHARED IMPORTED)
set_target_properties(Saleae::AnalyzerSDK PROPERTIES INTERFACE_INCLUDE_DIRECTORIES ${CMAKE_CURRENT_LIST_DIR}/include)

if(CMAKE_SIZEOF_VOID_P STREQUAL "4")
    message(FATAL_ERROR "Analyzer SDK only supports 64 bit builds")
endif()

if (APPLE)
    if("${CMAKE_OSX_ARCHITECTURES}" STREQUAL "arm64")
        set(LIB_DIR "lib_arm64")
    elseif("${CMAKE_OSX_ARCHITECTURES}" STREQUAL "x86_64")
        set(LIB_DIR "lib_x86_64")
    elseif(CMAKE_OSX_ARCHITECTURES STREQUAL "")
        message("CMAKE_OSX_ARCHITECTURES not set, defaulting to system processor")
        set(LIB_DIR "lib_${CMAKE_SYSTEM_PROCESSOR}")
    else()
        message(FATAL_ERROR "Universal Binaries are not supported. Either set CMAKE_OSX_ARCHITECTURES to a single supported platform, or do not set it.")
    endif()

    message("LIB_DIR: ${LIB_DIR}")
    set_target_properties(Saleae::AnalyzerSDK PROPERTIES
                                              IMPORTED_LOCATION ${CMAKE_CURRENT_LIST_DIR}/${LIB_DIR}/libAnalyzer.dylib)
else()
    if(CMAKE_SYSTEM_PROCESSOR STREQUAL "aarch64" OR CMAKE_SYSTEM_PROCESSOR STREQUAL "ARM64")
        set(LIB_DIR "lib_arm64")
    elseif(CMAKE_SYSTEM_PROCESSOR STREQUAL "x86_64" OR CMAKE_SYSTEM_PROCESSOR STREQUAL "AMD64")
        set(LIB_DIR "lib_x86_64")
    else()
        message(FATAL_ERROR "Unsupported architecture: ${CMAKE_SYSTEM_PROCESSOR}. Only x86_64/AMD64 and aarch64/ARM64 are supported.")
    endif()
    if(WIN32)
        set_target_properties(Saleae::AnalyzerSDK PROPERTIES
                                                IMPORTED_LOCATION ${CMAKE_CURRENT_LIST_DIR}/${LIB_DIR}/Analyzer.dll
                                                IMPORTED_IMPLIB   ${CMAKE_CURRENT_LIST_DIR}/${LIB_DIR}/Analyzer.lib)
    elseif(UNIX AND NOT APPLE)

        set_target_properties(Saleae::AnalyzerSDK PROPERTIES
                                                IMPORTED_LOCATION ${CMAKE_CURRENT_LIST_DIR}/${LIB_DIR}/libAnalyzer.so
                                                IMPORTED_SONAME   libAnalyzer.so)
    endif()
endif()