Check release builds component for component, instead of all together

Author: jorisdral

.github/workflows/check-release-builds.yml

@@ -41,11 +41,16 @@ jobs:
         os: ["ubuntu-latest", "macOS-latest", "windows-latest"]
         ghc-version: ["9.2", "9.4", "9.6", "9.8", "9.10", "9.12"]
         cabal-version: ["3.12"]
+        exclude:
+        # this configuration leads to a linker error when building/running the
+        # cabal-list-public-library-targets script.
+        - os: "windows-latest"
+          ghc-version: "9.2"
+          cabal-version: "3.12"
 
     env:
       tag-name: ${{ github.ref_name }}
-      release-build-target: |
-        ${{ startsWith(github.ref_name, 'blockio') && './blockio/blockio.cabal' || startsWith(github.ref_name, 'bloomfilter-blocked') && './bloomfilter-blocked/bloomfilter-blocked.cabal' || startsWith(github.ref_name, 'lsm-tree') && './lsm-tree/lsm-tree.cabal' }}
+      release-build-target: ${{ startsWith(github.ref_name, 'blockio') && './blockio/blockio.cabal' || startsWith(github.ref_name, 'bloomfilter-blocked') && './bloomfilter-blocked/bloomfilter-blocked.cabal' || startsWith(github.ref_name, 'lsm-tree') && './lsm-tree/lsm-tree.cabal' }}
 
     steps:
     - name: 🗄️ Print release build target
@@ -101,8 +106,10 @@ jobs:
         key: check-release-build-${{ runner.os }}-ghc-${{ steps.setup-haskell.outputs.ghc-version }}-cabal-${{ steps.setup-haskell.outputs.cabal-version }}
       with:
         path: ${{ steps.setup-haskell.outputs.cabal-store }}
-        key: ${{ env.key }}-plan-${{ hashFiles('dist-newstyle/cache/plan.json') }}
-        restore-keys: ${{ env.key }}-
+        key: ${{ env.key }}-tag-${{ env.tag-name }}-plan-${{ hashFiles('dist-newstyle/cache/plan.json') }}
+        restore-keys: |
+          ${{ env.key }}-tag-${{ env.tag-name }}-
+          ${{ env.key }}-
 
     - name: 🛠️ Build Cabal dependencies
       run: |
@@ -118,6 +125,9 @@ jobs:
         key: ${{ steps.cache-cabal.outputs.cache-primary-key }}
 
     - name: 🏗️ Build
+      shell: sh
       run: |
-        cabal build all \
-          --project-file="cabal.project.temp"
+        ./scripts/cabal-list-public-library-targets.hs '${{ env.release-build-target }}' | \
+          tail -n +2 | \
+          tr -d '\r' | \
+          xargs -L 1 sh -c 'echo "$0" && cabal build --project-file=cabal.project.temp "$0"'

scripts/cabal-list-public-library-targets.hs

@@ -0,0 +1,73 @@
+#!/usr/bin/env cabal
+{- cabal:
+build-depends:
+    , base          >=4.16
+    , bytestring    >=0.11
+    , Cabal-syntax ^>=3.10  || ^>=3.12
+
+ghc-options:
+  -Wall -Wcompat -Wincomplete-uni-patterns
+  -Wincomplete-record-updates -Wpartial-fields -Widentities
+  -Wredundant-constraints -Wmissing-export-lists
+  -Wno-unticked-promoted-constructors -Wunused-packages
+
+ghc-options: -Werror=missing-deriving-strategies
+
+ghc-options: -Werror
+
+ghc-options: -Wmissing-import-lists
+-}
+{-# LANGUAGE LambdaCase #-}
+
+module Main (main) where
+
+import           Control.Monad (forM_)
+import qualified Data.ByteString as BS
+import           Data.Maybe (mapMaybe)
+import           Distribution.PackageDescription.Parsec
+                     (parseGenericPackageDescriptionMaybe)
+import           Distribution.Types.CondTree (ignoreConditions)
+import qualified Distribution.Types.GenericPackageDescription as GenericPackageDescription
+import           Distribution.Types.Library (libVisibility)
+import           Distribution.Types.LibraryVisibility
+                     (LibraryVisibility (LibraryVisibilityPrivate, LibraryVisibilityPublic))
+import           Distribution.Types.PackageDescription (package)
+import           Distribution.Types.PackageId (pkgName)
+import           Distribution.Types.PackageName (unPackageName)
+import           Distribution.Types.UnqualComponentName (unUnqualComponentName)
+import           System.Environment (getArgs)
+import           System.IO (hPutStrLn, stderr)
+
+-- | Given a cabal file, list all public libraries in that cabal file (including
+-- the main library) and print them as valid cabal targets.
+--
+-- For example:
+--
+-- @
+-- ❯ ./scripts/cabal-list-public-library-targets.hs ./blockio/blockio.cabal
+-- Finding sub-libraries with public visibility in './blockio/blockio.cabal' ...
+-- blockio:blockio
+-- blockio:sim
+-- @
+main :: IO ()
+main = do
+    cabalFiles <- getArgs
+    forM_ cabalFiles $ \cabalFile -> do
+      putStrLn ("Finding sub-libraries with public visibility in '" ++ cabalFile ++ "' ...")
+      cabalContent <- BS.readFile cabalFile
+      case parseGenericPackageDescriptionMaybe cabalContent of
+          Nothing -> hPutStrLn stderr $ "error: Could not parse '" <> cabalFile <> "'"
+          Just genericPackageDescription -> do
+              let packageDescription = GenericPackageDescription.packageDescription genericPackageDescription
+                  packageName = unPackageName $ pkgName $ package packageDescription
+                  subLibraries = GenericPackageDescription.condSubLibraries genericPackageDescription
+                  publicSubLibraries = mapMaybe isPublic subLibraries
+                  mkCabalTarget s = packageName ++ ":" ++ s
+              forM_ (packageName : publicSubLibraries) $ \n ->
+                putStrLn $ mkCabalTarget n
+  where
+    isPublic (componentName, condTree) =
+      let vis = libVisibility (fst $ ignoreConditions condTree) in
+      case vis of
+        LibraryVisibilityPublic  -> Just (unUnqualComponentName componentName)
+        LibraryVisibilityPrivate -> Nothing