build.gradle

buildscript {
  ext {
    springBootVersion = "1.2.5.RELEASE"
  }
  repositories {
    jcenter()
    maven { url "https://spinnaker.bintray.com/gradle" }
  }
  dependencies {
    classpath 'com.netflix.spinnaker.gradle:spinnaker-gradle-project:3.5.0'
    classpath "org.springframework.boot:spring-boot-gradle-plugin:${springBootVersion}"
  }
}


allprojects {
  apply plugin: "spinnaker.project"
  apply plugin: "groovy"

  group = "com.netflix.spinnaker.rosco"

  spinnaker {
    dependenciesVersion = "0.42.0"
  }

  configurations.all {
    resolutionStrategy {
      force 'org.apache.httpcomponents:httpclient:4.3.5'
      force 'org.apache.httpcomponents:httpcore:4.3.2'
    }
    exclude group: 'javax.servlet', module: 'servlet-api'
    exclude group: "org.slf4j", module: "slf4j-log4j12"
    exclude group: "org.mortbay.jetty", module: "servlet-api"
  }

  dependencies {
    spinnaker.group("test")
    compile spinnaker.dependency("bootActuator")
    compile spinnaker.dependency("groovy")
    compile spinnaker.dependency("korkSwagger")
    compile spinnaker.dependency("korkWeb")
    compile spinnaker.dependency("spectatorReg")
  }
  test {
    testLogging {
      exceptionFormat = 'full'
    }
  }
}

defaultTasks ':rosco-web:bootRun'