THIP-Server/jacoco.gradle at develop · THIP-TextHip/THIP-Server · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
jacoco {
    toolVersion = "0.8.12"
}

tasks.named('test') {
    useJUnitPlatform()
    finalizedBy tasks.jacocoTestReport
}

tasks.named('jacocoTestReport', JacocoReport) {
    dependsOn(tasks.test)

    def mainClasses = files(sourceSets.main.output).asFileTree.matching {
        exclude(
                "**/generated/**",
                "**/build/**",
                "**/*Application*",
                "**/*Config*",
                "**/*Dto*",
                "**/*Request*",
                "**/*Response*",
                "**/generated/querydsl/**",
                "**/Q*.*"
        )
    }

    additionalSourceDirs.from files(sourceSets.main.allSource.srcDirs)
    sourceDirectories.from files(sourceSets.main.allSource.srcDirs)
    classDirectories.setFrom(mainClasses)
    executionData.from fileTree(project.rootDir) {
        include "**/build/jacoco/*.exec"
    }

    reports {
        html.required.set(true)
        xml.required.set(true)
        csv.required.set(false)
    }
}

tasks.named('jacocoTestCoverageVerification', JacocoCoverageVerification) {
    dependsOn(tasks.test)

    classDirectories.setFrom(
            files(sourceSets.main.output).asFileTree.matching {
                exclude(
                        "**/generated/**",
                        "**/build/**",
                        "**/*Application*",
                        "**/*Config*",
                        "**/*Dto*",
                        "**/*Request*",
                        "**/*Response*",
                        "**/generated/querydsl/**",
                        "**/Q*.*"
                )
            }
    )

    violationRules {
        rule {
            element = 'CLASS'
            limit {
                counter = 'INSTRUCTION'
                value = 'COVEREDRATIO'
                minimum = 0.00
            }
            limit {
                counter = 'BRANCH'
                value = 'COVEREDRATIO'
                minimum = 0.00
            }
        }
    }
}

tasks.named('check') {
    dependsOn tasks.named('jacocoTestCoverageVerification')
}