DRAFT WebSockets examples

Author: pschatzmann

examples/examples-communication/websockets/client-send/client/client.ino

@@ -0,0 +1,45 @@
+/**
+ * @brief A simple WebSocket client sketch that sends out some PCM audio
+ * data using the https://github.com/Links2004/arduinoWebSockets library
+ * @author Phil Schatzmann
+ */
+
+#include <WebSocketsClient.h>  // https://github.com/Links2004/arduinoWebSockets
+#include <WiFiMulti.h>
+
+#include "AudioTools.h"
+#include "AudioTools/Communication/WebSocketOutput.h"
+
+// websocket
+WiFiMulti WiFiMulti;
+WebSocketsClient webSocket;
+WebSocketOutput out(webSocket);
+// audio
+AudioInfo info(44100, 2, 16);
+SineWaveGenerator<int16_t> sineWave(32000);
+GeneratedSoundStream<int16_t> sound(sineWave);
+StreamCopy copier(out, sound);
+
+void setup() {
+  Serial.begin(115200);
+
+  // connect to wifi
+  WiFiMulti.addAP("SSID", "passpasspass");
+  while (WiFiMulti.run() != WL_CONNECTED) {
+    delay(100);
+  }
+
+  // connect to server address, port and URL
+  webSocket.begin("192.168.0.123", 81, "/");
+
+  // try ever 5000 again if connection has failed
+  webSocket.setReconnectInterval(5000);
+
+  sineWave.begin(info, N_B4);
+}
+
+void loop() {
+  webSocket.loop();
+  // generate audio only when we are connected
+  if (webSocket.isConnected()) copier.copy();
+}

examples/examples-communication/websockets/client-send/server/server.ino

@@ -0,0 +1,46 @@
+/**
+ * @brief A simple WebSocket server sketch that receives PCM audio data using the
+ * https://github.com/Links2004/arduinoWebSockets library and outputs it via i2s
+ * to an AudioKit for easy testing. Replace the output with whatever other class
+ * you like.
+ * @author Phil Schatzmann
+ */
+#include <WebSocketsServer.h>  //https://github.com/Links2004/arduinoWebSockets
+#include <WiFi.h>
+#include <WiFiClientSecure.h>
+#include <WiFiMulti.h>
+
+#include "AudioTools.h"
+
+WiFiMulti WiFiMulti;
+WebSocketsServer webSocket(81);
+AudioInfo info(44100, 2, 16);
+AudioBoardStream i2s(AudioKitEs8388V1);  // Access I2S as stream
+
+/// Just output the audio data
+void webSocketEvent(uint8_t num, WStype_t type, uint8_t* payload,
+                    size_t length) {
+  if (type == WStype_BIN) {
+    i2s.write(payload, length);
+  }
+}
+
+void setup() {
+  Serial.begin(115200);
+  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Info);
+
+  WiFiMulti.addAP("SSID", "passpasspass");
+  while (WiFiMulti.run() != WL_CONNECTED) {
+    delay(100);
+  }
+
+  webSocket.begin();
+  webSocket.onEvent(webSocketEvent);
+
+  // start i2s
+  auto cfg = i2s.defaultConfig(TX_MODE);
+  cfg.copyFrom(info);
+  i2s.begin(cfg);
+}
+
+void loop() { webSocket.loop(); }

examples/examples-communication/websockets/server-send/client/client.ino

@@ -0,0 +1,57 @@
+/**
+ * @brief A simple WebSocket client sketch that receives PCM audio data using the
+ * https://github.com/Links2004/arduinoWebSockets library and outputs it via i2s
+ * to an AudioKit for easy testing. Replace the output with whatever other class
+ * you like.
+ * @author Phil Schatzmann
+ */
+#include <WebSocketsClient.h>  // https://github.com/Links2004/arduinoWebSockets
+#include <WiFiMulti.h>
+
+#include "AudioTools.h"
+#include "AudioTools/Communication/WebSocketOutput.h"
+
+// websocket
+WiFiMulti WiFiMulti;
+WebSocketsClient webSocket;
+WebSocketOutput out(webSocket);  // or replace with I2SStream
+// audio
+AudioInfo info(44100, 2, 16);
+AudioBoardStream i2s(AudioKitEs8388V1);  // Access I2S as stream
+
+// write audio to i2s
+void webSocketEvent(WStype_t type, uint8_t* payload, size_t length) {
+  if (type == WStype_BIN) {
+    i2s.write(payload, length);
+  }
+}
+
+void setup() {
+  Serial.begin(115200);
+  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Info);
+
+  // connect to wifk
+  WiFiMulti.addAP("SSID", "passpasspass");
+  while (WiFiMulti.run() != WL_CONNECTED) {
+    delay(100);
+  }
+
+  // server address, port and URL
+  webSocket.begin("192.168.0.123", 81, "/");
+
+  // event handler
+  webSocket.onEvent(webSocketEvent);
+
+  // try ever 5000 again if connection has failed
+  webSocket.setReconnectInterval(5000);
+
+  // start i2s
+  auto cfg = i2s.defaultConfig(TX_MODE);
+  cfg.copyFrom(info);
+  i2s.begin(cfg);
+}
+
+void loop() {
+  webSocket.loop();
+  copier.copy();
+}

