Pack.sol

pragma solidity ^0.8.22;

contract Packbad {
    uint80 public a;
    uint256 public b;
    uint80 public c;
    uint256 public d;
    address public e;

    function calls() public {
        a = 12;
        c = 34;
        e = address(0x1234567890);
    }
}

contract Packgood {
    uint256 public a;
    uint256 public b;
    uint80 public c;
    uint80 public d;
    address public e;

    function calls() public {
        a = 12;
        c = 34;
        e = address(0x1234567890);
    }
}

contract Packbest {
    uint256 public a;
    uint256 public b;
    uint160 public cd;
    address public e;

    function calls() public {
        pack(12, 34);
        e = address(0x1234567890);
    }

    function pack(uint80 x, uint80 y) private {
        cd = (uint160(x) << 80) | uint160(y);
    }

    function unpack() external view returns (uint80, uint80) {
        uint80 x = uint80(cd >> 80);
        uint80 y = uint80(cd);
        return (x, y);
    }
}

contract Unpacked_Struct {
    struct unpackedStruct {
        uint64 time; // Takes one slot - although it  only uses 64 bits (8 bytes) out of 256 bits (32 bytes).
        uint256 money; // This will take a new slot because it is a complete 256 bits (32 bytes) value and thus cannot be packed with the previous value.
        address person; // An address occupies only 160 bits (20 bytes).
    }

    // Starts at slot 0
    unpackedStruct details =
        unpackedStruct(53_000, 21_000, address(0xdeadbeef));

    function unpack() external view returns (unpackedStruct memory) {
        return details;
    }
}

contract Packed_Struct {
    struct packedStruct {
        uint64 time; // In this case, both `time` (64 bits) and `person` (160 bits) are packed in the same slot since they can both fit into 256 bits (32 bytes)
        address person; // Same slot as `time`. Together they occupy 224 bits (28 bytes) out of 256 bits (32 bytes).
        uint256 money; // This will take a new slot because it is a complete 256 bits (32 bytes) value and thus cannot be packed with the previous value.
    }

    // Starts at slot 0
    packedStruct details = packedStruct(53_000, address(0xdeadbeef), 21_000);

    function unpack() external view returns (packedStruct memory) {
        return details;
    }
}