build.gradle

plugins {
    id 'java'
    id 'idea'
    id 'net.minecraftforge.gradle' version '[6.0,6.2)'
    id 'org.spongepowered.mixin' version '0.7.+'
    id 'org.parchmentmc.librarian.forgegradle' version '1.+'
    id "me.modmuss50.mod-publish-plugin" version "0.8.3"
}

def MT_TOKEN = System.getenv("MODRINTH_TOKEN")
def CF_TOKEN = System.getenv("CURSEFORGE_TOKEN")

base {
    archivesName = modid
    version = "$modloader-mc$mcversion-v$modversion"
}

java.toolchain {
    languageVersion = JavaLanguageVersion.of(17)
}

println "Java: ${System.getProperty 'java.version'}, Gradle Java: ${JavaVersion.current()}, JVM: ${System.getProperty 'java.vm.version'} (${System.getProperty 'java.vendor'}), Arch: ${System.getProperty 'os.arch'}"
minecraft {
    mappings channel: mappings_channel, version: "$mappings_version"
    accessTransformer file('src/main/resources/META-INF/accesstransformer.cfg')
    copyIdeResources = true

    runs {
        configureEach {
            workingDirectory project.file('run')
            property 'forge.logging.console.level', 'debug'
            property 'log4j.appender.Console', "org.apache.log4j.ConsoleAppender"
            property 'terminal.jline', 'true'
            args '--mixin.config', "$modid.$mixin_file_suffix"
            arg '--nogui'

            mods {
                "$modid" {
                    source sourceSets.main
                }
            }
        }

        client {}
        server {}
    }
}

sourceSets.main.resources { srcDir 'src/generated/resources' }

mixin {
    add sourceSets.main, "$modid.$mixin_refmap_suffix"
    config "$modid.$mixin_file_suffix"
}

repositories {
    maven { url 'https://maven.minecraftforge.net/' }
    maven { url 'https://repo.spongepowered.org/maven' }
    maven { url 'https://jitpack.io' }
    maven { url 'https://www.cursemaven.com'
        content {includeGroup 'curse.maven' }
    }
}

dependencies {
    minecraft "net.minecraftforge:forge:$mcversion-$fgversion"
    annotationProcessor 'org.spongepowered:mixin:0.8.5:processor'

    //DEPENDENCIES
    implementation "com.github.WaterMediaTeam:watermedia:$watermediaversion"
    implementation fg.deobf("curse.maven:creativecore-257814:${creativecoreversion}")
}

tasks.processResources.outputs.upToDateWhen { false }
processResources {
    filesMatching(['META-INF/*.toml', 'pack.mcmeta', 'resourcepacks/**/pack.mcmeta', "$modid.$mixin_file_suffix".toString()]) {
        expand project.properties
    }
}

jar {
    manifest {
        attributes "Specification-Title"        : modid
        attributes "Specification-Vendor"       : modauthor
        attributes "Specification-Version"      : version
        attributes "Implementation-Title"       : modname
        attributes "Implementation-Version"     : version
        attributes "Implementation-Vendor"      : modauthor
        attributes "Implementation-Timestamp"   : new Date().format("yyyy-MM-dd'T'HH:mm:ssZ")
        attributes "MixinConfigs"               : "$modid.$mixin_file_suffix"
    }
    exclude('org/valkyrienskies/**')
    finalizedBy('reobfJar')
}

publishMods {
    file = jar.archiveFile
    displayName = "WF-$modloader/mc$mcversion/v$modversion"
    type = STABLE
    changelog = getChangelogText()

    maxRetries = 2
    dryRun = false

    modLoaders.add(modloader.toLowerCase())

    curseforge {
        accessToken = CF_TOKEN
        projectId = curseforgeid
        minecraftVersions.addAll(mcversion)
        javaVersions.addAll(JavaVersion.VERSION_17)
        clientRequired = true
        serverRequired = true
        projectSlug = modid
        requires("creativecore", "watermedia")
    }

    modrinth {
        accessToken = MT_TOKEN
        projectId = modrinthid
        minecraftVersions.addAll(mcversion)
        requires("creativecore", "watermedia")
    }
}

def getChangelogText() {
    def result = ""
    for (String line: file('CHANGELOG.md').readLines('UTF-8')) {
        if (line.isEmpty()) return result
        result += line + '\n'
    }
    return result
}