JustEnoughDebugTools/build.gradle at master · FoxSamu/JustEnoughDebugTools · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
import java.util.stream.Collectors

plugins {
    id 'fabric-loom' version '0.9-SNAPSHOT'
    id 'maven-publish'
}

sourceCompatibility = JavaVersion.VERSION_16
targetCompatibility = JavaVersion.VERSION_16

archivesBaseName = project.archives_base_name
version = project.mod_version
group = project.maven_group

dependencies {
    minecraft "com.mojang:minecraft:${project.minecraft_version}"
    mappings loom.officialMojangMappings()
    modImplementation "net.fabricmc:fabric-loader:${project.loader_version}"
    modImplementation "net.fabricmc.fabric-api:fabric-api:${project.fabric_version}"

    testImplementation "net.fabricmc:dev-launch-injector:0.2.1+build.8"
}

tasks.withType(ProcessResources) {
    inputs.property "version", project.version

    filesMatching("fabric.mod.json") {
        expand "version": project.version
    }
}

tasks.withType(JavaCompile) {
    options.encoding = "UTF-8"
}

task sourcesJar(type: Jar, dependsOn: classes, group: "build") {
    archiveClassifier.set("sources")
    from sourceSets.main.allSource
}

jar {
    from "LICENSE"
}

if (project.hasProperty("shwMavenUser") && project.hasProperty("shwMavenPass")) {
    publishing {
        publications {
            mavenJava(MavenPublication) {
                artifact(remapJar) {
                    builtBy remapJar
                    artifactId "jedt"
                }
                artifact(sourcesJar) {
                    builtBy remapSourcesJar
                    artifactId "jedt"
                }
            }
        }

        repositories {
            maven {
                name = "ShwMaven"
                url = uri( "https://maven.shadew.net/" )
                credentials {
                    username = shwMavenUser
                    password = shwMavenPass
                }
            }
        }
    }
}

def getTestClassPath() {
    def cp = []
    sourceSets.test.runtimeClasspath.each {
        cp.add(it.toString())
    }
    return cp.stream().collect(Collectors.joining(";"))
}

sourceSets {
    gametest {
        compileClasspath += main.compileClasspath
        runtimeClasspath += main.runtimeClasspath
    }
    main {
    }
}

dependencies {
    gametestImplementation sourceSets.main.output
}

loom {
    runs {
        client {
            name "Minecraft Client"
            source sourceSets.gametest

            vmArg "-Djedt.test_structures_path=${file("gametest/gameteststructures")}"
        }
        server {
            name "Minecraft Server"
            source sourceSets.gametest

            vmArg "-Djedt.test_structures_path=${file("gametest/gameteststructures")}"
        }
        gametest {
            server()
            name "Minecraft GameTest"
            source sourceSets.gametest

            vmArg "-Djedt.gametest=true"
            vmArg "-Djedt.test_config=${file("gametest/gametest.json")}"
            vmArg "-Djedt.test_structures_dir=${file("gametest/gameteststructures")}"

            serverWithGui() // GameTestServer has no nogui property, this removes it
        }
    }
}