fix: Use and configure grub for mirrored efi partitions

Author: provokateurin

example/btrfs-raid-mirrored-boot.nix

@@ -0,0 +1,81 @@
+{
+  disko.devices.disk = {
+    one = {
+      type = "disk";
+      device = "/dev/vda";
+
+      content = {
+        type = "gpt";
+
+        partitions = {
+          boot = {
+            size = "1M";
+            type = "EF02";
+          };
+
+          esp = {
+            size = "1G";
+            type = "EF00";
+
+            content = {
+              type = "filesystem";
+              format = "vfat";
+              mountpoint = "/boot0";
+              mountOptions = [ "umask=0077" ];
+            };
+          };
+
+          root = {
+            size = "100%";
+
+            content = {
+              type = "btrfs";
+            };
+          };
+        };
+      };
+    };
+
+    two = {
+      type = "disk";
+      device = "/dev/vdb";
+
+      content = {
+        type = "gpt";
+
+        partitions = {
+          boot = {
+            size = "1M";
+            type = "EF02";
+          };
+
+          esp = {
+            size = "1G";
+            type = "EF00";
+
+            content = {
+              type = "filesystem";
+              format = "vfat";
+              mountpoint = "/boot1";
+              mountOptions = [ "umask=0077" ];
+            };
+          };
+
+          root = {
+            size = "100%";
+
+            content = {
+              type = "btrfs";
+              mountpoint = "/";
+              extraArgs = [
+                "-f"
+                "-d raid1"
+                "/dev/disk/by-partlabel/disk-one-root"
+              ];
+            };
+          };
+        };
+      };
+    };
+  };
+}

lib/default.nix

@@ -1059,13 +1059,40 @@ let
             '';
             default =
               with lib;
-              let
-                configKeys = flatten (
-                  map attrNames (flatten (map (dev: dev._config) (flatten (map attrValues (attrValues devices)))))
-                );
-                collectedConfigs = flatten (map (dev: dev._config) (flatten (map attrValues (attrValues devices))));
-              in
-              genAttrs configKeys (key: mkMerge (catAttrs key collectedConfigs));
+              (
+                let
+                  configKeys = flatten (
+                    map attrNames (flatten (map (dev: dev._config) (flatten (map attrValues (attrValues devices)))))
+                  );
+                  collectedConfigs = flatten (map (dev: dev._config) (flatten (map attrValues (attrValues devices))));
+                in
+                genAttrs configKeys (key: mkMerge (catAttrs key collectedConfigs))
+              )
+              // (
+                let
+                  efi_partitions = builtins.filter (part: part.type == "EF00") (
+                    flatten (
+                      map (
+                        disk:
+                        map (part: part // { device = disk.device; }) (
+                          if builtins.hasAttr "content" disk then attrValues disk.content.partitions else [ ]
+                        )
+                      ) (flatten (map attrValues (attrValues devices)))
+                    )
+                  );
+                in
+                (optionalAttrs (builtins.length efi_partitions >= 2) {
+                  # Mirrored boot partitions are not supported on systemd-boot.
+                  boot.loader.grub.enable = mkForce true;
+                  boot.loader.grub.devices = mkForce [ ];
+                  boot.loader.grub.mirroredBoots = mkForce (
+                    map (part: {
+                      devices = [ part.device ];
+                      path = part.content.mountpoint;
+                    }) efi_partitions
+                  );
+                })
+              );
           };
         };
       }

lib/make-disk-image.nix

@@ -64,6 +64,7 @@ let
         disko.testMode = true;
         disko.devices = lib.mkForce cleanedConfig.disko.devices;
         boot.loader.grub.devices = lib.mkForce cleanedConfig.boot.loader.grub.devices;
+        boot.loader.grub.mirroredBoots = lib.mkForce cleanedConfig.boot.loader.grub.mirroredBoots;
       }
     ];
   };
@@ -77,6 +78,7 @@ let
             disko.devices = lib.mkForce cleanedConfig.disko.devices;
             boot.loader.grub.devices = lib.mkForce cleanedConfig.boot.loader.grub.devices;
             boot.kernelPackages = cfg.kernelPackages;
+            boot.loader.grub.mirroredBoots = lib.mkForce cleanedConfig.boot.loader.grub.mirroredBoots;
             nixpkgs.hostPlatform = lib.mkForce pkgs.stdenv.hostPlatform;
             nixpkgs.buildPlatform = lib.mkForce pkgs.stdenv.hostPlatform;
           }

lib/tests.nix

@@ -185,7 +185,7 @@ let
                   boot.swraid.mdadmConf = "PROGRAM ${pkgs.coreutils}/bin/true";
 
                   # grub will install to these devices, we need to force those or we are offset by 1
-                  # we use mkOveride 70, so that users can override this with mkForce in case they are testing grub mirrored boots
+                  # we use mkOverride 70, so that users can override this with mkForce in case they are testing grub mirrored boots
                   boot.loader.grub.devices = lib.mkOverride 70 testConfigInstall.boot.loader.grub.devices;
 
                   assertions = [

tests/btrfs-raid-mirrored-boot.nix

@@ -0,0 +1,18 @@
+{
+  pkgs ? import <nixpkgs> { },
+  diskoLib ? pkgs.callPackage ../lib { },
+}:
+diskoLib.testLib.makeDiskoTest {
+  inherit pkgs;
+  name = "btrfs-raid-mirrored-boot";
+  disko-config = ../example/btrfs-raid-mirrored-boot.nix;
+  extraTestScript = ''
+    machine.succeed("mountpoint /");
+    machine.succeed("mountpoint /boot0");
+    machine.succeed("mountpoint /boot1");
+  '';
+  extraSystemConfig = {
+    # Mirrored boot partitions are not supported on systemd-boot.
+    boot.loader.systemd-boot.enable = false;
+  };
+}