GH-46165: [C++] Add cuda option to Meson configuration

Author: WillAyd

ci/docker/conda-cpp.dockerfile

@@ -38,6 +38,8 @@ RUN mamba install -q -y \
         doxygen \
         libnuma \
         mold \
+        nvidia::cuda \
+        nvidia::cuda-toolkit \
         python=${python} \
         valgrind && \
     mamba clean --all --yes

ci/scripts/cpp_build.sh

@@ -139,6 +139,9 @@ if [ "${ARROW_USE_MESON:-OFF}" = "ON" ]; then
       fi
     fi
   fi
+
+  export CUDA_PATH="${CONDA_PREFIX}"
+  env
   meson setup \
     --prefix=${MESON_PREFIX:-${ARROW_HOME}} \
     --buildtype=${ARROW_BUILD_TYPE:-debug} \

cpp/meson.build

@@ -62,8 +62,15 @@ needs_filesystem = get_option('filesystem').enabled() or needs_azure or needs_gc
 needs_integration = get_option('integration').enabled()
 needs_tests = get_option('tests').enabled()
 needs_acero = get_option('acero').enabled()
+needs_cuda = get_option('cuda').enabled()
 needs_flight = get_option('flight').enabled()
-needs_ipc = get_option('ipc').enabled() or needs_tests or needs_acero or needs_benchmarks or needs_flight
+needs_ipc = (get_option('ipc').enabled()
+or needs_tests
+or needs_acero
+or needs_benchmarks
+or needs_cuda
+or needs_flight
+)
 needs_fuzzing = get_option('fuzzing').enabled()
 needs_testing = (get_option('testing').enabled()
     or needs_tests

cpp/meson.options

@@ -39,6 +39,11 @@ option(
     description: 'Build all Arrow Compute kernels',
 )
 option('csv', type: 'feature', description: 'Build the Arrow CSV Parser Module')
+option(
+    'cuda',
+    type: 'feature',
+    description: 'Build the Arrow CUDA extensions (requires CUDA toolkit)',
+)
 option(
     'filesystem',
     type: 'feature',

cpp/src/arrow/gpu/meson.build

@@ -0,0 +1,76 @@
+# Licensed to the Apache Software Foundation (ASF) under one
+# or more contributor license agreements.  See the NOTICE file
+# distributed with this work for additional information
+# regarding copyright ownership.  The ASF licenses this file
+# to you under the Apache License, Version 2.0 (the
+# "License"); you may not use this file except in compliance
+# with the License.  You may obtain a copy of the License at
+#
+#   http://www.apache.org/licenses/LICENSE-2.0
+#
+# Unless required by applicable law or agreed to in writing,
+# software distributed under the License is distributed on an
+# "AS IS" BASIS, WITHOUT WARRANTIES OR CONDITIONS OF ANY
+# KIND, either express or implied.  See the License for the
+# specific language governing permissions and limitations
+# under the License.
+
+cuda_dep = dependency('cuda', modules: ['cuda'])
+
+arrow_cuda_srcs = [
+    'cuda_arrow_ipc.cc',
+    'cuda_context.cc',
+    'cuda_internal.cc',
+    'cuda_memory.cc',
+]
+
+arrow_cuda_lib = library(
+    'arrow-cuda',
+    sources: [arrow_cuda_srcs],
+    dependencies: [arrow_dep, cuda_dep, flatbuffers_dep],
+    cpp_args: ['-DARROW_CUDA_EXPORTING'],
+)
+
+arrow_cuda_dep = declare_dependency(
+    link_with: [arrow_cuda_lib],
+    dependencies: [cuda_dep],
+)
+
+cuda_version = cuda_dep.version()
+cuda_split_version = cuda_version.split('.')
+cuda_conf_data = configuration_data()
+cuda_conf_data.set('CUDA_VERSION_MAJOR', cuda_split_version[0])
+cuda_conf_data.set('CUDA_VERSION_MINOR', cuda_split_version[1])
+
+configure_file(
+    input: 'cuda_version.h.in',
+    output: 'cuda_version.h',
+    configuration: cuda_conf_data,
+    install_dir: 'arrow/gpu',
+)
+
+install_headers(
+    [
+        'cuda_api.h',
+        'cuda_arrow_ipc.h',
+        'cuda_context.h',
+        'cuda_internal.h',
+        'cuda_memory.h',
+        'visibility.h',
+    ],
+    subdir: 'arrow/gpu',
+)
+
+exc = executable(
+    'arrow-cuda-test',
+    sources: ['cuda_test.cc'],
+    dependencies: [arrow_test_dep, arrow_cuda_dep],
+)
+test('arrow-cuda-test', exc)
+
+exc = executable(
+    'arrow-cuda-benchmark',
+    sources: ['cuda_benchmark.cc'],
+    dependencies: [arrow_benchmark_dep, arrow_cuda_dep],
+)
+benchmark('arrow-gpu-cuda-benchmark', exc)

cpp/src/arrow/meson.build

@@ -769,6 +769,10 @@ if needs_acero
     subdir('acero')
 endif
 
+if needs_cuda
+    subdir('gpu')
+endif
+
 if needs_filesystem
     subdir('filesystem')
 endif