How to use DBEnum

[idontgetoutmuch]

I have

{-# OPTIONS_GHC -Wall -Wno-type-defaults #-}

{-# LANGUAGE OverloadedStrings #-}
{-# LANGUAGE DerivingStrategies #-}
{-# LANGUAGE TypeFamilies #-}
{-# LANGUAGE ScopedTypeVariables #-}
{-# LANGUAGE DeriveGeneric #-}
{-# LANGUAGE DeriveAnyClass #-}
{-# LANGUAGE QuasiQuotes #-}
{-# LANGUAGE TypeApplications #-}
{-# LANGUAGE DisambiguateRecordFields #-}
{-# LANGUAGE StandaloneDeriving #-}
{-# LANGUAGE GeneralizedNewtypeDeriving #-}
{-# LANGUAGE FlexibleInstances #-}
{-# LANGUAGE DerivingVia #-}

module Main where

import Control.Monad.IO.Unlift
import Data.Int
import Data.Text
import Hasql.Connection
import Hasql.Session
import Hasql.Statement
import Hasql.Transaction
import qualified Hasql.Transaction.Sessions as Transaction
import Hasql.TH
import GHC.Generics

import Rel8


data Mood = Sad | Ok | Happy
 deriving (Eq, Read, Show, Generic, DBEq)

instance DBEnum Mood where
  enumTypeName = "mood"

instance DBType Mood where
  typeInformation = parseTypeInformation parser printer typeInformation
    where
      parser :: Text -> Either String Mood
      parser "Sad" = Right Sad
      parser "Ok"  = Right Ok
      parser "Happy" = Right Happy
      parser other   = Left $ "Unknown Mood: " <> unpack other

      printer :: Mood -> Text
      printer Sad = "Sad"
      printer Ok = "Ok"
      printer Happy = "Happy"

data Author f = Author
  { authorId :: Column f AuthorId
  , name :: Column f Text
  , url :: Column f (Maybe Text)
  , mood :: Column f Mood
  }
  deriving stock (Generic)
  deriving anyclass (Rel8able)

deriving stock instance f ~ Result => Show (Author f)

newtype AuthorId = AuthrId { toInt64 :: Int64 }
  deriving newtype (DBEq, DBType, DBNum, Eq, Show)

authorSchema :: TableSchema (Author Name)
authorSchema = TableSchema
  { name = "author"
  , schema = Nothing
  , columns = Author
    { authorId = "author_id"
    , name = "name"
    , url = "url"
    , mood = "mood"
    }
  }

main :: IO ()
main = do
  let config = settings "localhost" 5432 "dom" "" "postgres"
  conn <- either (error . show) id <$> acquire config
  res <- flip run conn $ do
    Transaction.transaction Transaction.ReadCommitted Transaction.Write $ Hasql.Transaction.sql [uncheckedSql|
      drop table if exists author cascade;
      drop type if exists mood;
      create type mood AS enum ('Sad', 'Ok', 'Happy');
      create table author (
        author_id integer not null,
        name text not null,
        url text,
        mood mood,
        primary key(author_id)
      );
      insert into author values
        (1, 'Ollie', 'Foo', 'Sad'),
        (2, 'Bryan O''Sullivan', 'Bar', 'Ok'),
        (3, 'Emily Pilmore', 'Baz', 'Happy');
    |]
    Transaction.transaction Transaction.ReadCommitted Transaction.Write $ Hasql.Transaction.sql [uncheckedSql|
       SELECT
       CAST(author_id0_1 AS int8) as authorId,
       CAST(name1_1 AS text) as name,
       CAST(url2_1 AS text) as url,
       CAST(mood3_1 AS text) as mood
       FROM (SELECT
             *
             FROM (SELECT
                   author_id as author_id0_1,
                   name as name1_1,
                   url as url2_1,
                   mood as mood3_1
                   FROM author as T1) as T1
             WHERE ((CAST(E'Sad' AS mood)) = (mood3_1))) as T1
      |]
    let stmt1 :: Statement () [Author Result]
        stmt1 = select (Rel8.filter ((lit Sad ==.) . mood) =<< each authorSchema)
    Hasql.Session.statement () stmt1 >>= mapM_ (liftIO . print)
  print res

But

mapM_ print $ Prelude.lines $ showQuery (Rel8.filter ((lit Sad ==.) . mood) =<< each authorSchema)
"SELECT"
"CAST(\"author_id0_1\" AS int8) as \"authorId\","
"CAST(\"name1_1\" AS text) as \"name\","
"CAST(\"url2_1\" AS text) as \"url\","
"CAST(\"mood3_1\" AS text) as \"mood\""
"FROM (SELECT"
"      *"
"      FROM (SELECT"
"            \"author_id\" as \"author_id0_1\","
"            \"name\" as \"name1_1\","
"            \"url\" as \"url2_1\","
"            \"mood\" as \"mood3_1\""
"            FROM \"author\" as \"T1\") as \"T1\""
"      WHERE ((CAST(E'Sad' AS text)) = (\"mood3_1\"))) as \"T1\""

Note in the last line CAST(E'Sad' AS text) when it should be CAST(E'Sad' AS mood)

What else do I need to do to convince Rel8 to use mood?

[idontgetoutmuch]

data Mood = Sad | Ok | Happy
 deriving (Eq, Read, Show, Generic, DBEq)
 deriving DBType via (Rel8.Enum Mood)