new-ebodac/build.gradle at dev · motech-implementations/new-ebodac · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
plugins {
    id 'java'
    id 'idea'
    id 'org.springframework.boot' version '2.1.6.RELEASE'
    id 'com.moowork.node' version '1.3.1'
    id 'net.ltgt.apt' version '0.20'
    id 'org.liquibase.gradle' version '2.0.1'
    id 'pmd'
    id 'checkstyle'
    id 'net.researchgate.release' version '2.8.1'
}

apply plugin: 'io.spring.dependency-management'

group 'org.motechproject.newebodac'

repositories {
    mavenCentral()
}

dependencies {
    implementation 'org.apache.commons:commons-lang3:3.9'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.boot:spring-boot-starter-security'
    implementation 'org.springframework.boot:spring-boot-starter-quartz'
    implementation 'org.springframework.boot:spring-boot-starter-mail'
    implementation 'org.springframework.security.oauth.boot:spring-security-oauth2-autoconfigure:2.1.6.RELEASE'
    implementation 'org.springframework.security:spring-security-jwt'
    implementation 'mysql:mysql-connector-java'
    implementation 'org.liquibase:liquibase-core'
    implementation 'org.mapstruct:mapstruct:1.3.0.Final'
    implementation 'net.sf.supercsv:super-csv:2.4.0'
    implementation 'org.json:json:20190722'
    implementation 'com.fasterxml.jackson.datatype:jackson-datatype-json-org:2.10.1'
    compileOnly 'org.projectlombok:lombok:1.18.8'

    annotationProcessor 'org.mapstruct:mapstruct-processor:1.3.0.Final'
    annotationProcessor 'org.projectlombok:lombok:1.18.8'

    liquibaseRuntime 'org.liquibase:liquibase-core'
    liquibaseRuntime 'org.liquibase.ext:liquibase-hibernate5:3.6'
    liquibaseRuntime 'mysql:mysql-connector-java'
    liquibaseRuntime 'ch.qos.logback:logback-core:1.2.3'
    liquibaseRuntime 'ch.qos.logback:logback-classic:1.2.3'
    liquibaseRuntime sourceSets.main.compileClasspath

    testImplementation 'org.springframework.boot:spring-boot-starter-test'
}

defaultTasks "bootRun"

processResources {
    filesMatching("**/application.yml") {
        expand(project.properties)
    }
}

java {
    sourceCompatibility = JavaVersion.toVersion(targetJavaVersion)
}

node {
    version = '10.16.0'
    npmVersion = '6.9.0'
    download = true
}

checkstyle {
    toolVersion '8.22'
    configFile = file("checkstyle.xml")
    maxWarnings = 0
}

pmd {
    toolVersion = '6.16.0'
    consoleOutput= true
    ignoreFailures = false
    ruleSets = []
    ruleSetFiles = files("ruleset.xml")
    reportsDir = file("build/reports/pmd")
}

project.ext.diffChangelogFile = "src/main/resources/liquibase/changelog/" + new Date().format("yyyyMMddHHmmss") + "_changelog.xml"

if (!project.hasProperty("runList")) {
    project.ext.runList = "diffLog"
}

liquibase {
    activities {
        diffLog {
            driver "com.mysql.cj.jdbc.Driver"
            url databaseUrl
            username databaseUser
            password databasePassword
            changeLogFile project.ext.diffChangelogFile
            referenceUrl "hibernate:spring:org.motechproject.newebodac.domain?dialect=org.hibernate.dialect.MySQL5InnoDBDialect&hibernate.physical_naming_strategy=org.springframework.boot.orm.jpa.hibernate.SpringPhysicalNamingStrategy&hibernate.implicit_naming_strategy=org.springframework.boot.orm.jpa.hibernate.SpringImplicitNamingStrategy"
            defaultSchemaName "newEbodac"
            logLevel "debug"
            classpath "$buildDir/classes/java/main"
            excludeObjects "QRTZ_.*"
        }
    }

    runList = project.ext.runList
}

diff.dependsOn compileJava
diffChangeLog.dependsOn compileJava
generateChangelog.dependsOn compileJava

task webpack(type: NpmTask, dependsOn: 'npmInstall') {
    args = ['run-script', 'build']
}

task webpackWatch(type: NpmTask, dependsOn: 'npmInstall') {
    args = ['run-script', 'watch']
}

task webpackProd(type: NpmTask, dependsOn: 'npmInstall') {
    args = ['run-script', 'prod']
}

task dbDiff() {}

bootJar.dependsOn 'webpackProd'
bootRun.dependsOn 'webpack'
dbDiff.dependsOn 'diffChangeLog'