Arrays

[lv2eof]

Hi,
I have a Arduino Mega 2560 and I wrote the small program that I include at the end.
The problem is that it works fine when I write "#define MAX_CYCLES_ 10" but if I write "#define MAX_CYCLES_ 20" it just doesn't give any output.
I can't understand why.
Maybe is a question of memory allocation but I can't see how and where it is done.
Can you give me please a clue why this happens and how can I solve it.
Many thanks in advance.
Cheers,
Luis

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

#include <Arduino_FreeRTOS.h>

#define MAX_CYCLES_ 10

void v_Task_(void *pvParameters);
void v_PortState_Switch_(int i_PORT_, boolean *b_PortState_);

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

void setup(void) {
    Serial.begin(9600);

    // Wait for serial port.
    while (!Serial) {
        ;
    }

    // xTaskCreate:: .
    // 1 Parameter: Task name.
    // 2 Parameter: A name just for humans.
    // 3 Parameter: This stack size can be checked & adjusted by reading the Stack Highwater.
    // 4 Parameter: .
    // 5 Parameter: Priority, with 3 (configMAX_PRIORITIES - 1) being the highest, and 0 being the lowest.
    // 6 Parameter: .
    xTaskCreate(v_Task_, (const portCHAR *) "v_Task_", 128, NULL, 2, NULL);

    vTaskStartScheduler(); // Start the scheduler.
}

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

void loop() {
    // Nothing here.
}

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////
//
// Task: Each 500ms, this task inverts the value of one GPIO port.
//

void v_Task_(void *pvParameters) {
    const int PORT_ = 4;
    int i;
    int iA_WakeUpTime_Difs_[MAX_CYCLES_];
    TickType_t tt_Frequency_;
    TickType_t tt_WakeUpTime_Computed_;
    TickType_t tt_WakeUpTime_Real_;
    TickType_t tt_WakeUpTime_Real_Last_;
    boolean b_PortState_;
    boolean bA_PortState_[MAX_CYCLES_];

    i = 0;
    tt_Frequency_ = 500 / portTICK_PERIOD_MS;
    tt_WakeUpTime_Computed_ = xTaskGetTickCount(); // Initialise the "tt_WakeUpTime_Computed_" variable with the current time.
    tt_WakeUpTime_Real_ = xTaskGetTickCount();
    b_PortState_ = false;
    pinMode(PORT_, OUTPUT);

    for(;;) {
        tt_WakeUpTime_Real_Last_ = tt_WakeUpTime_Real_;
        vTaskDelayUntil(&tt_WakeUpTime_Computed_, tt_Frequency_); // Wait for the next cycle.
        tt_WakeUpTime_Real_ = xTaskGetTickCount();
        iA_WakeUpTime_Difs_[i] = (int)(tt_WakeUpTime_Real_ - tt_WakeUpTime_Real_Last_);
        bA_PortState_[i] = b_PortState_;
        v_PortState_Switch_(PORT_, &b_PortState_);
        i++;

        if(i == MAX_CYCLES_) {
            vTaskSuspendAll(); // Suspending the scheduler as method of mutual exclusion.

            for(i = 0; i < MAX_CYCLES_; i++) {
                Serial.print(i);
                Serial.write(' ');
                Serial.print(iA_WakeUpTime_Difs_[i]);
                Serial.write(' ');
                Serial.println(bA_PortState_[i]);
            }

            Serial.write('\n');
            Serial.flush();
            i = 0;
            xTaskResumeAll();
        }
    }
}

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

void v_PortState_Switch_(int PORT_, boolean *b_PortState_) {

    if(*b_PortState_) {
        digitalWrite(PORT_, HIGH);
    }
    else {
        digitalWrite(PORT_, LOW);
    }

    *b_PortState_ = !*b_PortState_;
}

////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////////

[feilipu]

I tried your code above and have found that the output is as I would expect.

But, the issue you may be facing is that Task stack storage is defined in the xTaskCreate() function, and is limited to the amount of space that you define in Task creation.

See configMINIMAL_STACK_SIZE
The minimum Stack size is ~85 bytes, leaving ~43 bytes available from the 128 you've assigned.

int i; // 2 bytes
TickType_t tt_Frequency_; // 2 bytes
TickType_t tt_WakeUpTime_Computed_; // 2 bytes
TickType_t tt_WakeUpTime_Real_; // 2 bytes
TickType_t tt_WakeUpTime_Real_Last_; // 2 bytes
boolean b_PortState_; // 1 byte

// subtotal is 11 bytes

int iA_WakeUpTime_Difs_[MAX_CYCLES_]; // 2x MAX_CYCLES_ bytes
boolean bA_PortState_[MAX_CYCLES_]; 1x MAX_CYCLES_ bytes

// subtotal is 3x MAX_CYCLES_

// if MAX_CYCLES_ = 20 you'll need 71 bytes of stack free.
// if MAX_CYCLES_ = 30 you'll need 101 bytes of stack free.

// try setting the stack size to what you need, or better declare your variables as globals (so the IDE can report how much RAM is being used)
// or use pvPortMalloc() to place your variables on the heap, and watch out for heap overflow.

You can use the functions available in freeRTOS to check your stack usage, and ensure that the Task stacks are not overflowing. http://www.freertos.org/Stacks-and-stack-overflow-checking.html

I note that the StackOverflow error flash (4 second cycle) occurs when I increase to 30 iterations...