jacoco.gradle

apply plugin:"jacoco"
jacoco {
    toolVersion = "0.8.8"
}

test {
    useJUnitPlatform()
    jacoco {
        excludes = ['**/Application.groovy',
                    '**/BootStrap.groovy',
                    '**/UrlMappings.groovy',
                    '**/*GrailsPlugin.groovy',
                    '**/*Mock.groovy',
                    'com.skedgo.converter.*']
    }
    finalizedBy jacocoTestReport // report is always generated after tests run
}

jacocoTestReport {
    dependsOn test
    finalizedBy jacocoTestCoverageVerification // report is always generated after tests run
    afterEvaluate {
        getClassDirectories().setFrom(classDirectories.files.collect {
            fileTree(dir: it,
                    exclude: [
                            '**/TimezoneMapper.class'
                    ]
            )
        })
    }

    reports {
        xml.enabled false
        csv.enabled false
        html.destination file("${buildDir}/reports/jacocoHtml")
    }
}

jacocoTestCoverageVerification {
    dependsOn test
    violationRules {
        rule {
            limit {
                minimum = 0.31
            }
        }
    }
}