creepersIArena.Java/build.gradle.kts at master · Our-Island/creepersIArena.Java · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
plugins {
    alias(libs.plugins.kotlin.jvm) apply false
    alias(libs.plugins.kotlin.plugin.lombok) apply false
    alias(libs.plugins.run.paper) apply false
}

val javaVersionInt = libs.versions.java.get().toInt()

allprojects {
    group = property("group") as String
    version = property("version") as String
    description = property("description") as String

    repositories {
        mavenCentral()
        maven {
            name = "papermc-repo"
            url = uri("https://repo.papermc.io/repository/maven-public/")
        }
    }
}

subprojects {
    plugins.withType<JavaPlugin> {
        extensions.configure<JavaPluginExtension> {
            val jv = JavaVersion.toVersion(javaVersionInt)
            sourceCompatibility = jv
            targetCompatibility = jv

            if (JavaVersion.current() < jv) {
                toolchain {
                    languageVersion.set(JavaLanguageVersion.of(javaVersionInt))
                }
            }
        }

        tasks.withType<JavaCompile>().configureEach {
            options.encoding = "UTF-8"
            options.release.set(javaVersionInt)
        }

        tasks.withType<Test>().configureEach {
            useJUnitPlatform()
            failOnNoDiscoveredTests = false
        }
    }
}