Building for MSVC like cargo xwin?

[MrFoxPro]

With cargo-xwin I can successfully build my project to MSVC target. But I’m unable to write Nix derivation to do it using crane.

I tried to replicate cargo-xwin behaviour using source code

packages.ferma-win = let
  # acquired via `xwin download, unpack, splat`
  wlibs = pkgs.stdenvNoCC.mkDerivation {
    name = "windows-libs";
    nativeBuildInputs = [pkgs.zstd];
    src = ./windows-libs.tar.zst;
    sourceRoot = ".";
    installPhase = "mkdir $out && cp -r ./* $out";
  };

  craneLib = inputs.crane.lib.${system};
  crane = craneLib.overrideToolchain rust;
  project = crane.crateNameFromCargoToml {cargoToml = ./Cargo.toml;};
  src = crane.cleanCargoSource (crane.path ./.);

  target = "x86_64-pc-windows-msvc";
  env_target = "x86_64_pc_windows_msvc";

  common =
    project
    // rec {
      inherit src;
      strictDeps = true;
      doCheck = false;
      buildInputs = with pkgs; [pkg-config libllvm clang libclang lld openssl openssl.dev wlibs];
      nativeBuildInputs = buildInputs;
      depsBuildBuild = buildInputs;
      CARGO_BUILD_TARGET = target;
      cargoExtraArgs = "-vvv";
      RUSTFLAGS = lib.concatStringsSep " " [
        "-Clinker-flavor=lld-link"
        "-Lnative=${wlibs}/crt/lib/x86_64"
        "-Lnative=${wlibs}/sdk/lib/um/x86_64"
        "-Lnative=${wlibs}/sdk/lib/ucrt/x86_64"
      ];
      "TARGET_CC" = "clang-cl";
      "TARGET_CXX" = "clang-cl";
      "CC_${env_target}" = "clang-cl";
      "CCX_${env_target}" = "clang-cl";
      "TARGET_AR" = "llvm-lib";
      "AR_${env_target}" = "llvm-lib";
      "CARGO_TARGET_${lib.toUpper env_target}_LINKER" = "lld-link";
      "CARGO_TARGET_${lib.toUpper env_target}_RUNNER" = lib.toUpper env_target;
      "CL_FLAGS" = "--target=${target} -Wno-unused-command-line-argument -fuse-ld=lld-link /imsvc${wlibs}/crt/include /imsvc${wlibs}/sdk/include/ucrt /imsvc${wlibs}/sdk/include/um /imsvc${wlibs}/sdk/include/shared";
      "CFLAGS_${env_target}" = CL_FLAGS;
      "CXXFLAGS_${env_target}" = CL_FLAGS;
      "BINDGEN_EXTRA_CLANG_ARGS_${env_target}" = "-I${wlibs}/crt/include -I${wlibs}/sdk/include/ucrt -I${wlibs}/sdk/include/um -I${wlibs}/sdk/include/shared";
      "RC_FLAGS" = "-I${wlibs}/crt/include -I${wlibs}/sdk/include/ucrt -I${wlibs}/sdk/include/um -I${wlibs}/sdk/include/shared";
      # "CARGO_ENCODED_RUSTFLAGS" = builtins.replaceStrings [" "] ["\\x1f"] RUSTFLAGS;
    };
  artifacts = crane.buildDepsOnly common;
in
  crane.buildPackage (common
    // {
      src = fileset.toSource {
        root = ./.;
        fileset = fileset.unions [
          ./src/script.js
          ./src/dev.js
          (fileset.fromSource (cleanSourceWith {
            src = ./.;
            filter = craneLib.filterCargoSources;
          }))
        ];
      };
      cargoArtifacts = artifacts;
    });

output of sucessful build via cargo-xwin
https://0x0.st/Xrck.txt

output of failed build in Nix
https://0x0.st/XrcD.txt

Most notable:

[ring 0.17.8] cargo:warning=crypto/curve25519/../internal.h(132,10): fatal error: 'stdalign.h' file not found
[ring 0.17.8] cargo:warning=  132 | #include <stdalign.h>
[ring 0.17.8] cargo:warning=      |          ^~~~~~~~~~~~
[ring 0.17.8] cargo:warning=1 error generated.
[ring 0.17.8] exit status: 1
[ring 0.17.8] cargo:warning=ToolExecError: Command "clang-cl" "-nologo" "-MD" "-O2" "-Brepro" "-m64" "--target=x86_64-pc-windows-msvc" "-Wno-unused-command-line-argument" "-fuse-ld=lld-link" "/imsvc/nix/store/arssalx44qdxjpmh124m62zn56fqglfx-windows-libs/crt/include" "/imsvc/nix/store/arssalx44qdxjpmh124m62zn56fqglfx-windows-libs/sdk/include/ucrt" "/imsvc/nix/store/arssalx44qdxjpmh124m62zn56fqglfx-windows-libs/sdk/include/um" "/imsvc/nix/store/arssalx44qdxjpmh124m62zn56fqglfx-windows-libs/sdk/include/shared" "-I" "include" "-I" "/build/source/target/x86_64-pc-windows-msvc/release/build/ring-cfc8ac3d1499ba92/out" "/Gy" "/Zc:wchar_t" "/Zc:forScope" "/Zc:inline" "/Wall" "/wd4127" "/wd4464" "/wd4514" "/wd4710" "/wd4711" "/wd4820" "/wd5045" "-DNDEBUG" "-Fo/build/source/target/x86_64-pc-windows-msvc/release/build/ring-cfc8ac3d1499ba92/out/fad98b632b8ce3cc-curve25519.o" "-c" "--" "crypto/curve25519/curve25519.c" with args "clang-cl" did not execute successfully (status code exit status: 1).cargo:warning=In file included from crypto/fipsmodule/aes/aes_nohw.c:17:
[ring 0.17.8] cargo:warning=crypto/fipsmodule/aes/../../internal.h(132,10): fatal error: 'stdalign.h' file not found

