Pin opium at 0.18.0

Pinning to the last CoHttp-based version 0.18.0, because 0.19.0 was a major rewrite to switch away from CoHttp[1], but there seem to be intentions to switch back to CoHttp[2]. We do not need to make this detour.

[1]: https://github.com/rgrinberg/opium/blob/0.20.0/CHANGES.md#0190
[2]: rgrinberg/opium#279

Author: knuton

pkgs/default.nix

@@ -18,6 +18,8 @@ let
       ocamlPackages = super.ocamlPackages.overrideScope' (self: super: {
         semver = self.callPackage ./ocaml-modules/semver {};
         obus = self.callPackage ./ocaml-modules/obus {};
+        opium = self.callPackage ./ocaml-modules/opium {};
+        opium_kernel = self.callPackage ./ocaml-modules/opium_kernel {};
       });
 
     };

pkgs/ocaml-modules/opium/default.nix

@@ -0,0 +1,32 @@
+{ buildDunePackage
+
+, ppx_sexp_conv
+, ppx_fields_conv
+
+, cmdliner
+, cohttp-lwt-unix
+, logs
+, magic-mime
+, opium_kernel
+, stringext
+
+, alcotest
+}:
+
+buildDunePackage {
+  pname = "opium";
+  inherit (opium_kernel) version src meta minimumOCamlVersion;
+
+  useDune2 = true;
+
+  doCheck = true;
+
+  buildInputs = [
+    ppx_sexp_conv ppx_fields_conv
+    alcotest
+  ];
+
+  propagatedBuildInputs = [
+    opium_kernel cmdliner cohttp-lwt-unix magic-mime logs stringext
+  ];
+}

pkgs/ocaml-modules/opium_kernel/default.nix

@@ -0,0 +1,44 @@
+{ lib
+, buildDunePackage
+, fetchurl
+
+, ppx_fields_conv
+, ppx_sexp_conv
+
+, cohttp-lwt
+, ezjsonm
+, hmap
+, sexplib
+, fieldslib
+}:
+
+buildDunePackage rec {
+  pname = "opium_kernel";
+  version = "0.18.0";
+
+  useDune2 = true;
+
+  minimumOCamlVersion = "4.04.1";
+
+  src = fetchurl {
+    url = "https://github.com/rgrinberg/opium/releases/download/${version}/opium-${version}.tbz";
+    sha256 = "0a2y9gw55psqhqli3a5ps9mfdab8r46fnbj882r2sp366sfcy37q";
+  };
+
+  doCheck = true;
+
+  buildInputs = [
+    ppx_sexp_conv ppx_fields_conv
+  ];
+
+  propagatedBuildInputs = [
+    hmap cohttp-lwt ezjsonm sexplib fieldslib
+  ];
+
+  meta = {
+    description = "Sinatra like web toolkit for OCaml based on cohttp & lwt";
+    homepage = "https://github.com/rgrinberg/opium";
+    license = lib.licenses.mit;
+    maintainers = [ lib.maintainers.pmahoney ];
+  };
+}