smallfolk_cpp/CMakeLists.txt at master · Rochet2/smallfolk_cpp · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
cmake_minimum_required(VERSION 3.16)
project(smallfolk_cpp VERSION 2.0.1 LANGUAGES CXX)

option(SMALLFOLK_BUILD_TESTS "Build the test runner" ON)
option(SMALLFOLK_BUILD_BENCHMARK "Build the benchmark runner" ON)
option(SMALLFOLK_BUILD_EXAMPLES "Build the interactive demo example" ON)
option(SMALLFOLK_ENABLE_CLANG_TIDY "Attach clang-tidy to library targets when available" OFF)

include(cmake/StaticAnalysis.cmake)

set(CMAKE_EXPORT_COMPILE_COMMANDS ON)

add_library(smallfolk smallfolk.cpp smallfolk_schema.cpp)
add_library(smallfolk_cpp::smallfolk ALIAS smallfolk)
smallfolk_enable_clang_tidy(smallfolk)
target_include_directories(smallfolk PUBLIC
    "$<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}>"
    "$<INSTALL_INTERFACE:include>"
)
target_compile_features(smallfolk PUBLIC cxx_std_11)

if(MSVC)
    target_compile_options(smallfolk PRIVATE /W4)
    target_compile_definitions(smallfolk PRIVATE
        _CRT_SECURE_CPP_OVERLOAD_STANDARD_NAMES
        _CRT_SECURE_NO_WARNINGS
    )
else()
    target_compile_options(smallfolk PRIVATE
        -Wall -Wextra -Werror -Wno-long-long -pedantic
    )
endif()

if(SMALLFOLK_BUILD_TESTS)
    enable_testing()
    add_executable(smallfolk_tests tests/test_smallfolk.cpp)
    target_link_libraries(smallfolk_tests PRIVATE smallfolk)
    add_test(NAME smallfolk_tests COMMAND smallfolk_tests)

    add_executable(smallfolk_schema_tests tests/test_schema.cpp)
    target_link_libraries(smallfolk_schema_tests PRIVATE smallfolk)
    add_test(NAME smallfolk_schema_tests COMMAND smallfolk_schema_tests)
    if(NOT MSVC)
        target_compile_options(smallfolk_tests PRIVATE
            -Wall -Wextra -Werror -Wno-long-long -pedantic
        )
        target_compile_options(smallfolk_schema_tests PRIVATE
            -Wall -Wextra -Werror -Wno-long-long -pedantic
        )
    endif()
endif()

if(SMALLFOLK_BUILD_EXAMPLES)
    if(NOT SMALLFOLK_BUILD_TESTS)
        enable_testing()
    endif()
    add_executable(smallfolk_demo examples/demo.cpp)
    target_link_libraries(smallfolk_demo PRIVATE smallfolk)
    add_test(NAME smallfolk_demo COMMAND smallfolk_demo)
    if(NOT MSVC)
        target_compile_options(smallfolk_demo PRIVATE
            -Wall -Wextra -Werror -Wno-long-long -pedantic
        )
    endif()
endif()

if(SMALLFOLK_BUILD_BENCHMARK)
    add_executable(smallfolk_benchmark benchmark/benchmark.cpp)
    target_link_libraries(smallfolk_benchmark PRIVATE smallfolk)
    if(NOT MSVC)
        target_compile_options(smallfolk_benchmark PRIVATE
            -Wall -Wextra -Werror -Wno-long-long -pedantic
        )
    endif()
endif()

include(GNUInstallDirs)
install(TARGETS smallfolk EXPORT smallfolk_cppTargets
    ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
    LIBRARY DESTINATION ${CMAKE_INSTALL_LIBDIR}
    RUNTIME DESTINATION ${CMAKE_INSTALL_BINDIR}
)
install(FILES smallfolk.h smallfolk_convert.h smallfolk_schema.h DESTINATION ${CMAKE_INSTALL_INCLUDEDIR})
install(EXPORT smallfolk_cppTargets
    FILE smallfolk_cppTargets.cmake
    NAMESPACE smallfolk_cpp::
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/smallfolk_cpp
)

include(CMakePackageConfigHelpers)
write_basic_package_version_file(
    "${CMAKE_CURRENT_BINARY_DIR}/smallfolk_cppConfigVersion.cmake"
    VERSION ${PROJECT_VERSION}
    COMPATIBILITY SameMajorVersion
)
configure_package_config_file(
    "${CMAKE_CURRENT_SOURCE_DIR}/cmake/smallfolk_cppConfig.cmake.in"
    "${CMAKE_CURRENT_BINARY_DIR}/smallfolk_cppConfig.cmake"
    INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/smallfolk_cpp
)
install(FILES
    "${CMAKE_CURRENT_BINARY_DIR}/smallfolk_cppConfig.cmake"
    "${CMAKE_CURRENT_BINARY_DIR}/smallfolk_cppConfigVersion.cmake"
    DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/smallfolk_cpp
)

smallfolk_add_static_analysis_targets()