trofers/build.gradle at 1.21.x · ochotonida/trofers · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
plugins {
    id 'base'
    id 'dev.architectury.loom' version '1.11-SNAPSHOT' apply false
    id 'architectury-plugin' version '3.4-SNAPSHOT'
    id 'com.gradleup.shadow' version '8.3.6' apply false
}

architectury {
    minecraft = project.minecraft_version
}

allprojects {
    group = rootProject.maven_group
    version = rootProject.mod_version
}

subprojects {
    apply from: "$rootDir/repositories.gradle"

    apply plugin: 'dev.architectury.loom'
    apply plugin: 'architectury-plugin'

    sourceSets {
        main.resources.srcDirs = ['src/main/resources', 'src/generated/resources']
    }

    base {
        archivesName = "$rootProject.archives_name-$project.name"
    }

    loom {
        silentMojangMappingsLicense()
    }

    dependencies {
        minecraft "net.minecraft:minecraft:$rootProject.minecraft_version"
        mappings loom.officialMojangMappings()
    }

    java {
        withSourcesJar()

        sourceCompatibility = JavaVersion.VERSION_21
        targetCompatibility = JavaVersion.VERSION_21
    }

    tasks.withType(JavaCompile).configureEach {
        it.options.release = 21
    }
}

tasks.register('collectJars', Copy) {
    dependsOn subprojects.collect { it.tasks.named('remapJar') }

    from(subprojects.findAll { it.name != 'common' }.collect { it.tasks.named('remapJar').get().archiveFile })
    into(layout.buildDirectory.dir('libs'))
}

tasks.assemble.dependsOn(collectJars)