6 Weeks - [InvokeDynamic]

[dpwns523]

문제

책의 끝 부분 Appendix에서 자바 컴파일러가 람다 표현식을 어떻게 구현하고 JVM은 컴파일러의 결과물을 어떻게 처리하는 지에 대해 설명하고 있습니다.

invokedynamic과 부트스트랩 메서드, call site와 MethodHandler에 대해 설명을 해주고 있지만 제대로 이해하지 못하는 사람도 있을 수 있고 맨 뒤에 있어서 놓칠 수 있는 분들이 계실 수 있을 것 같아 정리해서 설명해주면 좋을 것 같습니다!

contents - 세부 내용

• invokedynamic이란?
• inner class는 컴파일 시 어떻게 정적 바인딩이되는 걸까요?
• 람다 표현식의 컴파일 시 처리와 어떻게 런타임 시 동적 바인딩이 되는 걸까요?

참고

책 p683
자세히 정리된 블로그
javamagazine
java docs

[devjy39]

람다는 컴파일 시 어떻게 처리되는 걸까요?

• 람다는 내부적으로 익명 클래스와 다른 메커니즘으로 처리된다.
• 익명클래스는 내부적으로 클래스로 표현이 되지만 람다는 아니다

실행 과정

1. invokedynamic 명령어에 의해서 람다가 실행됩니다.
2. invokedynamic를 통해 람다 표현식의 실행을 초기화하기 위해 부트스트랩 메서드가 호출됩니다.
3. 호출 사이트는 부트스트랩 메서드를 호출하고 람다 표현식에 대한 메서드 핸들(method handle)을 반환합니다.
4. execution (실행): 마지막으로, 람다 표현식의 실행이 발생합니다.

왜 이런 과정을 거쳐야할까?

• 람다라는 것은 어떤 함수가 들어갈 지 모르기 때문에 런타임에 동적으로 함수를 참조하기 위해서 이런 복잡한 프로세스를 거친다.

---

용어 알아보기

InvokeDynamic

• 런타임에 동적으로 호출할 메서드를 결정하기 위해 추가된 바이트코드
• 람다, 레코드 클래스, String concat 등에 활용된다.
• JVM 부트스트랩 메서드를 호출하고 반환되는 메서드핸들을 통해 동적으로 메서드를 호출한다. ( 바이트코드)

---

bootstrap method

• invokedynamic 명령 호출 단계에서 jvm이 호출하는 메서드
• methodHandle 객체의 생성과 초기화 담당
• 동적으로 CallSite 를 링킹하는데 사용되는 메서드 ( 메서드 호출을 유연하게 해준다)
• Java 컴파일러에 의해 생성되며 JVM에 의해 단 한번만 호출되고 CallSite객체를 생성해준다.

LambdaMetafactory.metafactory

• 모든 람다의 부트스트랩 메서드, Callsite 객체 생성 역할

---

MethodHandle

• 메서드를 동적으로 찾거나 호출하기 위한 JVM 메커니즘, ( 로우 레벨의 명령 )
• 어떤 메서드를 호출할지 정보를 들고 있는 클래스
• Target 으로 메서드를 갖고있음
• java컴파일러가 추가한 스태틱 메서드(method area에 위치하는 람다로 전달되는 메서드) 를 참조.

CallSite

• MethodHandle을 감싸고 있는 클래스, 홀더
• 명령이 호출되는 지점, jvm에 의해 관리됨

람다식이 성능이 더 좋은 이유

• 익명 클래스 방식은 결국 그 생성된 클래스에 대응하는 클래스 파일이 새로 생긴다는 의미이고 자바에서 모든 클래스들은 로딩되고 검증되는 일련의 작업들이 모두 포함되므로 성능에 악영향을 끼친다고 할 수 있다.
• 만약 수백개의 람다식이 코드에 존재한다면,, 일일이 그에 해당하는 클래스파일을 생성해야만 했다면?...

---

inner class는 컴파일 시 어떻게 정적 바인딩이되는 걸까요?

