From be42d62dc6d1e9c3b7f26a67636c7971e4b7ba31 Mon Sep 17 00:00:00 2001
From: taotieren <admin@taotieren.com>
Date: Sun, 29 Jan 2023 23:52:05 +0800
Subject: [PATCH] Add python-fontparts-git

---
 archlinuxcn/python-fontparts-git/PKGBUILD   | 47 +++++++++++++++++++++
 archlinuxcn/python-fontparts-git/lilac.yaml | 13 ++++++
 2 files changed, 60 insertions(+)
 create mode 100644 archlinuxcn/python-fontparts-git/PKGBUILD
 create mode 100644 archlinuxcn/python-fontparts-git/lilac.yaml

diff --git a/archlinuxcn/python-fontparts-git/PKGBUILD b/archlinuxcn/python-fontparts-git/PKGBUILD
new file mode 100644
index 000000000000..14199166ddfa
--- /dev/null
+++ b/archlinuxcn/python-fontparts-git/PKGBUILD
@@ -0,0 +1,47 @@
+# Maintainer: taotieren <admin@taotieren.com>
+
+pkgname=python-fontparts-git
+pkgver=0.11.0.r1.gf5250dc
+pkgrel=1
+pkgdesc='The replacement for RoboFab'
+url='https://github.com/robotools/fontParts'
+license=('MIT')
+arch=(any)
+_pydeps=(booleanoperations
+         defcon
+         fontmath
+         fontpens # for defcon[pens]
+         fonttools
+         fs # for fonttools[ufo]
+         lxml # for fonttools[lxml]
+         unicodedata2) # for fonttools[unicode]
+depends=(python
+         "${_pydeps[@]/#/python-}")
+makedepends=(python-{build,installer}
+             python-setuptools-scm
+             python-wheel)
+provides=("${pkgname%-git}")
+conflicts=("${pkgname%-git}")
+source=("$pkgname::git+$url.git")
+sha256sums=('SKIP')
+
+pkgver() {
+    cd "$pkgname"
+    git describe --long --tags | sed 's/^v//g;s/\([^-]*-g\)/r\1/;s/-/./g'
+}
+
+build() {
+    cd "$pkgname"
+    python -m build -wn
+}
+
+check() {
+    cd "$pkgname/Lib"
+    PYTHONPATH=. python "fontParts/fontshell/test.py"
+}
+
+package() {
+    cd "$pkgname"
+    python -m installer -d "$pkgdir" dist/*.whl
+}
+
diff --git a/archlinuxcn/python-fontparts-git/lilac.yaml b/archlinuxcn/python-fontparts-git/lilac.yaml
new file mode 100644
index 000000000000..69edeba34e66
--- /dev/null
+++ b/archlinuxcn/python-fontparts-git/lilac.yaml
@@ -0,0 +1,13 @@
+maintainers:
+  - github: taotieren
+
+build_prefix: archlinuxcn-x86_64
+
+pre_build: vcs_update
+
+post_build_script: |
+  git_pkgbuild_commit()
+
+update_on:
+  - source: github
+    github: robotools/fontParts