Create a Directory from a zipped shapefile URL

Author: jericks

src/main/groovy/geoscript/GeoScript.groovy

@@ -16,7 +16,6 @@ import geoscript.layer.Layer
 import geoscript.filter.Color
 import geoscript.proj.Projection
 import geoscript.workspace.Workspace
-import org.geotools.data.DataUtilities
 
 import java.util.zip.ZipEntry
 import java.util.zip.ZipFile
@@ -354,4 +353,26 @@ class GeoScript {
         }
         dir
     }
+
+    /**
+     * Download a URL to a File
+     * @param options Optional named parameters:
+     * <ul>
+     *     <li>overwrite = Whether to overwrite the existing file or not (defaults to true) </li>
+     * </ul>
+     * @param url The URL
+     * @param file The File
+     * @return The downloaded File
+     */
+    static File download(Map options = [:], URL url, File file) {
+        boolean overwrite = options.get('overwrite', true) as boolean
+        if (overwrite == true || (overwrite == false && !file.exists())) {
+            url.withInputStream { InputStream inputStream ->
+                file.withOutputStream { OutputStream outputStream ->
+                    new BufferedOutputStream(outputStream) << inputStream
+                }
+            }
+        }
+        file
+    }
 }

src/main/groovy/geoscript/workspace/Directory.groovy

@@ -1,5 +1,6 @@
 package geoscript.workspace
 
+import geoscript.GeoScript
 import geoscript.layer.Layer
 import org.geotools.data.DataStore
 import org.geotools.data.DataUtilities
@@ -102,6 +103,26 @@ class Directory extends Workspace {
         "Directory[${getFile().absolutePath}]"
     }
 
+    /**
+     * Get a Directory from a zipped Shapefile
+     * @param options Optional named parameters:
+     * <ul>
+     *     <li>overwrite = Whether to overwrite the existing file or not (defaults to true) </li>
+     * </ul>
+     * @param url The URL of the zipped Shapefile
+     * @param dir The File directory where we will unzip the zip file
+     * @return A Directory Workspace
+     */
+    static Directory fromURL(Map options = [:], URL url, File dir) {
+        if (!dir.exists()) {
+            dir.mkdir()
+        }
+        File file = File.createTempFile("download",".zip")
+        GeoScript.download(url, file, overwrite: options.get("overwrite", true) as boolean)
+        GeoScript.unzip(file, dir)
+        new Directory(dir)
+    }
+
     /**
      * The Directory WorkspaceFactory
      */
@@ -129,6 +150,16 @@ class Directory extends Workspace {
             if (type.equalsIgnoreCase('shapefile') && params.containsKey('file')) {
                 File file = params.get('file') instanceof File ? params.get('file') : new File(params.get('file'))
                 super.create([url: DataUtilities.fileToURL(file.absoluteFile)])
+            } else if (type.equalsIgnoreCase('shapefile') && params.containsKey('url') && params.containsKey("dir")) {
+                URL url = params.get('url') instanceof URL ? params.get('url') : new URL(params.get('url'))
+                File dir = params.get('dir') instanceof File ? params.get('dir') : new File(params.get('dir'))
+                if (!dir.exists()) {
+                    dir.mkdir()
+                }
+                File file = File.createTempFile("download",".zip")
+                GeoScript.download(url, file, overwrite: params.get("overwrite", true) as boolean)
+                GeoScript.unzip(file, dir)
+                super.create([url: DataUtilities.fileToURL(dir.absoluteFile)])
             } else {
                 null
             }

src/main/groovy/geoscript/workspace/Workspace.groovy

@@ -7,6 +7,7 @@ import geoscript.feature.Schema
 import geoscript.layer.Cursor
 import geoscript.layer.Layer
 import org.geotools.data.DataStore
+import org.geotools.data.DataUtilities
 import org.geotools.feature.FeatureCollection
 import org.geotools.data.collection.ListFeatureCollection
 import org.geotools.data.DataStoreFinder
@@ -315,7 +316,19 @@ class Workspace {
                     value = value.substring(1, value.length() - 1)
                 }
                 if (key.equalsIgnoreCase("url")) {
-                    value = new File(value).absoluteFile.toURL()
+                    try {
+                        // URLs with a protocol (file: http:)
+                        value = new URL(value)
+                        File file = DataUtilities.urlToFile(value)
+                        if (file != null) {
+                            value = DataUtilities.fileToURL(file.absoluteFile)
+                        } else {
+                            value = new URL(value)
+                        }
+                    } catch(MalformedURLException e) {
+                        // Files without a protocol
+                        value = new File(value).absoluteFile.toURL()
+                    }
                 }
                 params.put(key, value)
             }

src/test/groovy/geoscript/GeoScriptTestCase.groovy

@@ -253,4 +253,12 @@ class GeoScriptTestCase {
             assertEquals "123", f.text
         }
     }
+
+    @Test void download() {
+        URL url = getClass().getClassLoader().getResource("points.zip")
+        File file = folder.newFile("zipped_points")
+        GeoScript.download(url, file)
+        assertTrue file.exists()
+        assertTrue file.length() > 100
+    }
 }

src/test/groovy/geoscript/workspace/DirectoryTestCase.groovy

@@ -145,5 +145,25 @@ class DirectoryTestCase {
         assertTrue dir.names.contains("states")
     }
 
+    @Test void fromUrl() {
+        URL url = getClass().getClassLoader().getResource("points.zip")
+        File dir = folder.newFolder("points")
+        Directory directory = Directory.fromURL(url, dir)
+        assertTrue directory.names.contains("points")
+    }
+
+    @Test void zippedUrlParamMap() {
+        URL url = getClass().getClassLoader().getResource("points.zip")
+        File dir = folder.newFolder("points")
+        Directory directory = Workspace.getWorkspace([type: "shapefile", url: url, dir: dir])
+        assertTrue directory.names.contains("points")
+    }
+
+    @Test void zippedUrlParamString() {
+        URL url = getClass().getClassLoader().getResource("points.zip")
+        File dir = folder.newFolder("points")
+        Directory directory = Workspace.getWorkspace("type=shapefile url='${url}' dir='${dir}'")
+        assertTrue directory.names.contains("points")
+    }
 }