build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.4.5'
    id 'io.spring.dependency-management' version '1.1.7'
    id 'org.asciidoctor.jvm.convert' version '3.3.2'
    id 'jacoco'
}

group = 'com.project200'
version = '0.12.2-SNAPSHOT'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }

    asciidoctorExt
    mockitoAgent
}

repositories {
    mavenCentral()
}

ext {
    set('snippetsDir', file("build/generated-snippets"))
    set('springRestDocsVersion', "3.0.3")
    set('springCloudAwsVersion', "3.3.0")
}

dependencies {
    // Spring Cloud AWS BOM (Bill of Materials)
    implementation platform("io.awspring.cloud:spring-cloud-aws-dependencies:${springCloudAwsVersion}")

    // Spring Boot 의존성
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'jakarta.persistence:jakarta.persistence-api:3.1.0'

    // Spring Batch 의존성 추가
    implementation 'org.springframework.boot:spring-boot-starter-batch:2.7.18'
    implementation 'org.springframework.batch:spring-batch-test'

    implementation 'com.querydsl:querydsl-core:5.1.0'
    implementation "com.querydsl:querydsl-jpa:5.1.0:jakarta"
    implementation 'org.springframework.boot:spring-boot-starter-cache'
    annotationProcessor "com.querydsl:querydsl-apt:5.1.0:jakarta"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api:3.1.0"

    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-web'

    implementation 'org.springframework.boot:spring-boot-starter-actuator'

    // Slack API Client 의존성 추가
    implementation 'com.slack.api:slack-api-client:1.45.3'

    // 공간 좌표 데이터 활용
    implementation 'org.hibernate.orm:hibernate-spatial'
    implementation 'org.locationtech.jts:jts-core:1.20.0'

    compileOnly 'org.projectlombok:lombok'
    developmentOnly 'org.springframework.boot:spring-boot-devtools'
    developmentOnly 'org.springframework.boot:spring-boot-docker-compose'

    // 데이터베이스
    runtimeOnly 'com.h2database:h2'
    runtimeOnly 'com.mysql:mysql-connector-j'

    // Lombok
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'

    // Spring Boot Configuration Processor
    annotationProcessor 'org.springframework.boot:spring-boot-configuration-processor'

    // AWS 관련
    implementation "io.awspring.cloud:spring-cloud-aws-starter-s3"    // Spring Cloud AWS S3 Starter

    // firebase
    implementation 'com.google.firebase:firebase-admin:9.5.0'

    // websocket
    implementation 'org.springframework.boot:spring-boot-starter-websocket'

    // caffeine cache
    implementation 'com.github.ben-manes.caffeine:caffeine'


    // 테스트 의존성
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testImplementation 'org.springframework.restdocs:spring-restdocs-mockmvc'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
    asciidoctorExt "org.springframework.restdocs:spring-restdocs-asciidoctor:${springRestDocsVersion}"
    testImplementation 'io.awspring.cloud:spring-cloud-aws-testcontainers'
    testImplementation 'org.testcontainers:localstack'
    testImplementation 'org.testcontainers:junit-jupiter'

    // wiremock 테스트 의존성 추가
    testImplementation "org.wiremock:wiremock:3.5.2"

    // Scheduler 테스트 를 위한 의존성 추가
    testImplementation 'org.awaitility:awaitility:4.2.2'

    // Mockito 설정
    mockitoAgent('org.mockito:mockito-core') {
        transitive = false
    }
}

tasks.named('test') {
    outputs.dir snippetsDir
    useJUnitPlatform()
//    systemProperty("spring.profiles.active", System.getProperty("spring.profiles.active", "local"))
    jvmArgs("-javaagent:${configurations.mockitoAgent.asPath}")

    maxHeapSize = '4g'
}

tasks.named('asciidoctor') {
    dependsOn tasks.named('test')
    configurations 'asciidoctorExt'
    inputs.dir snippetsDir

    sourceDir file('src/docs/asciidoc') // 소스 디렉토리 설정

    // 처리할 소스 파일을 명시적으로 지정합니다.
    sources {
        include '*.adoc' // sourceDir 바로 아래의 .adoc 파일만 포함합니다.
        // 하위 디렉토리는 포함하지 않습니다.
    }

    baseDirFollowsSourceDir()

    attributes([
            'snippets': snippetsDir
    ])

    forkOptions {
        jvmArgs(
                '-Xmx2g', // 최대 힙 메모리 2GB 설정
                '--add-opens', 'java.base/sun.nio.ch=ALL-UNNAMED',
                '--add-opens', 'java.base/java.io=ALL-UNNAMED'
        )
    }
}

// 생성된 문서를 JAR에 포함시키기
tasks.named('bootJar') {
    dependsOn tasks.named('asciidoctor') // asciidoctor 작업이 먼저 실행되도록 보장
    from("${tasks.named('asciidoctor').get().outputDir}") { // AsciidoctorTask의 outputDir 사용
        into 'static/docs'
    }
}

// Q클래스 생성 경로 설정
def querydslSrcDir = 'src/main/generated'
sourceSets {
    main.java.srcDirs += [querydslSrcDir]
}

tasks.withType(JavaCompile) {
    options.annotationProcessorGeneratedSourcesDirectory = file(querydslSrcDir)
}

// 생성된 Q클래스 소스 삭제
clean {
    delete file(querydslSrcDir)
}

// JaCoCo 테스트 리포트 설정
jacocoTestReport {
    reports {
        html.required = true
        xml.required = true
        csv.required = false
    }

    // 커버리지 측정에서 제외할 클래스 파일들을 지정합니다.
    afterEvaluate {
        classDirectories.setFrom(files(classDirectories.files.collect {
            fileTree(dir: it, exclude: [
                    '**/entity/Q*.class',  // QueryDSL QClass
                    '**/*Dto.class',           // DTO 클래스
            ])
        }))
    }
}

// 'test' 태스크가 성공적으로 끝나면 jacocoTestReport 태스크가 실행되도록 설정
test.finalizedBy jacocoTestReport