sequence.rv

import { ... } from "./core.rv"
import { ... } from "./numbers.rv"
import { isa? } from "./patterns.rv"

export {
  Sequence, seq, first, rest, prepend, empty?, length, seqRange, repeat, sum
}

bundle Sequence { Prepend(xs, x), Empty() }

fn prepend(xs: Sequence, x) { Prepend(xs, x) }

fn seq() { Empty() }
fn seq(x, xs...) { prepend(seq(xs...), x) }

fn first(l: Empty) { abort("first: seq is empty") }
fn first(l: Prepend) { part(l, 2) }

@extend
fn rest(l: Empty) { abort("rest: seq is empty") }

@extend
fn rest(l: Prepend) { part(l, 1) }

@extend
fn empty?(_: Prepend) { false }

@extend
fn empty?(_: Empty) { true }

@extend
fn length(Prepend(xs, _)) { 1 + length(xs) }

@extend
fn length(Empty()) { 0 }

fn seqRange(start, end) {
  if start > end {
    seq()
  } else {
    prepend(seqRange(start + one(start), end), start)
  }
}

fn repeat(n, x) { prepend(repeat(n - 1, x), x) }
fn repeat(0, x) { seq() }

fn sum(Empty(), total) { total }
fn sum(Prepend(xs, x), total) { sum(xs, total + x) }

fn sum(Prepend(xs, x)) { sum(xs, x) }

fn printList(Empty()) {
  print(")")
}

fn printList(Prepend(xs, x)) {
  print(x)
  if !isa?(xs, Empty) {
    print(", ")
  }
  printList(xs)
}

@extend
fn show(xs: Sequence) {
  print("seq(")
  printList(xs)
}