addon.gradle

javadoc {
    javadocTool = javaToolchains.javadocToolFor {
        //java 11 crashes with Jabel modern syntax
        languageVersion = JavaLanguageVersion.of(23)
        vendor = JvmVendorSpec.ADOPTIUM
    }

    include "com/gtnewhorizons/wdmla/**"
    exclude "com/gtnewhorizons/wdmla/plugin/**"
    exclude "com/gtnewhorizons/wdmla/test/**"
    include "mcp/mobius/waila/**"
    exclude "mcp/mobius/waila/addons/**"
    exclude "mcp/mobius/waila/test/**"

    classpath += sourceSets.patchedMc.output

    options {
        addStringOption("Xdoclint:none", "-quiet")
        links 'https://docs.oracle.com/en/java/javase/24/docs/api/'
        links 'https://skmedix.github.io/ForgeJavaDocs/javadoc/forge/1.7.10-10.13.4.1614/'
    }

    destinationDir = file("${projectDir}/src/doc")
}

tasks.register('javadocJar', Jar) {
    dependsOn javadoc
    archiveClassifier = 'javadoc'
    from javadoc.destinationDir
}

artifacts {
    archives javadocJar
}

test {
    useJUnitPlatform()
    testLogging {
        events "passed", "skipped", "failed"
    }
}