forked from Nek5000-deprecated/Nek5000-deprecated
-
Notifications
You must be signed in to change notification settings - Fork 2
/
Copy patheigsolv.f
465 lines (456 loc) · 13.3 KB
/
eigsolv.f
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
C**********************************************************************
C
C ROUTINES FOR ESITMATING AND CALCULATING EIGENVALUES
C USED IN NEKTON
C
C**********************************************************************
C
SUBROUTINE ESTEIG
C--------------------------------------------------------------
C
C Estimate eigenvalues
C
C-------------------------------------------------------------
INCLUDE 'SIZE'
INCLUDE 'GEOM'
INCLUDE 'INPUT'
INCLUDE 'EIGEN'
INCLUDE 'TSTEP'
C
NTOT1=NX1*NY1*NZ1*NELFLD(IFIELD)
XMIN = GLMIN(XM1,NTOT1)
XMAX = GLMAX(XM1,NTOT1)
YMIN = GLMIN(YM1,NTOT1)
YMAX = GLMAX(YM1,NTOT1)
IF (IF3D) THEN
ZMIN = GLMIN(ZM1,NTOT1)
ZMAX = GLMAX(ZM1,NTOT1)
ELSE
ZMIN = 0.0
ZMAX = 0.0
ENDIF
C
XX = XMAX - XMIN
YY = YMAX - YMIN
ZZ = ZMAX - ZMIN
RXY = XX/YY
RYX = YY/XX
RMIN = RXY
IF (RYX .LT. RMIN) RMIN = RYX
IF (NDIM .EQ. 3) THEN
RXZ = XX/ZZ
RZX = ZZ/XX
RYZ = YY/ZZ
RZY = ZZ/YY
IF (RXZ .LT. RMIN) RMIN = RXZ
IF (RZX .LT. RMIN) RMIN = RZX
IF (RYZ .LT. RMIN) RMIN = RYZ
IF (RZY .LT. RMIN) RMIN = RZY
ENDIF
C
XX2 = 1./XX**2
YY2 = 1./YY**2
XYZMIN = XX2
XYZMAX = XX2+YY2
IF (YY2 .LT. XYZMIN) XYZMIN = YY2
IF (NDIM .EQ. 3) THEN
ZZ2 = 1./ZZ**2
XYZMAX = XYZMAX+ZZ2
IF (ZZ2 .LT. XYZMIN) XYZMIN = ZZ2
ENDIF
C
one = 1.
PI = 4.*ATAN(one)
RATIO = XYZMIN/XYZMAX
EIGAE = PI*PI*XYZMIN
EIGGE = EIGGA
IF (NDIM .EQ. 2) EIGAA = PI*PI*(XX2+YY2)/2.
IF (NDIM .EQ. 3) EIGAA = PI*PI*(XX2+YY2+ZZ2)/3.
IF (IFAXIS) EIGAA = .25*PI*PI*YY2
EIGAS = 0.25*RATIO
EIGGS = 2.0
C
IF (NIO.EQ.0 .AND. ISTEP.LE.0) THEN
WRITE (6,*) ' '
WRITE (6,*) 'Estimated eigenvalues'
WRITE (6,*) 'EIGAA = ',EIGAA
WRITE (6,*) 'EIGGA = ',EIGGA
IF (IFFLOW) THEN
WRITE (6,*) 'EIGAE = ',EIGAE
WRITE (6,*) 'EIGAS = ',EIGAS
WRITE (6,*) 'EIGGE = ',EIGGE
WRITE (6,*) 'EIGGS = ',EIGGS
ENDIF
WRITE (6,*) ' '
ENDIF
C
RETURN
END
C
SUBROUTINE EIGENV
C-------------------------------------------------------------------------
C
C Compute the following eigenvalues:
C EIGAA = minimum eigenvalue of the matrix A (=Laplacian)
C EIGAE = minimum eigenvalue of the matrix E (=DB-1DT)
C EIGAS = minimum eigenvalue of the matrix S (=DA-1DT)
C EIGAST = minimum eigenvalue of the matrix St (=D(A+B/dt)-1DT
C EIGGA = maximum eigenvalue of the matrix A
C EIGGS = maximum eigenvalue of the matrix S
C EIGGE = maximum eigenvalue of the matrix E
C EIGGST = maximum eigenvalue of the matrix St
C
C Method : Power method/Inverse iteration & Rayleigh quotient wo shift
C
C-------------------------------------------------------------------------
INCLUDE 'SIZE'
INCLUDE 'EIGEN'
INCLUDE 'INPUT'
INCLUDE 'SOLN'
INCLUDE 'TSTEP'
C
COMMON /SCRVH/ H1 (LX1,LY1,LZ1,LELT)
$ , H2 (LX1,LY1,LZ1,LELT)
COMMON /SCRHI/ H2INV (LX1,LY1,LZ1,LELV)
C
NTOT1 = NX1*NY1*NZ1*NELV
C
IF (IFAA) THEN
NTOT1 = NX1*NY1*NZ1*NELV
CALL RONE (H1,NTOT1)
CALL RZERO (H2,NTOT1)
CALL ALPHAM1 (EIGAA1,V1MASK,VMULT,H1,H2,1)
CALL ALPHAM1 (EIGAA2,V2MASK,VMULT,H1,H2,2)
EIGAA = MIN (EIGAA1,EIGAA2)
IF (NDIM.EQ.3) THEN
CALL ALPHAM1 (EIGAA3,V3MASK,VMULT,H1,H2,3)
EIGAA = MIN (EIGAA,EIGAA3)
ENDIF
IF (NIO.EQ.0 .AND. ISTEP.LE.0) WRITE (6,*) 'EIGAA = ',EIGAA
ENDIF
C
IF (IFAS) THEN
INLOC = 0
CALL RONE (H1,NTOT1)
CALL RZERO (H2,NTOT1)
CALL RZERO (H2INV,NTOT1)
CALL ALPHAM2 (EIGAS,H1,H2,H2INV,INLOC)
IF (NIO.EQ.0 .AND. ISTEP.LE.0) WRITE (6,*) 'EIGAS = ',EIGAS
ENDIF
C
IF (IFAE) THEN
INLOC = 1
CALL RZERO (H1,NTOT1)
CALL RONE (H2,NTOT1)
CALL RONE (H2INV,NTOT1)
CALL ALPHAM2 (EIGAE,H1,H2,H2INV,INLOC)
IF (NIO.EQ.0 .AND. ISTEP.LE.0) WRITE (6,*) 'EIGAE = ',EIGAE
ENDIF
C
IF (IFAST) THEN
INLOC = -1
CALL SETHLM (H1,H2,INLOC)
CALL INVERS2 (H2INV,H2,NTOT1)
CALL ALPHAM2 (EIGAST,H1,H2,H2INV,INLOC)
IF (NIO.EQ.0 .AND. ISTEP.LE.0) WRITE (6,*) 'EIGAST = ',EIGAST
ENDIF
C
IF (IFGS) THEN
INLOC = 0
CALL RONE (H1,NTOT1)
CALL RZERO (H2,NTOT1)
CALL RZERO (H2INV,NTOT1)
CALL GAMMAM2 (EIGGS,H1,H2,H2INV,INLOC)
IF (NIO.EQ.0 .AND. ISTEP.LE.0) WRITE (6,*) 'EIGGS = ',EIGGS
ENDIF
C
IF (IFGE) THEN
INLOC = 1
CALL RZERO (H1,NTOT1)
CALL RONE (H2,NTOT1)
CALL RONE (H2INV,NTOT1)
CALL GAMMAM2 (EIGGE,H1,H2,H2INV,INLOC)
IF (NIO.EQ.0 .AND. ISTEP.LE.0) WRITE (6,*) 'EIGGE = ',EIGGE
ENDIF
C
IF (IFGST) THEN
INLOC = -1
CALL SETHLM (H1,H2,INLOC)
CALL INVERS2 (H2INV,H2,NTOT1)
CALL GAMMAM2 (EIGGST,H1,H2,H2INV,INLOC)
IF (NIO.EQ.0 .AND. ISTEP.LE.0) WRITE (6,*) 'EIGGST = ',EIGGST
ENDIF
C
IF (IFGA) THEN
NTOT1 = NX1*NY1*NZ1*NELV
CALL RONE (H1,NTOT1)
CALL RZERO (H2,NTOT1)
IF (.NOT.IFSTRS) THEN
CALL GAMMAM1 (EIGGA1,V1MASK,VMULT,H1,H2,1)
CALL GAMMAM1 (EIGGA2,V2MASK,VMULT,H1,H2,2)
EIGGA3 = 0.
IF (NDIM.EQ.3)
$ CALL GAMMAM1 (EIGGA3,V3MASK,VMULT,H1,H2,3)
EIGGA = MAX (EIGGA1,EIGGA2,EIGGA3)
ELSE
CALL GAMMASF (H1,H2)
ENDIF
ENDIF
C
RETURN
END
C
SUBROUTINE ALPHAM1 (ALPHA,MASK,MULT,H1,H2,ISD)
C---------------------------------------------------------------------------
C
C Compute minimum eigenvalue, ALPHA, of the discrete Helmholtz operator
C
C---------------------------------------------------------------------------
INCLUDE 'SIZE'
INCLUDE 'MASS'
INCLUDE 'TSTEP'
C
REAL MASK (LX1,LY1,LZ1,1)
REAL MULT (LX1,LY1,LZ1,1)
REAL H1 (LX1,LY1,LZ1,1)
REAL H2 (LX1,LY1,LZ1,1)
COMMON /SCREV/ X1 (LX1,LY1,LZ1,LELT)
$ , Y1 (LX1,LY1,LZ1,LELT)
CHARACTER NAME*4
C
IF (IMESH.EQ.1) NEL = NELV
IF (IMESH.EQ.2) NEL = NELT
IF (ISD .EQ.1) NAME = 'EVVX'
IF (ISD .EQ.2) NAME = 'EVVX'
IF (ISD .EQ.3) NAME = 'EVVX'
C
NXYZ1 = NX1*NY1*NZ1
NTOT1 = NXYZ1*NEL
EVNEW = 0.
CALL STARTX1 (X1,Y1,MASK,MULT,NEL)
C
DO 1000 ITER=1,NMXE
CALL AXHELM (Y1,X1,H1,H2,IMESH,ISD)
CALL COL2 (Y1,MASK,NTOT1)
CALL DSSUM (Y1,NX1,NY1,NZ1)
RQ = GLSC3 (X1,Y1,MULT,NTOT1)
EVOLD = EVNEW
EVNEW = RQ
write (6,*) 'alphaa = ',rq
CRIT = ABS((EVNEW-EVOLD)/EVNEW)
IF (CRIT.LT.TOLEV) GOTO 2000
CALL COL2 (X1,BM1,NTOT1)
CALL HMHOLTZ ('NOMG',Y1,X1,H1,H2,MASK,MULT,
$ IMESH,TOLHE,NMXH,ISD)
CALL COL3 (X1,BM1,Y1,NTOT1)
CALL DSSUM (X1,NX1,NY1,NZ1)
YY = GLSC3 (X1,Y1,MULT,NTOT1)
YNORM = 1./SQRT(YY)
CALL CMULT (Y1,YNORM,NTOT1)
CALL COPY (X1,Y1,NTOT1)
1000 CONTINUE
2000 CONTINUE
C
ALPHA = RQ
RETURN
END
C
SUBROUTINE GAMMAM1 (GAMMA,MASK,MULT,H1,H2,ISD)
C---------------------------------------------------------------------------
C
C Compute maximum eigenvalue of the discrete Helmholtz operator
C
C---------------------------------------------------------------------------
INCLUDE 'SIZE'
INCLUDE 'MASS'
INCLUDE 'TSTEP'
C
REAL MASK (LX1,LY1,LZ1,1)
REAL MULT (LX1,LY1,LZ1,1)
REAL H1 (LX1,LY1,LZ1,1)
REAL H2 (LX1,LY1,LZ1,1)
COMMON /SCREV/ X1 (LX1,LY1,LZ1,LELT)
$ , Y1 (LX1,LY1,LZ1,LELT)
C
IF (IMESH.EQ.1) NEL = NELV
IF (IMESH.EQ.2) NEL = NELT
NXYZ1 = NX1*NY1*NZ1
NTOT1 = NXYZ1*NEL
EVNEW = 0.
c pff (2/15/96)
if (isd.eq.1) CALL STARTX1 (X1,Y1,MASK,MULT,NEL)
C
DO 1000 ITER=1,NMXE
CALL AXHELM (Y1,X1,H1,H2,IMESH,ISD)
CALL COL2 (Y1,MASK,NTOT1)
CALL DSSUM (Y1,NX1,NY1,NZ1)
RQ = GLSC3 (X1,Y1,MULT,NTOT1)
EVOLD = EVNEW
EVNEW = RQ
CRIT = ABS((EVNEW-EVOLD)/EVNEW)
C
C HMT removed
C
C if (nio.eq.0) then
C write(6,*) iter,' eig_max A:',evnew,crit,tolev
C endif
IF (CRIT.LT.TOLEV) GOTO 2000
CALL COL3 (X1,BINVM1,Y1,NTOT1)
XX = GLSC3 (X1,Y1,MULT,NTOT1)
XNORM = 1./SQRT(XX)
CALL CMULT (X1,XNORM,NTOT1)
1000 CONTINUE
2000 CONTINUE
C
GAMMA = RQ
RETURN
END
C
SUBROUTINE ALPHAM2 (ALPHA,H1,H2,H2INV,INLOC)
C----------------------------------------------------------------------
C
C Compute minimum eigenvalue, ALPHA, of one of the matrices
C defined on the pressure mesh:
C INLOC = 0 : DA-1DT
C INLOC = 1 : DB-1DT
C INLOC = -1 : D(A+B/DT)-1DT
C
C----------------------------------------------------------------------
INCLUDE 'SIZE'
INCLUDE 'MASS'
INCLUDE 'TSTEP'
C
REAL H1 (LX1,LY1,LZ1,1)
REAL H2 (LX1,LY1,LZ1,1)
REAL H2INV(LX1,LY1,LZ1,1)
COMMON /SCREV/ X2 (LX2,LY2,LZ2,LELV)
$ , Y2 (LX2,LY2,LZ2,LELV)
C
NTOT2 = NX2*NY2*NZ2*NELV
EVNEW = 0.
CALL STARTX2 (X2,Y2)
C
DO 1000 ITER=1,NMXE
CALL CDABDTP (Y2,X2,H1,H2,H2INV,INLOC)
RQ = GLSC2 (X2,Y2,NTOT2)
EVOLD = EVNEW
EVNEW = RQ
c write (6,*) 'new eigenvalue ************* eigas = ',evnew
CRIT = ABS((EVNEW-EVOLD)/EVNEW)
IF (CRIT.LT.TOLEV) GOTO 2000
CALL COL2 (X2,BM2,NTOT2)
CALL UZAWA (X2,H1,H2,H2INV,INLOC,ICG)
CALL COL3 (Y2,BM2,X2,NTOT2)
XX = GLSC2 (X2,Y2,NTOT2)
XNORM = 1./SQRT(XX)
CALL CMULT (X2,XNORM,NTOT2)
1000 CONTINUE
2000 CONTINUE
C
ALPHA = RQ
RETURN
END
C
SUBROUTINE GAMMAM2 (GAMMA,H1,H2,H2INV,INLOC)
C-------------------------------------------------------------------
C
C Compute maximum eigenvalue, GAMMA, of one of the matrices
C defined on the pressure mesh:
C INLOC = 0 : DA-1DT
C INLOC = 1 : DB-1DT
C INLOC = -1 : D(A+B/DT)-1DT
C
C-------------------------------------------------------------------
INCLUDE 'SIZE'
INCLUDE 'MASS'
INCLUDE 'TSTEP'
C
REAL H1 (LX1,LY1,LZ1,1)
REAL H2 (LX1,LY1,LZ1,1)
REAL H2INV (LX1,LY1,LZ1,1)
COMMON /SCREV/ X2 (LX2,LY2,LZ2,LELV)
$ , Y2 (LX2,LY2,LZ2,LELV)
C
NTOT2 = NX2*NY2*NZ2*NELV
EVNEW = 0.
CALL STARTX2 (X2,Y2)
C
DO 1000 ITER=1,NMXE
CALL CDABDTP (Y2,X2,H1,H2,H2INV,INLOC)
RQ = GLSC2 (X2,Y2,NTOT2)
EVOLD = EVNEW
EVNEW = RQ
CRIT = ABS((EVNEW-EVOLD)/EVNEW)
IF (CRIT.LT.TOLEV) GOTO 2000
CALL INVCOL3 (X2,Y2,BM2,NTOT2)
XX = GLSC2 (Y2,X2,NTOT2)
XNORM = 1./SQRT(XX)
CALL CMULT (X2,XNORM,NTOT2)
1000 CONTINUE
2000 CONTINUE
C
GAMMA = RQ
RETURN
END
C
c-----------------------------------------------------------------------
SUBROUTINE STARTX1 (X1,Y1,MASK,MULT,NEL)
c Compute startvector for finding an eigenvalue on mesh 1.
c Normalization: XT*B*X = 1
INCLUDE 'SIZE'
INCLUDE 'MASS'
REAL X1 (LX1,LY1,LZ1,1)
REAL Y1 (LX1,LY1,LZ1,1)
REAL MASK (LX1,LY1,LZ1,1)
REAL MULT (LX1,LY1,LZ1,1)
NTOT1 = NX1*NY1*NZ1*NEL
CALL COPY (X1,BM1,NTOT1)
call rand_fld_h1(y1) ! pff 3/21/12
small = 0.001*glamax(x1,ntot1)
call add2s2(x1,y1,small,ntot1)
CALL COL2 (X1,MASK,NTOT1)
CALL COL3 (Y1,BM1,X1,NTOT1)
CALL DSSUM (Y1,NX1,NY1,NZ1)
XX = GLSC3 (X1,Y1,MULT,NTOT1)
XNORM = 1./SQRT(XX)
CALL CMULT (X1,XNORM,NTOT1)
RETURN
END
c-----------------------------------------------------------------------
SUBROUTINE STARTX2 (X2,Y2)
C------------------------------------------------------------------
C
C Compute startvector for finding an eigenvalue on mesh 2.
C
C------------------------------------------------------------------
INCLUDE 'SIZE'
INCLUDE 'MASS'
C
REAL X2 (LX2,LY2,LZ2,LELV)
REAL Y2 (LX2,LY2,LZ2,LELV)
C
NXYZ2 = NX2*NY2*NZ2
NTOT2 = NXYZ2*NELV
ICONST = 0
IF ((NDIM .EQ. 2).AND.(NXYZ2 .EQ. 4)) ICONST = 1
IF ((NDIM .EQ. 3).AND.(NXYZ2 .EQ. 8)) ICONST = 1
C
IF (ICONST .EQ. 1) THEN
DO 1000 IEL=1,NELV
DO 1000 K=1,NZ2
DO 1000 J=1,NY2
DO 1000 I=1,NX2
X2(I,J,K,IEL) = I*J*K
1000 CONTINUE
ELSE
CALL COPY (X2,BM2,NTOT2)
ENDIF
C
call ortho (x2)
CALL COL3 (Y2,BM2,X2,NTOT2)
XX = GLSC2 (X2,Y2,NTOT2)
XNORM = 1./SQRT(XX)
CALL CMULT (X2,XNORM,NTOT2)
C
RETURN
END