Could you please suggest ideas for fixing this?

[MrFoxPro]

I was finally able to build

let
  craneLib = inputs.crane.lib.${system};
  crane = craneLib.overrideToolchain rust;
  project = crane.crateNameFromCargoToml {cargoToml = ./Cargo.toml;};

  target = "x86_64-pc-windows-msvc";
  envTarget = builtins.replaceStrings ["-"] ["_"] target;

  wlibs = pkgs.stdenvNoCC.mkDerivation {
    name = "windows-libs-17";
    src = ./windows-libs-17.tar.xz;
    sourceRoot = ".";
    installPhase = "mkdir $out && cp -R ./* $out";
    phases = ["unpackPhase" "installPhase"];
  };

  libs = [
    "${pkgs.libclang.lib}/lib/clang/17/include" # PLACE IT FIRST!

    "${wlibs}"
    "${wlibs}/sdk/lib"
    "${wlibs}/sdk/include"
    "${wlibs}/sdk/include/um"
    "${wlibs}/sdk/include/ucrt"
    "${wlibs}/sdk/include/shared"

    "${wlibs}/crt/lib"
    "${wlibs}/crt/include"

    "${wlibs}/crt/lib/x86_64"
    "${wlibs}/sdk/lib/um/x86_64"
    "${wlibs}/sdk/lib/ucrt/x86_64"
  ];

  common =
    project
    // rec {
      src = fileset.toSource {
        root = ./.;
        fileset = fileset.unions [
          ./src/script.js
          ./src/dev.js
          ./resources.res
          ./resources.rc
          ./ic.ico
          (fileset.fromSource (cleanSourceWith {
            src = ./.;
            filter = craneLib.filterCargoSources;
          }))
        ];
      };

      doCheck = false;

      buildInputs = with pkgs; [clang libclang libclang.lib libllvm lld openssl openssl.dev wlibs];
      nativeBuildInputs = with pkgs; [pkg-config] ++ buildInputs;
      depsBuildBuild = nativeBuildInputs;

      "CARGO_BUILD_RUSTFLAGS" = concatStringsSep " " ([
          "-Clinker-flavor=lld-link"
        ]
        ++ map (l: "-Lnative=${l}") libs);
      "CARGO_BUILD_TARGET" = target;
      "CARGO_TARGET_${toUpper envTarget}_LINKER" = "lld-link";
      "CARGO_TARGET_${toUpper envTarget}_RUNNER" = toUpper envTarget;

      "TARGET_CC" = "clang-cl";
      "TARGET_CXX" = TARGET_CC;
      "CC_${envTarget}" = TARGET_CC;
      "CCX_${envTarget}" = TARGET_CC;

      "TARGET_AR" = "llvm-lib";
      "AR_${envTarget}" = TARGET_AR;

      "CL_FLAGS" = concatStringsSep " " ([
          "--target=${target}"
          "-Wno-unused-command-line-argument"
          "-fuse-ld=lld-link"
        ]
        ++ map (str: "/imsvc${str}") libs);
      "CFLAGS_${envTarget}" = CL_FLAGS;
      "CXXFLAGS_${envTarget}" = CL_FLAGS;
      "RC_FLAGS" = concatStringsSep " " ([] ++ map (str: "-I${str}") libs);
      "BINDGEN_EXTRA_CLANG_ARGS_${envTarget}" = RC_FLAGS;

      dontFixup = true;
      dontStrip = true;
    };

  cargoArtifacts = crane.buildDepsOnly common;
in
  crane.buildPackage (common // {inherit cargoArtifacts;});

[MrFoxPro]

btw seems like there is a problem now: dependencies are always rebuilding

[dpc]

Split that buildPackage into buildPackage + buildDepsOnly`. That's usually where the problem lies. There are also some cargo bugs w.r.t build script optimizations that can cause rebuilds of proc-macro deps (search the existing issues).

[ipetkov]

Take a look at the troubleshooting section to see if any of the listed issues match what you are seeing: https://crane.dev/faq/faq.html

Otherwise you can try setting env.CARGO_LOG = "cargo::core::compiler::fingerprint=info"; and seeing if that provides any useful details as to why the artifacts are not being reused

[MrFoxPro]

I see. Does doCheck = false work in my case? I see cargo check command in logs when building dependenciea

[MrFoxPro]

@dpc @ipetkov I see rebuilding of all dependencies happens when I change version of my crate in Cargo.toml. Is it correct?

[ipetkov]

Yeah this is unfortunately expected since that changes both Cargo.toml and Cargo.lock which requires rebuilding dependencies.