improvement: verify pub_sub actions at compile time

Author: zachdaniel

Diff for: lib/ash/notifier/pub_sub/pub_sub.ex

@@ -201,7 +201,9 @@ defmodule Ash.Notifier.PubSub do
   - `:broadcast` sends `%{topic: (topic), event: (event), notification: (notification)}`
   """
 
-  use Spark.Dsl.Extension, sections: @sections
+  use Spark.Dsl.Extension,
+    sections: @sections,
+    verifiers: [Ash.Notifier.PubSub.Verifiers.VerifyActionNames]
 
   use Ash.Notifier
 

Diff for: lib/ash/notifier/pub_sub/verifiers/verify_action_names.ex

@@ -0,0 +1,35 @@
+defmodule Ash.Notifier.PubSub.Verifiers.VerifyActionNames do
+  use Spark.Dsl.Verifier
+
+  def verify(dsl) do
+    module =
+      Spark.Dsl.Verifier.get_persisted(dsl, :module)
+
+    for publication <- Ash.Notifier.PubSub.Info.publications(dsl),
+        not is_nil(publication.action) do
+      action = Ash.Resource.Info.action(dsl, publication.action)
+
+      if !action do
+        raise Spark.Error.DslError,
+          path: [:pub_sub, :publish, publication.action],
+          module: module,
+          message: """
+          Non-existent action #{inspect(module)}.#{publication.action} referenced in `pub_sub` notifier.
+          """
+      end
+
+      if action.type == :action do
+        raise Spark.Error.DslError,
+          path: [:pub_sub, :publish, publication.action],
+          module: module,
+          message: """
+          Invalid action #{inspect(module)}.#{publication.action} referenced in `pub_sub` notifier.
+
+          Only create, update and destroy actions emit notifications, not generic actions.
+          """
+      end
+    end
+
+    :ok
+  end
+end