feat: Add batch withdrawals reporting (#429)

Author: dgusakov

script/fork-helpers/NodeOperators.s.sol

@@ -9,7 +9,7 @@ import { ForkHelpersCommon } from "./Common.sol";
 import "../../src/interfaces/IVEBO.sol";
 import { Utilities } from "../../test/helpers/Utilities.sol";
 import { IStakingRouter } from "../../src/interfaces/IStakingRouter.sol";
-import { NodeOperator } from "../../src/interfaces/ICSModule.sol";
+import { NodeOperator, ValidatorWithdrawalInfo } from "../../src/interfaces/ICSModule.sol";
 
 contract NodeOperators is
     Script,
@@ -200,7 +200,15 @@ contract NodeOperators is
     ) external broadcastVerifier {
         uint256 withdrawnBefore = csm.getNodeOperator(noId).totalWithdrawnKeys;
 
-        csm.submitWithdrawal(noId, keyIndex, amount, false);
+        ValidatorWithdrawalInfo[]
+            memory withdrawalInfo = new ValidatorWithdrawalInfo[](1);
+        withdrawalInfo[0] = ValidatorWithdrawalInfo(
+            noId,
+            keyIndex,
+            amount,
+            false
+        );
+        csm.submitWithdrawals(withdrawalInfo);
 
         assertTrue(csm.isValidatorWithdrawn(noId, keyIndex));
         assertEq(

src/CSModule.sol

@@ -13,7 +13,7 @@ import { ILidoLocator } from "./interfaces/ILidoLocator.sol";
 import { IStETH } from "./interfaces/IStETH.sol";
 import { ICSParametersRegistry } from "./interfaces/ICSParametersRegistry.sol";
 import { ICSAccounting } from "./interfaces/ICSAccounting.sol";
-import { ICSModule, NodeOperator, NodeOperatorManagementProperties } from "./interfaces/ICSModule.sol";
+import { ICSModule, NodeOperator, NodeOperatorManagementProperties, ValidatorWithdrawalInfo } from "./interfaces/ICSModule.sol";
 
 import { QueueLib, Batch } from "./lib/QueueLib.sol";
 import { ValidatorCountsReport } from "./lib/ValidatorCountsReport.sol";
@@ -677,45 +677,65 @@ contract CSModule is
     }
 
     /// @inheritdoc ICSModule
-    function submitWithdrawal(
-        uint256 nodeOperatorId,
-        uint256 keyIndex,
-        uint256 amount,
-        bool isSlashed
+    function submitWithdrawals(
+        ValidatorWithdrawalInfo[] calldata withdrawalsInfo
     ) external onlyRole(VERIFIER_ROLE) {
-        _onlyExistingNodeOperator(nodeOperatorId);
-        NodeOperator storage no = _nodeOperators[nodeOperatorId];
-        if (keyIndex >= no.totalDepositedKeys) {
-            revert SigningKeysInvalidOffset();
-        }
-
-        uint256 pointer = _keyPointer(nodeOperatorId, keyIndex);
-        if (_isValidatorWithdrawn[pointer]) revert AlreadyWithdrawn();
+        for (uint256 i; i < withdrawalsInfo.length; ++i) {
+            ValidatorWithdrawalInfo memory withdrawalInfo = withdrawalsInfo[i];
 
-        _isValidatorWithdrawn[pointer] = true;
-        unchecked {
-            ++no.totalWithdrawnKeys;
-        }
+            _onlyExistingNodeOperator(withdrawalInfo.nodeOperatorId);
+            NodeOperator storage no = _nodeOperators[
+                withdrawalInfo.nodeOperatorId
+            ];
 
-        bytes memory pubkey = SigningKeys.loadKeys(nodeOperatorId, keyIndex, 1);
-        emit WithdrawalSubmitted(nodeOperatorId, keyIndex, amount, pubkey);
+            if (withdrawalInfo.keyIndex >= no.totalDepositedKeys) {
+                revert SigningKeysInvalidOffset();
+            }
 
-        if (isSlashed) {
-            // Bond curve should be reset to default in case of slashing. See https://hackmd.io/@lido/SygBLW5ja
-            accounting.resetBondCurve(nodeOperatorId);
-        }
+            uint256 pointer = _keyPointer(
+                withdrawalInfo.nodeOperatorId,
+                withdrawalInfo.keyIndex
+            );
+            if (_isValidatorWithdrawn[pointer]) revert AlreadyWithdrawn();
 
-        if (DEPOSIT_SIZE > amount) {
+            _isValidatorWithdrawn[pointer] = true;
             unchecked {
-                accounting.penalize(nodeOperatorId, DEPOSIT_SIZE - amount);
+                ++no.totalWithdrawnKeys;
             }
-        }
 
-        // Nonce should be updated if depositableValidators change
-        _updateDepositableValidatorsCount({
-            nodeOperatorId: nodeOperatorId,
-            incrementNonceIfUpdated: true
-        });
+            bytes memory pubkey = SigningKeys.loadKeys(
+                withdrawalInfo.nodeOperatorId,
+                withdrawalInfo.keyIndex,
+                1
+            );
+
+            emit WithdrawalSubmitted(
+                withdrawalInfo.nodeOperatorId,
+                withdrawalInfo.keyIndex,
+                withdrawalInfo.amount,
+                pubkey
+            );
+
+            if (withdrawalInfo.isSlashed) {
+                // Bond curve should be reset to default in case of slashing. See https://hackmd.io/@lido/SygBLW5ja
+                accounting.resetBondCurve(withdrawalInfo.nodeOperatorId);
+            }
+
+            if (DEPOSIT_SIZE > withdrawalInfo.amount) {
+                unchecked {
+                    accounting.penalize(
+                        withdrawalInfo.nodeOperatorId,
+                        DEPOSIT_SIZE - withdrawalInfo.amount
+                    );
+                }
+            }
+
+            // Nonce should be updated if depositableValidators change
+            _updateDepositableValidatorsCount({
+                nodeOperatorId: withdrawalInfo.nodeOperatorId,
+                incrementNonceIfUpdated: true
+            });
+        }
     }
 
     /// @inheritdoc IStakingModule

src/CSVerifier.sol

@@ -4,7 +4,7 @@
 pragma solidity 0.8.24;
 
 import { ICSVerifier } from "./interfaces/ICSVerifier.sol";
-import { ICSModule } from "./interfaces/ICSModule.sol";
+import { ICSModule, ValidatorWithdrawalInfo } from "./interfaces/ICSModule.sol";
 import { AccessControlEnumerable } from "@openzeppelin/contracts/access/extensions/AccessControlEnumerable.sol";
 import { PausableUntil } from "./lib/utils/PausableUntil.sol";
 
@@ -150,12 +150,15 @@ contract CSVerifier is ICSVerifier, AccessControlEnumerable, PausableUntil {
             pubkey: pubkey
         });
 
-        MODULE.submitWithdrawal(
+        ValidatorWithdrawalInfo[]
+            memory withdrawalsInfo = new ValidatorWithdrawalInfo[](1);
+        withdrawalsInfo[0] = ValidatorWithdrawalInfo(
             nodeOperatorId,
             keyIndex,
             withdrawalAmount,
             witness.slashed
         );
+        MODULE.submitWithdrawals(withdrawalsInfo);
     }
 
     /// @inheritdoc ICSVerifier
@@ -214,12 +217,15 @@ contract CSVerifier is ICSVerifier, AccessControlEnumerable, PausableUntil {
             pubkey: pubkey
         });
 
