build.gradle

plugins {
    id 'java'
    id 'jacoco'
    id 'eclipse'
    id 'checkstyle'
    id 'distribution'
    id 'nebula.release' version '17.2.1'
    id 'org.omegat.gradle'  version '1.4.2'
    id 'com.diffplug.spotless' version '6.13.0'
}

sourceCompatibility = JavaVersion.VERSION_1_8
targetCompatibility = JavaVersion.VERSION_1_8

omegat {
    version = "5.7.1"
    pluginClass = "net.briac.omegat.plugin.odtreview.ODTReviewPlugin"
}

release {
  defaultVersionStrategy = nebula.plugin.release.git.opinion.Strategies.SNAPSHOT
}

dependencies {
    packIntoJar  group: 'org.slf4j', name: 'slf4j-api', version: '1.7.21'
    // The ODF Simple API is gone in version > 0.9.0, after that we'll have to
    // use the 'odfdom-java' package
    packIntoJar group: 'org.odftoolkit', name: 'simple-odf', version: '0.9.0'

    implementation group: 'commons-io', name: 'commons-io', version: '2.5'
    implementation group: 'commons-lang', name: 'commons-lang', version: '2.6'
    implementation group: 'org.omegat', name: 'lib-mnemonics', version: '1.0'

    implementation group: 'com.devskiller', name: 'jfairy', version: '0.6.4'
    testImplementation group: 'junit', name: 'junit', version: '4.12'
    testImplementation group: 'xmlunit', name: 'xmlunit', version: '1.6'

}

checkstyle {
    ignoreFailures = true
    toolVersion = '7.1'
}

distributions {
    main {
        contents {
            from(jar)
            from('README.md', 'COPYING', 'CHANGELOG.md')
        }
    }
}

spotless {
    java {
        licenseHeaderFile rootProject.file('config/spotless/license.txt')
        targetExclude 'src/gen/**'
        eclipse().configFile 'config/eclipse/eclipse-formatting.xml'
        removeUnusedImports()
    }
}