feat(home-manager): add support for vscode (#509)

Author: getchoo

modules/home-manager/all-modules.nix

@@ -47,6 +47,7 @@
   ./thunderbird.nix
   ./tmux.nix
   ./tofi.nix
+  ./vscode.nix
   ./waybar.nix
   ./wlogout.nix
   ./yazi.nix

modules/home-manager/vscode.nix

@@ -0,0 +1,42 @@
+{ catppuccinLib }:
+{ config, lib, ... }:
+
+let
+  inherit (config.catppuccin) sources;
+  cfg = config.catppuccin.vscode;
+
+  usesPerProfileCfg = lib.versionAtLeast catppuccinLib.getModuleRelease "25.05";
+  settings = {
+    extensions = [ sources.vscode ];
+
+    userSettings = {
+      "workbench.colorTheme" = "Catppuccin " + catppuccinLib.mkUpper cfg.flavor;
+      "catppuccin.accentColor" = cfg.accent;
+
+      # Recommended settings
+      # https://github.com/catppuccin/vscode?tab=readme-ov-file#vscode-settings
+      "editor.semanticHighlighting.enabled" = lib.mkDefault true;
+      "terminal.integrated.minimumContrastRatio" = lib.mkDefault 1;
+      "window.titleBarStyle" = lib.mkDefault "custom";
+    };
+  };
+in
+
+{
+  options.catppuccin.vscode = catppuccinLib.mkCatppuccinOption {
+    name = "vscode";
+    accentSupport = true;
+  };
+
+  config = lib.mkIf cfg.enable {
+    # TODO: Remove compat layer when 25.05 is stable
+    # https://github.com/nix-community/home-manager/pull/5640
+    programs.vscode =
+      if usesPerProfileCfg then
+        {
+          profiles.default = settings;
+        }
+      else
+        settings;
+  };
+}

modules/tests/home.nix

@@ -1,4 +1,4 @@
-{ lib, ... }:
+{ lib, pkgs, ... }:
 
 {
   imports = [
@@ -65,6 +65,10 @@
       enable = true;
       profiles.catppuccin-mocha-mauve.isDefault = true;
     };
+    vscode = {
+      enable = true;
+      package = pkgs.vscodium;
+    };
     waybar.enable = true;
     wlogout.enable = true;
     yazi.enable = true;

pkgs/vscode/package.nix

@@ -0,0 +1,10 @@
+{ vscode-utils, ... }:
+
+vscode-utils.buildVscodeMarketplaceExtension {
+  mktplcRef = {
+    name = "catppuccin-vsc";
+    publisher = "catppuccin";
+    version = "3.16.1";
+    hash = "sha256-qEwQ583DW17dlJbODN8SNUMbDMCR1gUH4REaFkQT65I=";
+  };
+}