Add publishing to Maven Central

Author: cketti

.gitignore

@@ -4,6 +4,7 @@
 /TODO*
 
 /kotlin-js-store
+local.properties
 
 ### JetBrains template
 # Covers JetBrains IDEs: IntelliJ, RubyMine, PhpStorm, AppCode, PyCharm, CLion, Android Studio and WebStorm

build.gradle.kts

@@ -1,5 +1,11 @@
+import java.util.Properties
+import org.gradle.api.publish.maven.MavenPublication
+import org.gradle.api.tasks.bundling.Jar
+
 plugins {
     kotlin("multiplatform") version "1.8.0"
+    id("maven-publish")
+    id("signing")
 }
 
 group = "de.cketti.unicode"
@@ -59,3 +65,83 @@ kotlin {
         val nativeTest by getting
     }
 }
+
+// Stub secrets to let the project sync and build without the publication values set up
+ext["signing.keyId"] = null
+ext["signing.password"] = null
+ext["signing.secretKeyRingFile"] = null
+ext["ossrhUsername"] = null
+ext["ossrhPassword"] = null
+
+// Grabbing secrets from local.properties file or from environment variables, which could be used on CI
+val secretPropsFile = project.rootProject.file("local.properties")
+if (secretPropsFile.exists()) {
+    secretPropsFile.reader().use {
+        Properties().apply {
+            load(it)
+        }
+    }.onEach { (name, value) ->
+        ext[name.toString()] = value
+    }
+} else {
+    ext["signing.keyId"] = System.getenv("SIGNING_KEY_ID")
+    ext["signing.password"] = System.getenv("SIGNING_PASSWORD")
+    ext["signing.secretKeyRingFile"] = System.getenv("SIGNING_SECRET_KEY_RING_FILE")
+    ext["ossrhUsername"] = System.getenv("OSSRH_USERNAME")
+    ext["ossrhPassword"] = System.getenv("OSSRH_PASSWORD")
+}
+
+val javadocJar by tasks.registering(Jar::class) {
+    archiveClassifier.set("javadoc")
+}
+
+fun getExtraString(name: String) = ext[name]?.toString()
+
+publishing {
+    // Configure maven central repository
+    repositories {
+        maven {
+            name = "sonatype"
+            setUrl("https://oss.sonatype.org/service/local/staging/deploy/maven2/")
+            credentials {
+                username = getExtraString("ossrhUsername")
+                password = getExtraString("ossrhPassword")
+            }
+        }
+    }
+
+    // Configure all publications
+    publications.withType<MavenPublication> {
+        // Stub javadoc.jar artifact
+        artifact(javadocJar.get())
+
+        // Provide artifacts information requited by Maven Central
+        pom {
+            name.set("kotlin-codepoints")
+            description.set("Kotlin Multiplatform (KMP) library that adds basic support for Unicode code points.")
+            url.set("https://github.com/cketti/kotlin-codepoints")
+
+            licenses {
+                license {
+                    name.set("MIT")
+                    url.set("https://opensource.org/licenses/MIT")
+                }
+            }
+            developers {
+                developer {
+                    id.set("cketti")
+                    name.set("cketti")
+                    email.set("[email protected]")
+                }
+            }
+            scm {
+                url.set("https://github.com/cketti/kotlin-codepoints")
+            }
+        }
+    }
+}
+
+// Signing artifacts. Signing.* extra properties values will be used
+signing {
+    sign(publishing.publications)
+}