build.gradle

apply plugin: 'es.hadoop.build.integration'

description = "Elasticsearch Hadoop Pig"

evaluationDependsOn(':elasticsearch-hadoop-mr')

configurations {
    embedded {
        transitive = false
        canBeResolved = true
    }
    implementation {
        extendsFrom project.configurations.embedded
    }
}

ext.pigClassifier = "h2"

dependencies {
    embedded(project(":elasticsearch-hadoop-mr"))

    implementation("org.apache.pig:pig:$pigVersion:$pigClassifier")
    implementation("joda-time:joda-time:$jodaVersion")
    implementation("commons-logging:commons-logging:1.1.1")
    implementation("javax.xml.bind:jaxb-api:2.3.1")

    testImplementation(project(":test:shared"))
    testImplementation("org.apache.pig:pig:$pigVersion:$pigClassifier")
    testImplementation("joda-time:joda-time:$jodaVersion")
    testImplementation("com.google.guava:guava:11.0")
    testImplementation("jline:jline:0.9.94")

    itestImplementation(project(":test:shared"))
    itestImplementation("dk.brics.automaton:automaton:1.11-8")

    additionalSources(project(":elasticsearch-hadoop-mr"))
    javadocSources(project(":elasticsearch-hadoop-mr"))
}

jar {
    dependsOn(project.configurations.embedded)
    from(project.configurations.embedded.collect { it.isDirectory() ? it : zipTree(it)}) {
        include "org/elasticsearch/hadoop/**"
        include "esh-build.properties"
        include "META-INF/services/*"
    }
}