examples/examples-communication/websockets/server-send/server/server.ino

@@ -0,0 +1,46 @@
+/**
+ * @brief A simple WebSocket server sketch using the
+ * https://github.com/Links2004/arduinoWebSockets library to send out some
+ * PCM audio data when some clients are connnected.
+ * @author Phil Schatzmann
+ */
+
+#include <WebSocketsServer.h>  // https://github.com/Links2004/arduinoWebSockets
+#include <WiFi.h>
+#include <WiFiMulti.h>
+
+#include "AudioTools.h"
+#include "AudioTools/Communication/WebSocketOutput.h"
+
+WiFiMulti WiFiMulti;
+WebSocketsServer webSocket(81);
+WebSocketOutput out(webSocket);
+
+// audio
+AudioInfo info(44100, 2, 16);
+SineWaveGenerator<int16_t> sineWave(32000);
+GeneratedSoundStream<int16_t> sound(sineWave);
+StreamCopy copier(out, sound);  // copies sound into i2s
+
+void setup() {
+  // Serial.begin(921600);
+  Serial.begin(115200);
+  AudioToolsLogger.begin(Serial, AudioToolsLogLevel::Info);
+
+  // connect to wifi
+  WiFiMulti.addAP("SSID", "passpasspass");
+  while (WiFiMulti.run() != WL_CONNECTED) {
+    delay(100);
+  }
+
+  webSocket.begin();
+
+  // start i2s
+  sineWave.begin(info, N_B4);
+}
+
+void loop() {
+  webSocket.loop();
+  // generate audio only when we have any clients
+  if (webSocket.connectedClients() > 0) copier.copy();
+}

src/AudioTools/Communication/WebSocketOutput.h

@@ -0,0 +1,60 @@
+#pragma once
+#include "AudioTools/CoreAudio/AudioOutput.h"
+#include "WebSocketsClient.h"  // https://github.com/Links2004/arduinoWebSockets
+#include "WebSocketsServer.h"  // https://github.com/Links2004/arduinoWebSockets
+
+namespace audio_tools {
+
+/**
+ * @brief A simple wrapper class that lets you use the standard
+ * Arduino Print class output commands to send audio data over a WebSocket
+ * connection.
+ * Uses https://github.com/Links2004/arduinoWebSockets
+ * @ingroup communications
+ * @author Phil Schatzmann
+ * @copyright GPLv3
+ */
+
+class WebSocketOutput : public AudioOutput {
+ public:
+  WebSocketOutput() = default;
+  /// @brief Constructor which defines an alternative WebSocket object. By
+  /// default we use WebSocket
+  WebSocketOutput(WebSocketsClient &ws) { setWebSocket(ws); }
+  /// @brief Constructor which defines an alternative WebSocket object. By
+  /// default we use WebSocket
+  WebSocketOutput(WebSocketsServer &ws) { setWebSocket(ws); }
+
+  /// @brief Defines an alternative WebSocket object. By default we use
+  /// WebSocket
+  void setWebSocket(WebSocketsClient &ws) { p_ws = &ws; };
+  /// @brief Defines an alternative WebSocket object. By default we use
+  /// WebSocket
+  void setWebSocket(WebSocketsServer &ws) { p_ws_server = &ws; };
+
+  /// Replys will be sent to the initial remote caller
+  size_t write(const uint8_t *data, size_t len) override {
+    bool rc = false;
+    if (p_ws != nullptr) rc = p_ws->sendBIN(data, len);
+    if (p_ws_server != nullptr) {
+      if (clientNo >= 0) {
+        rc = p_ws_server->sendBIN(clientNo, data, len);
+      } else {
+        // broadcast to all clients
+        rc = p_ws_server->broadcastBIN(data, len);
+      }
+      rc = p_ws_server->broadcastBIN(data, len);
+    }
+    return rc ? len : 0;
+  }
+
+  /// For WebSocketServer we can define an individual recipient!
+  void setTargetNo(int clientNo) { this->clientNo = clientNo; }
+
+ protected:
+  WebSocketsClient *p_ws = nullptr;
+  WebSocketsServer *p_ws_server = nullptr;
+  int clientNo = -1;
+};
+
+}  // namespace audio_tools