build.gradle

ext {
    grailsVersion = projectVersion
    isCiBuild = System.getenv().get('CI') as Boolean

    // Directories created during the build which are related
    // to turning the workspace root into a GRAILS_HOME
    distInstallDir = layout.buildDirectory.dir('dist-tmp')
    homeDistDir = layout.projectDirectory.dir('dist')
    homeBinDir = layout.projectDirectory.dir('bin')
    homeConfDir = layout.projectDirectory.dir('conf')
    homeLibDir = layout.projectDirectory.dir('lib')

    testProjectsStartWith = [
            'grails-test-suite',
            'grails-test-examples'
    ]
    testProjects = [ /* Will be populated by subprojects loop below */ ]
}

allprojects {
    repositories {
        mavenCentral()
        maven { url = 'https://repo.grails.org/grails/core' }
        maven { url = 'https://oss.sonatype.org/content/repositories/snapshots' }
        maven { url = 'https://repository.apache.org/content/repositories/snapshots' }
        // mavenLocal() // Keep, this will be uncommented and used by CI (groovy-joint-workflow)
    }
}

subprojects {

    for (String testPrefix : testProjectsStartWith) {
        if (name.startsWith(testPrefix)) {
            rootProject.ext['testProjects'] << name
        }
    }

    configurations.configureEach {
        resolutionStrategy {
            def cacheHours = isCiBuild ? 0 : 24
            cacheDynamicVersionsFor(cacheHours, 'hours')
            cacheChangingModulesFor(cacheHours, 'hours')
            eachDependency { DependencyResolveDetails details ->
                if (details.requested.group == 'org.apache.groovy') {
                    details.useVersion(groovyVersion)
                }
            }
        }
    }

    // This is added to prevent a remote cache misses, because the project JAR include a manifest
    // file with Built-By and Created-By properties which might be different for CI vs Local.
    normalization {
        runtimeClasspath {
            metaInf {
                ignoreAttribute('Built-By')
                ignoreAttribute('Created-By')
            }
        }
    }
    apply from: rootProject.layout.projectDirectory.file('gradle/dependency-licenses.gradle')
}

tasks.register('clean', Delete) {
    group = 'build'
    delete(layout.buildDirectory, homeBinDir, homeConfDir, homeDistDir, homeLibDir)
}

apply {
    from layout.projectDirectory.file('gradle/docs-root-config.gradle')
    from layout.projectDirectory.file('gradle/assemble-root-config.gradle')
    from layout.projectDirectory.file('gradle/publish-root-config.gradle')
}