elasticsearch-carrot2/build.gradle at master · objectrocket/elasticsearch-carrot2 · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162

// This plugin's version (typically must match that of ES).
version = '7.3.2'
group = 'org.carrot2'

buildscript {
    ext {
        // ES version we depend upon/ compile against.
        version_es = '7.3.2'
    }

    repositories {
        mavenLocal()
        mavenCentral()
        jcenter()
    }

    dependencies {
        classpath "org.elasticsearch.gradle:build-tools:" + version_es
    }
}

apply plugin: 'java'
apply plugin: 'idea'
apply plugin: 'eclipse'
apply plugin: 'elasticsearch.testclusters'
apply plugin: 'elasticsearch.esplugin'

apply plugin: 'maven'
apply plugin: 'signing'
apply plugin: 'maven-publish'

apply plugin: 'nebula.maven-base-publish'
apply plugin: 'nebula.maven-scm'

ext {
  projectSubstitutions = [:]
  licenseFile = rootProject.file('LICENSE.txt')
  noticeFile = rootProject.file('NOTICE.txt')
}

esplugin {
    name 'elasticsearch-carrot2'
    description 'Search results clustering plugin for ElasticSearch (Carrot2-based)'
    classname 'org.carrot2.elasticsearch.ClusteringPlugin'
}

// We don't have unit tests, only integration tests.
test.enabled = false

testingConventions {
  enabled = true
}

integTest {
  runner {
    systemProperty 'tests.security.manager', 'false'
  }
}

testClusters.integTest {
  // extraConfigFile doesn't allow directories, only files, so we need to add each individually
  fileTree(dir: 'src/main/config').each { File file ->
    extraConfigFile 'elasticsearch-carrot2/' + file.name, file
  }
}

licenseHeaders.enabled = false
dependencyLicenses.enabled = false
thirdPartyAudit.enabled = false

repositories {
    mavenLocal()
    mavenCentral()
}

// esplugin forces transitive:false on all dependencies
// so list all transitive dependencies individually
dependencies {
    compile "org.carrot2:carrot2-mini:3.16.1"
    compile "com.carrotsearch.thirdparty:simple-xml-safe:2.7.1"
    compile "com.carrotsearch:hppc:0.8.1"
    compile "org.carrot2.attributes:attributes-binder:1.3.3"
    compile "org.carrot2.shaded:carrot2-guava:18.0"
    compile "org.apache.commons:commons-lang3:3.5"
    compile "com.fasterxml.jackson.core:jackson-core:2.8.11"
    compile "com.fasterxml.jackson.core:jackson-annotations:2.8.11"
    compile "com.fasterxml.jackson.core:jackson-databind:2.8.11"
    compile "org.slf4j:slf4j-api:1.7.13"
    compile "org.apache.logging.log4j:log4j-slf4j-impl:2.11.1"
    compile "org.carrot2:morfologik-stemming:2.1.5"
    compile "org.carrot2:morfologik-fsa:2.1.5"

    testCompile "org.assertj:assertj-core:3.12.0"
    testCompile "org.elasticsearch.client:transport:" + version_es

    testCompile "org.apache.httpcomponents:httpclient:${versions.httpclient}"
    testCompile "org.apache.httpcomponents:httpcore:${versions.httpcore}"
}

artifacts {
    archives javadocJar, sourcesJar
}

signing {
    required { gradle.taskGraph.hasTask("uploadArchives") }
    sign configurations.archives
}

project.gradle.taskGraph.whenReady { taskGraph ->
  if (taskGraph.allTasks.any { it.name == 'uploadArchives' }) {
    uploadArchives {
      repositories {
        mavenDeployer {
          beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

          repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
            authentication(userName: nexusUsername, password: nexusPassword)
          }

          snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
            authentication(userName: nexusUsername, password: nexusPassword)
          }

          pom.project {
            name 'Search results clustering plugin for Elasticsearch (Carrot2-based)'
            packaging 'zip'
            artifactId 'elasticsearch-carrot2'
            description 'Search results clustering plugin for Elasticsearch (Carrot2-based)'
            url 'https://github.com/carrot2/elasticsearch-carrot2'

            scm {
              connection 'scm:git:https://github.com/carrot2/elasticsearch-carrot2'
              developerConnection 'scm:git:git@github.com:carrot2/elasticsearch-carrot2.git'
              url 'https://github.com/carrot2/elasticsearch-carrot2'
            }

            licenses {
              license {
                name 'The Apache License, Version 2.0'
                url 'http://www.apache.org/licenses/LICENSE-2.0.txt'
              }
            }

            developers {
              developer {
                id 'dawid.weiss'
                name 'Dawid Weiss'
                email 'dawid.weiss@carrotsearch.com'
              }
              developer {
                id 'stanislaw.osinski'
                name 'Stanisław Osiński'
                email 'stanislaw.osinski@carrotsearch.com'
              }
            }
          }
        }
      }
    }
  }
}