GC9A01 Display not working with WiFI

[sam632]

HI,
I am using this library with a GC9A01 display. I am using the following pin configuration with an ESP32 WROOM model,

#define TFT_MOSI 15 // In some display driver board, it might be written as "SDA" and so on.
#define TFT_SCLK 14
#define TFT_CS   5  // Chip select control pin
#define TFT_DC   27  // Data Command control pin
#define TFT_RST  33  // Reset pin (could connect to Arduino RESET pin)
// #define TFT_BL   22  // LED back-light

When i have initWiFi(); commented out, this works fine. However when I try to connect to WiFi (which works in a different script), the display stops working. I can set the background colour etc in the setup function but the loop does not seem to work or update the display. Heres the script,

#include <SPI.h>
#include <TFT_eSPI.h> 
#include <WiFi.h>
#include "custom_fonts.h"

#define IWIDTH  240
#define IHEIGHT 240
#define BACKGROUND TFT_BLACK
#define CLOCK_BG TFT_BLUE
#define TEXT_COLOUR TFT_WHITE

TFT_eSPI tft = TFT_eSPI();
TFT_eSprite img = TFT_eSprite(&tft);

const char* ssid     = "*****";
const char* password = "***********";

float temperature;
float humidity;

void initWiFi() {
  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
  }
}

void updateData(float temperature, float humidity, String curr_time) {
  char temp[7], hum[4];

  img.fillSprite(BACKGROUND);

  // Temp and Humidity
  img.setTextSize(1);
  img.setFreeFont(&Roboto_Black_50);
  
  img.setTextColor(TEXT_COLOUR, BACKGROUND);
  snprintf(temp, 7, "%.1f", temperature);
  img.drawString(temp, 35, 70);
  img.setTextSize(2);
  img.drawString("`", 150, 70, 4);
  img.setTextSize(1);
  img.drawString("C", 170, 70);
  
  img.setTextColor(TEXT_COLOUR, BACKGROUND);
  snprintf(hum, 4, "%.0f%s", humidity, "%");
  img.drawString(hum, 70, 125);

  // Time box
  int rect_x = 70;
  int rect_y = 190;
  int t_offset = 30;
  img.fillRoundRect(rect_x, rect_y, 240-2*rect_x, 240-rect_y, 8, CLOCK_BG);
  img.fillTriangle(rect_x-t_offset, 240, rect_x+3,     rect_y+2, rect_x,              240, CLOCK_BG);
  img.fillTriangle(240-rect_x,      240, 240-rect_x-3, rect_y+2, 240-rect_x+t_offset, 240, CLOCK_BG);

  // Time
  img.setTextColor(TFT_WHITE, CLOCK_BG);
  img.setFreeFont(&DSEG7_Classic_Mini_Regular_26);
  img.drawString("09:45", 73, 200);
}

void setup(void) {  
   
  tft.init();
  tft.setRotation(0);
  tft.fillScreen(BACKGROUND);
  
  initWiFi();

  temperature = 18.0;
  humidity = 40;
}

void loop() {

  if(temperature>24) {
    temperature = 18.0;
  }
  if(humidity>60) {
    humidity = 40;
  }
  temperature = temperature + 0.2;
  humidity = humidity + 2;
  
  img.createSprite(IWIDTH, IHEIGHT);
  img.fillSprite(BACKGROUND);

  updateData(temperature, humidity, "09:45");  

  img.pushSprite(0, 0);
  img.deleteSprite();

  delay(5000);
}

[Bodmer]

This is likely due to lack of available RAM. Make the sprite smaller or use a processor board with PSRAM.

[sam632]

Yes I got it working with smaller sprites. I realised the board I was using was an ESP-WROOM board. Will switch to a WROVER one for more PSRAM. Thanks!

[sam632]

@Bodmer How much PSRAM is sufficient? I see the ESP32-PICO-MINI-02 has 2MB and is small vs the larger ESP32-WROVER-E with 8MB. Is 2MB sufficient to use large sprites on a GC9A01?

[Bodmer]

Yes, 2MB is sufficient.