forked from Tribler/tribler
-
Notifications
You must be signed in to change notification settings - Fork 0
/
Copy pathpluginmakedist_IE_only.bat
103 lines (75 loc) · 4.22 KB
/
pluginmakedist_IE_only.bat
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
REM @echo off
set LIBRARYNAME=Tribler
set PYTHONHOME=\Python254
REM Arno: Add . to find our core (py 2.5)
set PYTHONPATH=.;%PYTHONHOME%
echo PYTHONPATH SET TO %PYTHONPATH%
set NSIS="\Program Files\NSIS\makensis.exe"
REM ----- Check for Python and essential site-packages
IF NOT EXIST %PYTHONHOME%\python.exe (
echo .
echo Could not locate Python in %PYTHONHOME%.
echo Please modify this script or install python [www.python.org]
exit /b
)
IF NOT EXIST %PYTHONHOME%\Lib\site-packages\wx-*-unicode (
echo .
echo Could not locate wxPython in %PYTHONHOME%\Lib\site-packages.
echo Please modify this script or install wxPython [www.wxpython.org]
exit /b
)
IF NOT EXIST %PYTHONHOME%\Lib\site-packages\py2exe (
echo .
echo Could not locate py2exe in %PYTHONHOME%\Lib\site-packages.
echo Please modify this script or install wxPython [www.py2exe.org]
exit /b
)
REM ----- Check for NSIS installer
IF NOT EXIST %NSIS% (
echo .
echo Could not locate the NSIS installer at %NSIS%.
echo Please modify this script or install NSIS [nsis.sf.net]
exit /b
)
REM ----- Clean up
call clean.bat
REM ----- Build
REM Arno: When adding files here, make sure tribler.nsi actually
REM packs them in the installer .EXE
REM Diego: building the deepest dir we get all of them.
mkdir dist\installdir\bgprocess\%LIBRARYNAME%\Images
%PYTHONHOME%\python.exe -O %LIBRARYNAME%\Plugin\Build\Win32\setupBGexe.py py2exe
REM Arno: Move py2exe results to installdir
move dist\*.* dist\installdir\bgprocess
copy %LIBRARYNAME%\Images\SwarmPluginIcon.ico dist\installdir\bgprocess\%LIBRARYNAME%\Images
xcopy vlc4plugin\* dist\installdir /E /I
REM Riccardo: move the files needed for the WebUI
xcopy %LIBRARYNAME%\WebUI dist\installdir\bgprocess\%LIBRARYNAME%\WebUI /S /I
del dist\installdir\bgprocess\%LIBRARYNAME%\WebUI\*.py
REM Diego: replace vlc *.txt with P2P-Next License.txt
del dist\installdir\*.txt
type %LIBRARYNAME%\ns-LICENSE.txt %LIBRARYNAME%\binary-LICENSE-postfix.txt > %LIBRARYNAME%\binary-LICENSE.txt
copy %LIBRARYNAME%\binary-LICENSE.txt dist\installdir
REM Diego: sign axvlc.dll
"C:\Program Files\Microsoft Platform SDK for Windows Server 2003 R2\Bin\signtool.exe" sign /f c:\build\certs\swarmplayerprivatekey.pfx /p "" /d "SwarmPlugin for Internet Explorer" /du "http://www.pds.ewi.tudelft.nl/code.html" /t "http://timestamp.verisign.com/scripts/timestamp.dll" "dist\installdir\activex\axvlc.dll"
copy %LIBRARYNAME%\Plugin\Build\Win32\heading.bmp dist\installdir
REM TODO Diego: manifest?
copy %LIBRARYNAME%\Plugin\Build\Win32\swarmplugin_IE_only.nsi dist\installdir
REM copy %LIBRARYNAME%\Plugin\Build\Win32\swarmplugin.exe.manifest dist\installdir
copy %PYTHONHOME%\Lib\site-packages\wx-2.8-msw-unicode\wx\msvcp71.dll dist\installdir\bgprocess
copy reset*.bat dist\installdir
cd dist\installdir
REM Arno: Win7 gives popup if SwarmEngine is not signed
"C:\Program Files\Microsoft Platform SDK for Windows Server 2003 R2\Bin\signtool.exe" sign /f c:\build\certs\swarmplayerprivatekey.pfx /p "" /d "SwarmPlugin for Internet Explorer and Firefox" /du "http://www.pds.ewi.tudelft.nl/code.html" /t "http://timestamp.verisign.com/scripts/timestamp.dll" bgprocess\SwarmEngine.exe
:makeinstaller
%NSIS% swarmplugin_IE_only.nsi
rename SwarmPlugin_*.exe SwarmPlugin_IE_*.exe
move SwarmPlugin_IE*.exe ..
cd ..
REM Diego : sign SwarmPlugin_*.exe
"C:\Program Files\Microsoft Platform SDK for Windows Server 2003 R2\Bin\signtool.exe" sign /f c:\build\certs\swarmplayerprivatekey.pfx /p "" /d "SwarmPlugin for Internet Explorer" /du "http://www.pds.ewi.tudelft.nl/code.html" /t "http://timestamp.verisign.com/scripts/timestamp.dll" "SwarmPlugin_IE*.exe"
REM Arno: build .cab file.
"C:\Program Files\Microsoft Platform SDK for Windows Server 2003 R2\Bin\CabArc.Exe" -s 6144 n SwarmPlugin_IE.cab ..\%LIBRARYNAME%\Plugin\Build\Win32\SwarmPlugin_IE.inf
REM Arno : sign SwarmPlugin*.cab
"C:\Program Files\Microsoft Platform SDK for Windows Server 2003 R2\Bin\signtool.exe" sign /f c:\build\certs\swarmplayerprivatekey.pfx /p "" /d "SwarmPlugin for Internet Explorer" /du "http://www.pds.ewi.tudelft.nl/code.html" /t "http://timestamp.verisign.com/scripts/timestamp.dll" "SwarmPlugin_IE*.cab"
cd ..