1. inner class의 메서드나 변수는 컴파일 시에 외부 클래스와 연관된 메서드와 변수에 대한 링크가 정적으로 결정됩니다. 이것은 컴파일 시에 내부 클래스가 어떤 외부 클래스의 인스턴스에 속하는지를 결정하며, 이것은 실행 시에 변경되지 않습니다.
2. 외부 클래스의 인스턴스에 종속성: 내부 클래스는 외부 클래스의 인스턴스에 종속적이므로 내부 클래스의 인스턴스를 생성하려면 외부 클래스의 인스턴스가 먼저 생성되어 있어야 합니다.

---

• 생성 순서
  • Lookup 생성 → methodtype → methodhandle → invoke

익명 클래스의 바이트코드 컴파일

public class AnonymousClassTest {
    public static void main(String[] args) {
        Runnable anonymousClassInstance = new Runnable() {
            @Override
            public void run() {
                System.out.println("hi");
            }
        };

        anonymousClassInstance.run();
    }

}

// class version 55.0 (55)
// access flags 0x20
class AnonymousClassTest$1 implements java/lang/Runnable {

  // compiled from: AnonymousClassTest.java
  NESTHOST AnonymousClassTest
  OUTERCLASS AnonymousClassTest main ([Ljava/lang/String;)V
  // access flags 0x0
  INNERCLASS AnonymousClassTest$1 null null

  // access flags 0x1
  public run()V
   L0
    LINENUMBER 6 L0
    GETSTATIC java/lang/System.out : Ljava/io/PrintStream;
    LDC "hi"
    INVOKEVIRTUAL java/io/PrintStream.println (Ljava/lang/String;)V
   L1
    LINENUMBER 7 L1
    RETURN
   L2
    LOCALVARIABLE this LAnonymousClassTest$1; L0 L2 0
    MAXSTACK = 2
    MAXLOCALS = 1
}

---

람다의 바이트코드 컴파일

/*
 *   람다 호출 시 invokedynamic 을 확인하고
 *   익명클래스와 람다가 내부적으로 다르게 처리됨을 확인한다.
 *
 *   람다는 내부적으로 해당 메서드를 캡처하여 lambda&...$... 포멧의 이름을 가진 프라이빗 메서드로 생성된다.
 *   해당 메서드가 methodhandle을 통해 invokedynamic 명령에 참조되며 런타임에 동적 바인딩된다.
 * */
public class LambdaTest {
    public static void main(String[] args) {
        Runnable instance = () -> {
            System.out.println("hi");
        };

        instance.run();
    }

}

// class version 55.0 (55)
// access flags 0x21
public class LambdaTest {

  // compiled from: LambdaTest.java
  // access flags 0x19
  public final static INNERCLASS java/lang/invoke/MethodHandles$Lookup java/lang/invoke/MethodHandles Lookup

  // access flags 0x9
  public static main([Ljava/lang/String;)V
   L0
    LINENUMBER 11 L0
    INVOKEDYNAMIC run()Ljava/lang/Runnable; [
      // handle kind 0x6 : INVOKESTATIC
      java/lang/invoke/LambdaMetafactory.metafactory(Ljava/lang/invoke/MethodHandles$Lookup;Ljava/lang/String;Ljava/lang/invoke/MethodType;Ljava/lang/invoke/MethodType;Ljava/lang/invoke/MethodHandle;Ljava/lang/invoke/MethodType;)Ljava/lang/invoke/CallSite;
      // arguments:
      ()V, 
      // handle kind 0x6 : INVOKESTATIC
      LambdaTest.lambda$main$0()V, 
      ()V
    ]
    ASTORE 1
   L1
    LINENUMBER 15 L1
    ALOAD 1
    INVOKEINTERFACE java/lang/Runnable.run ()V (itf)
   L2
    LINENUMBER 16 L2
    RETURN
   L3
    LOCALVARIABLE args [Ljava/lang/String; L0 L3 0
    LOCALVARIABLE instance Ljava/lang/Runnable; L1 L3 1
    MAXSTACK = 1
    MAXLOCALS = 2

  // access flags 0x100A
  private static synthetic lambda$main$0()V
   L0
    LINENUMBER 12 L0
    GETSTATIC java/lang/System.out : Ljava/io/PrintStream;
    LDC "hi"
    INVOKEVIRTUAL java/io/PrintStream.println (Ljava/lang/String;)V
   L1
    LINENUMBER 13 L1
    RETURN
    MAXSTACK = 2
    MAXLOCALS = 0
}