AIBE4_FinalProject_Team4/build.gradle at dev · prgrms-aibe-devcourse/AIBE4_FinalProject_Team4 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
plugins {
    id 'java'
    id 'org.springframework.boot' version '3.5.11'
    id 'io.spring.dependency-management' version '1.1.7'
    id "com.diffplug.spotless" version "6.23.3"
}

group = 'kr.java'
version = '0.0.1-SNAPSHOT'
description = 'AIBE4_FinalProject_Team4'

spotless {
    java {
        target '**/*.java'
        targetExclude '.clone/**/*.java'
        // 구글 스타일(AOSP) = 들여쓰기 4칸 적용
        googleJavaFormat().aosp()
        importOrder() // import 순서 정의
        removeUnusedImports() // 안 쓰는 import 제거
        trimTrailingWhitespace() // 끝 공백 제거
        endWithNewline() // 파일 끝 빈 줄 추가
    }
    // [중요] 윈도우/맥 사용자 간 충돌 방지를 위해 LF로 통일
    lineEndings 'UNIX'
}

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(17)
    }
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
    maven { url 'https://jitpack.io' }
}

ext {
    set('springAiVersion', "1.1.2")
}

// ========== QueryDSL 설정 ==========
def querydslDir = "$buildDir/generated/querydsl"

sourceSets {
    main.java.srcDirs += [querydslDir]
}

tasks.withType(JavaCompile) {
    options.generatedSourceOutputDirectory = file(querydslDir)
}

clean {
    delete file(querydslDir)
}

dependencies {
    // Spring Boot Core
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-aop'
    implementation 'org.springframework.retry:spring-retry'
    implementation 'org.springframework.boot:spring-boot-starter-validation'
    implementation 'org.springframework.boot:spring-boot-starter-thymeleaf'
    // Source: https://mvnrepository.com/artifact/nz.net.ultraq.thymeleaf/thymeleaf-layout-dialect
    implementation 'nz.net.ultraq.thymeleaf:thymeleaf-layout-dialect:3.4.0'
    implementation 'org.springdoc:springdoc-openapi-starter-webmvc-ui:2.8.16'
    developmentOnly 'org.springframework.boot:spring-boot-devtools'

    // Database & Cache
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-data-redis'
    implementation 'org.flywaydb:flyway-core'
    implementation 'org.flywaydb:flyway-database-postgresql'
    runtimeOnly 'org.postgresql:postgresql'
    // Source: https://mvnrepository.com/artifact/io.hypersistence/hypersistence-utils-hibernate-63
    implementation 'io.hypersistence:hypersistence-utils-hibernate-63:3.15.2'

    // QueryDSL
    implementation 'com.querydsl:querydsl-jpa:5.0.0:jakarta'
    annotationProcessor 'com.querydsl:querydsl-apt:5.0.0:jakarta'
    annotationProcessor 'jakarta.annotation:jakarta.annotation-api'
    annotationProcessor 'jakarta.persistence:jakarta.persistence-api'

    // Rate Limiting (Bucket4j & Redisson)
    // Source: https://mvnrepository.com/artifact/com.bucket4j/bucket4j_jdk17-redisson
    implementation 'com.bucket4j:bucket4j_jdk17-redisson:8.16.1'
    // Source: https://mvnrepository.com/artifact/org.redisson/redisson-spring-boot-starter
    implementation 'org.redisson:redisson-spring-boot-starter:3.52.0'

    // S3
    implementation 'io.awspring.cloud:spring-cloud-aws-starter-s3:3.4.2'

    // Parquet (Cold Storage)
    implementation 'org.apache.parquet:parquet-avro:1.13.1'
    implementation('org.apache.hadoop:hadoop-common:3.3.6') {
        exclude group: 'org.slf4j', module: 'slf4j-reload4j'
        exclude group: 'org.slf4j', module: 'slf4j-log4j12'
    }
    implementation('org.apache.hadoop:hadoop-mapreduce-client-core:3.3.6') {
        exclude group: 'org.slf4j', module: 'slf4j-reload4j'
        exclude group: 'org.slf4j', module: 'slf4j-log4j12'
    }
    implementation 'org.apache.commons:commons-csv:1.11.0'

    // Spring AI & ETL & RAG
    implementation 'org.springframework.ai:spring-ai-starter-model-ollama'
    implementation 'org.springframework.ai:spring-ai-starter-model-openai'
    implementation 'org.springframework.ai:spring-ai-starter-model-google-genai'

    implementation 'org.apache.pdfbox:pdfbox:3.0.5'
    implementation('com.github.tabulapdf:tabula-java:master-SNAPSHOT') {
        exclude group: 'org.slf4j', module: 'slf4j-simple'
    }
    implementation 'org.apache.poi:poi:5.4.1'
    implementation 'org.apache.poi:poi-ooxml:5.4.1'
    implementation 'org.springframework.ai:spring-ai-tika-document-reader'

    implementation 'org.springframework.ai:spring-ai-rag'
    implementation 'org.springframework.ai:spring-ai-advisors-vector-store'
    implementation 'org.springframework.ai:spring-ai-starter-vector-store-pgvector'

    // Monitoring
    implementation 'org.springframework.boot:spring-boot-starter-actuator'
    implementation 'io.micrometer:micrometer-registry-influx'

    // Resilience4j (Circuit Breaker & Retry)
    implementation 'io.github.resilience4j:resilience4j-spring-boot3:2.2.0'
    implementation 'io.github.resilience4j:resilience4j-circuitbreaker:2.2.0'
    implementation 'io.github.resilience4j:resilience4j-retry:2.2.0'
    implementation 'io.github.resilience4j:resilience4j-micrometer:2.2.0'
    implementation 'io.github.resilience4j:resilience4j-all:2.2.0'

    // Utils & Test
    compileOnly 'org.projectlombok:lombok'
    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'
    testImplementation 'com.h2database:h2'
    // Source: https://mvnrepository.com/artifact/com.github.f4b6a3/uuid-creator
    implementation 'com.github.f4b6a3:uuid-creator:6.1.1'

    //JWT
    // Source: https://mvnrepository.com/artifact/io.jsonwebtoken/jjwt-api
    implementation 'io.jsonwebtoken:jjwt-api:0.13.0'
    // Source: https://mvnrepository.com/artifact/io.jsonwebtoken/jjwt-impl
    runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.13.0'
    // Source: https://mvnrepository.com/artifact/io.jsonwebtoken/jjwt-jackson
    runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.13.0'

    // Security
    implementation 'org.thymeleaf.extras:thymeleaf-extras-springsecurity6'
    testImplementation 'org.springframework.security:spring-security-test'
    implementation 'org.springframework.boot:spring-boot-starter-security'

    // OAuth2
    implementation 'org.springframework.boot:spring-boot-starter-oauth2-client'

    // Gmail SMTP (이메일 발송)
    implementation 'org.springframework.boot:spring-boot-starter-mail'

}

dependencyManagement {
    imports {
        mavenBom "org.springframework.ai:spring-ai-bom:${springAiVersion}"
    }
}

tasks.named('test') {
    useJUnitPlatform()
}

tasks.named('bootJar') {
    duplicatesStrategy = DuplicatesStrategy.EXCLUDE
}