Speed up class list importing.

Use a batch insertion and update for users, permissions, and passwords
when importing a class list.

This improves the speed of imporing large class lists quite a bit.  For
example, importing a classlist containing 5000 users improves from
around 22 seconds to around 7 seconds in my testing.

Author: drgrice1

lib/WeBWorK/ContentGenerator/Instructor/UserList.pm

@@ -626,50 +626,47 @@ sub menuLabels ($c, $hashRef) {
 }
 
 sub importUsersFromCSV ($c, $fileName, $replaceExisting, $fallbackPasswordSource, @replaceList) {
-	my $ce   = $c->ce;
-	my $db   = $c->db;
-	my $dir  = $ce->{courseDirs}{templates};
-	my $user = $c->param('user');
-	my $perm = $c->{userPermission};
+	my $ce = $c->ce;
+	my $db = $c->db;
 
-	die $c->maketext("Illegal '/' character in input.") if $fileName =~ m|/|;
-	die $c->maketext("File [_1]/[_2] either does not exist or is not readable.", $dir, $fileName)
-		unless -r "$dir/$fileName";
+	die $c->maketext(q{Illegal '/' character in input.}) if $fileName =~ m|/|;
+	die $c->maketext('File [_1]/[_2] either does not exist or is not readable.',
+		$ce->{courseDirs}{templates}, $fileName)
+		unless -r "$ce->{courseDirs}{templates}/$fileName";
 
 	my %allUserIDs = map { $_ => 1 } @{ $c->{allUserIDs} };
 
 	my %replaceOK;
-	if ($replaceExisting eq 'none') {
-		%replaceOK = ();
-	} elsif ($replaceExisting eq 'listed') {
+	if ($replaceExisting eq 'listed') {
 		%replaceOK = map { $_ => 1 } @replaceList;
 	} elsif ($replaceExisting eq 'any') {
 		%replaceOK = %allUserIDs;
 	}
 
 	my $default_permission_level = $ce->{default_permission_level};
 
-	my (@replaced, @added, @skipped);
+	my (@usersToInsert, @passwordsToInsert, @permissionsToInsert,
+		@usersToUpdate, @passwordsToUpdate, @permissionsToUpdate, @skipped);
 
 	# get list of hashrefs representing lines in classlist file
-	my @classlist = parse_classlist("$dir/$fileName");
+	my @classlist = parse_classlist("$ce->{courseDirs}{templates}/$fileName");
 
 	# Default status is enrolled -- fetch abbreviation for enrolled
 	my $default_status_abbrev = $ce->{statuses}{Enrolled}{abbrevs}[0];
 
-	foreach my $record (@classlist) {
+	for my $record (@classlist) {
 		my %record  = %$record;
 		my $user_id = $record{user_id};
 
 		unless (WeBWorK::DB::check_user_id($user_id)) {    # try to catch lines with bad characters
 			push @skipped, $user_id;
 			next;
 		}
-		if ($user_id eq $user) {                           # don't replace yourself!!
+		if ($user_id eq $c->param('user')) {               # don't replace yourself!!
 			push @skipped, $user_id;
 			next;
 		}
-		if ($record{permission} && $perm < $record{permission}) {
+		if ($record{permission} && $c->{userPermission} < $record{permission}) {
 			push @skipped, $user_id;
 			next;
 		}
@@ -681,7 +678,7 @@ sub importUsersFromCSV ($c, $fileName, $replaceExisting, $fallbackPasswordSource
 
 		# set default status is status field is "empty"
 		$record{status} = $default_status_abbrev
-			unless defined $record{status} and $record{status} ne "";
+			unless defined $record{status} && $record{status} ne '';
 
 		# Determine what to use for the password (if anything).
 		if (!$record{password}) {
@@ -697,32 +694,37 @@ sub importUsersFromCSV ($c, $fileName, $replaceExisting, $fallbackPasswordSource
 
 		# set default permission level if permission level is "empty"
 		$record{permission} = $default_permission_level
-			unless defined $record{permission} and $record{permission} ne "";
+			unless defined $record{permission} && $record{permission} ne '';
 
 		my $User            = $db->newUser(%record);
 		my $PermissionLevel = $db->newPermissionLevel(user_id => $user_id, permission => $record{permission});
 		my $Password = $record{password} ? $db->newPassword(user_id => $user_id, password => $record{password}) : undef;
 
 		# DBFIXME use REPLACE
 		if (exists $allUserIDs{$user_id}) {
-			$db->putUser($User);
-			$db->putPermissionLevel($PermissionLevel);
-			$db->putPassword($Password) if $Password;
+			push(@usersToUpdate,       $User);
+			push(@permissionsToUpdate, $PermissionLevel);
+			push(@passwordsToUpdate,   $Password) if $Password;
 			$User->{permission}     = $PermissionLevel->permission;
 			$User->{passwordExists} = 1 if $Password;
-			push @replaced, $User;
 		} else {
 			$allUserIDs{$user_id} = 1;
-			$db->addUser($User);
-			$db->addPermissionLevel($PermissionLevel);
-			$db->addPassword($Password) if $Password;
+			push(@usersToInsert,       $User);
+			push(@permissionsToInsert, $PermissionLevel);
+			push(@passwordsToInsert,   $Password) if $Password;
 			$User->{permission}     = $PermissionLevel->permission;
 			$User->{passwordExists} = 1 if $Password;
-			push @added, $User;
 		}
 	}
 
-	return \@replaced, \@added, \@skipped;
+	$db->User->insert_records(\@usersToInsert)                  if @usersToInsert;
+	$db->User->update_records(\@usersToUpdate)                  if @usersToUpdate;
+	$db->Password->insert_records(\@passwordsToInsert)          if @passwordsToInsert;
+	$db->Password->update_records(\@passwordsToUpdate)          if @passwordsToUpdate;
+	$db->PermissionLevel->insert_records(\@permissionsToInsert) if @permissionsToInsert;
+	$db->PermissionLevel->update_records(\@permissionsToUpdate) if @permissionsToUpdate;
+
+	return \@usersToUpdate, \@usersToInsert, \@skipped;
 }
 
 sub exportUsersToCSV ($c, $fileName, @userIDsToExport) {