-        MODULE.submitWithdrawal(
+        ValidatorWithdrawalInfo[]
+            memory withdrawalsInfo = new ValidatorWithdrawalInfo[](1);
+        withdrawalsInfo[0] = ValidatorWithdrawalInfo(
             nodeOperatorId,
             keyIndex,
             withdrawalAmount,
             witness.slashed
         );
+        MODULE.submitWithdrawals(withdrawalsInfo);
     }
 
     function _getParentBlockRoot(

src/interfaces/ICSModule.sol

@@ -39,6 +39,13 @@ struct NodeOperatorManagementProperties {
     bool extendedManagerPermissions;
 }
 
+struct ValidatorWithdrawalInfo {
+    uint256 nodeOperatorId; // @dev ID of the Node Operator
+    uint256 keyIndex; // @dev Index of the withdrawn key in the Node Operator's keys storage
+    uint256 amount; // @dev Amount of withdrawn ETH in wei
+    bool isSlashed; // @dev If validator is slashed or not
+}
+
 /// @title Lido's Community Staking Module interface
 interface ICSModule is IQueueLib, INOAddresses, IAssetRecovererLib {
     error NodeOperatorHasKeys();
@@ -412,18 +419,12 @@ interface ICSModule is IQueueLib, INOAddresses, IAssetRecovererLib {
         uint256 keysCount
     ) external view returns (bytes memory keys, bytes memory signatures);
 
-    /// @notice Report Node Operator's key as withdrawn and settle withdrawn amount
+    /// @notice Report Node Operator's keys as withdrawn and settle withdrawn amount
     /// @notice Called by `CSVerifier` contract.
     ///         See `CSVerifier.processWithdrawalProof` to use this method permissionless
-    /// @param nodeOperatorId ID of the Node Operator
-    /// @param keyIndex Index of the withdrawn key in the Node Operator's keys storage
-    /// @param amount Amount of withdrawn ETH in wei
-    /// @param isSlashed Validator is slashed or not
-    function submitWithdrawal(
-        uint256 nodeOperatorId,
-        uint256 keyIndex,
-        uint256 amount,
-        bool isSlashed
+    /// @param withdrawalsInfo An array for the validator withdrawals info structs
+    function submitWithdrawals(
+        ValidatorWithdrawalInfo[] calldata withdrawalsInfo
     ) external;
 
     /// @notice Check if the given Node Operator's key is reported as withdrawn