database: Add basic-raft nixos-test

Author: jsoo1

.gitignore

@@ -37,3 +37,5 @@ venv.bak/
 # They can be nice to have for reference
 result*
 result*/
+# Also probably don't need the nixos-test repl history
+.nixos-test-history

nix/nixos-tests/basic-raft/default.nix

@@ -0,0 +1,60 @@
+{ testers
+, lib
+  # Adjust for more nodes
+, nPeers ? 3
+}:
+# see also:
+# https://nix.dev/tutorials/nixos/integration-testing-using-virtual-machines.html
+let
+  peers = lib.genList (n: "peer${toString n}") nPeers;
+
+  raft-port = 3000;
+in
+testers.runNixOSTest {
+  name = "null-db-basic-raft";
+
+  nodes = lib.genAttrs peers (_self: { });
+
+  defaults = { pkgs, ... }: {
+    imports = [ ../../module.nix ];
+
+    config = {
+      # Test-specific vm configuration
+      virtualisation = {
+        # Default is 1 - might need more for our workers
+        cores = 2;
+        memorySize = 512;
+        # If you want to see ttys run the same stuff as stdout/stderr,
+        # enable this
+        graphics = false;
+      };
+
+      # Interactive debugging
+      environment.defaultPackages = [ pkgs.curl pkgs.bind.host ];
+
+      programs.null-db.enable = true;
+
+      services.null-db = {
+        enable = true;
+        openFirewall = true;
+        args.encoding = "json";
+        args.roster = lib.map (n: "${n}:${toString raft-port}") peers;
+        inherit raft-port;
+      };
+
+      # If you want verbose logging, you might break a bit of an
+      # abstraction boundary:
+      # systemd.services.null-db.serviceConfig.Environment =
+      #   "RUST_LOG=info";
+    };
+  };
+
+  testScript = { nodes }: ''
+    start_all()
+
+    for peer in machines:
+      peer.wait_for_unit("null-db.service")
+
+    peer0.wait_for_console_text("null-db.*Starting raft main loop", timeout=60)
+  '';
+}

nix/overlay.nix

@@ -1,3 +1,8 @@
 final: prev: {
-  null-db = final.callPackage ../database { };
+  null-db = (final.callPackage ../database { }).overrideAttrs (o: {
+    # passthru is a nixpkgs field that is reserved to only exist in
+    # nix runtime but not end up in a derivation. passthru.tests is
+    # one very common attribute.
+    passthru.tests.basic-raft = final.callPackage ./nixos-tests/basic-raft { };
+  });
 }