aio/CMakeLists.txt at master · Hackerl/aio · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
cmake_minimum_required(VERSION 3.17)
project(aio)

set(CMAKE_CXX_STANDARD 17)

option(AIO_DISABLE_SSL "disable ssl support" OFF)
option(AIO_DISABLE_TESTS "disable aio unit test" OFF)
option(AIO_DISABLE_SAMPLES "disable aio samples" OFF)
option(AIO_EMBED_CA_CERT "use embedded CA certificates" OFF)

set(CMAKE_POSITION_INDEPENDENT_CODE TRUE)

set(CMAKE_RUNTIME_OUTPUT_DIRECTORY ${CMAKE_SOURCE_DIR}/bin)
set(CMAKE_ARCHIVE_OUTPUT_DIRECTORY ${CMAKE_SOURCE_DIR}/lib)

set(AIO_VERSION 1.0.5)

include(GNUInstallDirs)
include(CMakePackageConfigHelpers)

find_package(zero CONFIG REQUIRED)
find_package(CURL CONFIG REQUIRED)
find_package(Libevent CONFIG REQUIRED)
find_package(nlohmann_json CONFIG REQUIRED)

add_library(
        aio
        STATIC
        src/io.cpp
        src/error.cpp
        src/worker.cpp
        src/context.cpp
        src/ev/buffer.cpp
        src/ev/pipe.cpp
        src/ev/event.cpp
        src/ev/timer.cpp
        src/ev/signal.cpp
        src/net/dns.cpp
        src/net/net.cpp
        src/net/stream.cpp
        src/net/dgram.cpp
        src/http/url.cpp
        src/http/request.cpp
        $<$<NOT:$<BOOL:${AIO_DISABLE_SSL}>>:src/net/ssl.cpp>
        $<$<NOT:$<BOOL:${AIO_DISABLE_SSL}>>:src/http/websocket.cpp>
)

if (AIO_EMBED_CA_CERT)
    set(CA_CERT_FILE ${CMAKE_CURRENT_BINARY_DIR}/cacert.pem)
    set(CA_CERT_HEADER ${CMAKE_CURRENT_SOURCE_DIR}/include/cacert.h)

    if (NOT EXISTS ${CA_CERT_FILE})
        file(DOWNLOAD https://curl.se/ca/cacert.pem ${CA_CERT_FILE})
    endif ()

    if (NOT EXISTS ${CA_CERT_HEADER})
        file(READ ${CA_CERT_FILE} content HEX)
        string(REGEX REPLACE "([0-9a-f][0-9a-f])" "0x\\1," content ${content})
        file(WRITE ${CA_CERT_HEADER} "constexpr unsigned char CA_CERT[] = {${content}};")
    endif ()

    set(EXCLUDE_HEADERS ${EXCLUDE_HEADERS} PATTERN "cacert.h" EXCLUDE)
    target_compile_definitions(aio PUBLIC AIO_EMBED_CA_CERT)
endif ()

target_include_directories(
        aio
        PUBLIC
        $<INSTALL_INTERFACE:${CMAKE_INSTALL_INCLUDEDIR}>
        $<BUILD_INTERFACE:${CMAKE_CURRENT_SOURCE_DIR}/include>
)

target_link_libraries(
        aio
        PUBLIC
        zero::zero
        CURL::libcurl
        libevent::core
        libevent::extra
        nlohmann_json::nlohmann_json
        $<$<PLATFORM_ID:Linux,Android>:libevent::pthreads>
        $<$<NOT:$<BOOL:${AIO_DISABLE_SSL}>>:libevent::openssl>
)

if (AIO_DISABLE_SSL)
    set(
            EXCLUDE_HEADERS
            ${EXCLUDE_HEADERS}
            PATTERN "net/ssl.h" EXCLUDE
            PATTERN "http/websocket.h" EXCLUDE
    )
endif ()

install(
        DIRECTORY
        include/
        DESTINATION ${CMAKE_INSTALL_INCLUDEDIR}
        ${EXCLUDE_HEADERS}
)

install(
        TARGETS aio
        EXPORT ${PROJECT_NAME}Targets
        ARCHIVE DESTINATION ${CMAKE_INSTALL_LIBDIR}
)

install(
        EXPORT ${PROJECT_NAME}Targets
        NAMESPACE aio::
        DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}
)

configure_package_config_file(
        cmake/${PROJECT_NAME}-config.cmake.in
        ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake
        INSTALL_DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}
)

write_basic_package_version_file(
        ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake
        VERSION ${AIO_VERSION}
        COMPATIBILITY SameMajorVersion
)

install(
        FILES
        ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}Config.cmake
        ${CMAKE_CURRENT_BINARY_DIR}/${PROJECT_NAME}ConfigVersion.cmake
        DESTINATION ${CMAKE_INSTALL_LIBDIR}/cmake/${PROJECT_NAME}
)

if (NOT AIO_DISABLE_SAMPLES)
    add_subdirectory(sample)
endif ()

if (NOT AIO_DISABLE_TESTS)
    add_subdirectory(test)
endif ()