jsyn/build.gradle at master · philburk/jsyn · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
plugins {
    id 'java'
    id 'application'
    id 'maven-publish'
}

group = 'com.jsyn'
version = '17.3.0'
sourceCompatibility = '1.8'
mainClassName = 'com.jsyn.apps.AboutJSyn'

repositories {
    mavenCentral()
    mavenLocal()
}

dependencies {
    testImplementation 'org.junit.jupiter:junit-jupiter:5.4.2'

    implementation fileTree(dir: 'libs', include: '*.jar')
}

sourceSets {
    jsynExamples {
        java {
            srcDirs = [
                'examples/src/main/java',
                'src/main/java'
            ]
            exclude 'com/jsyn/devices/jportaudio/**'
        }
        resources {
            srcDirs = ['examples/src/main/resources']
        }
        compileClasspath += sourceSets.main.output
        runtimeClasspath += sourceSets.main.output
    }
}

// Create a new task of type Jar
task jsynExamplesJar(type: Jar) {
    // Set the base name of the JAR file
    archiveBaseName.set('jsyn-examples-v2')

    // Set the version of the JAR file
    archiveVersion.set(project.version)

    // Use the output of your custom source set as the source for this JAR
    from sourceSets.jsynExamples.output

}

jar {
    manifest {
        attributes('Main-Class': mainClassName)
    }

    from {
        configurations.runtimeClasspath.collect { it.isDirectory() ? it : zipTree(it) }
    }
}

javadoc {
    exclude 'com/portaudio/**'
    exclude 'com/jsyn/devices/jportaudio/**'
    source = sourceSets.main.allJava

    options {
        addStringOption('Xdoclint:none', '-quiet')
    }
}

task javadocJar(type: Jar) {
    archiveClassifier = 'javadoc'
    from javadoc
}

artifacts {
    archives javadocJar
}

test {
    useJUnitPlatform()
}

publishing {
    publications {
        mavenJava(MavenPublication) {
            artifactId = 'jsyn'
            from components.java
            pom {
                name = 'JSyn'
                description = 'Java synthesizer library with unit generators.'
                url = 'https://www.softsynth.com/jsyn'
                licenses {
                    license {
                        name = 'The Apache License, Version 2.0'
                        url = 'https://www.apache.org/licenses/LICENSE-2.0.txt'
                    }
                }
                developers {
                    developer {
                        id = 'philburk'
                        name = 'Phil Burk'
                    }
                }
                scm {
                    connection = 'scm:git:git://github.com/philburk/jsyn.git'
                    developerConnection = 'scm:git:git@github.com:philburk/jsyn.git'
                    url = 'https://github.com/philburk/jsyn'
                }
            }
        }
    }
}